Funktionreferenz

_GUICtrlRichEdit_SetText

Beschreibung anzeigen in

Setzt den Text eines Controls

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetText ( $hWnd, $sText )

Parameter

$hWnd Handle des Controls
$sText Einfacher oder RTF-Text, der in das Control geschrieben werden soll

Rückgabewert

Erfolg: True.
Fehler: False und setzt das @error Flag auf ungleich 0.
@error: 101 - $hWnd ist kein Handle

Bemerkungen

Setzt den gesamten Text, der einfacher oder RTF-Text sein kann.
Behält den Rückgängig-Stapel bei.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_EmptyUndoBuffer, _GUICtrlRichEdit_GetText, _GUICtrlRichEdit_InsertText, _GUICtrlRichEdit_ReplaceText

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsStylesConstants.au3>

Global $g_idLbl_Msg

Example()

Func Example()
    Local $hGui = GUICreate("RichEdit: Setzt und ermittelt Text (v" & @AutoItVersion & ")", 440, 350, -1, -1)
    Local $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 320, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_SetText($hRichEdit, "Dies ist angehängter Text.")

    Report("Inhalt: " & @CRLF & @CRLF & _GUICtrlRichEdit_GetText($hRichEdit))

    Local $iMsg
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLbl_Msg, $sMsg)
EndFunc   ;==>Report