_GUICtrlRichEdit_InsertText
Beschreibung anzeigen in
Fügt Text am Einfügepunkt oder Ankerpunkt der Markierung ein
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_InsertText ( $hWnd, $sText )
Parameter
| $hWnd | Handle des Controls |
| $sText | Einzufügender Text |
Rückgabewert
| Erfolg: | True |
| Fehler: | False und setzt das @error Flag auf ungleich 0 |
| @error: | 101 - $hWnd ist kein Handle 102 - $sText = "" 700 - Kann nicht gesetzt werden |
Bemerkungen
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
_GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_GetText, _GUICtrlRichEdit_ReplaceText, _GUICtrlRichEdit_SetText
Siehe auch
Suche nach EM_SETTEXTEX in der MSDN Bibliothek.
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsStylesConstants.au3>
Example()
Func Example()
Local $hGui, $iMsg, $idBtn_Next, $iStep = 0, $g_idLbl_Msg, $hRichEdit
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$idBtn_Next = GUICtrlCreateButton("Weiter", 270, 310, 40, 30)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_SetText($hRichEdit, "Erster Absatz")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
Case $iMsg = $idBtn_Next
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_SetSel($hRichEdit, 5, 2)
Case 2
_GUICtrlRichEdit_InsertText($hRichEdit, "EINGEFÜGT_1")
GUICtrlSetData($g_idLbl_Msg, "Text wurde am aktive Punkt der Auswahl eingefügt")
Case 3
_GUICtrlRichEdit_GotoCharPos($hRichEdit, 20)
_GUICtrlRichEdit_InsertText($hRichEdit, "EINGEFÜGT_2")
GUICtrlSetData($g_idLbl_Msg, "Text wurde am Einfügungspunkt eingefügt")
GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Example