_WinAPI_FlashWindowEx

Beschreibung anzeigen in

Lässt das angegebene Fenster (mehrmalig) aufblinken

#include <WinAPISysWin.au3>
_WinAPI_FlashWindowEx ( $hWnd [, $iFlags = 3 [, $iCount = 3 [, $iTimeout = 0]]] )

Parameter

$hWnd	Handle zu dem Fenster, welches aufblinken soll. Das Fenster muss entweder geöffnet oder minimiert sein.
$iFlags	[optional] Der Blinkstatus. Kann einer oder eine Kombination der folgenden Werte sein: 0 - Stoppt das Aufblinken. Das System stellt den ursprünglichen Status wieder her. 1 - Lässt die Titelleiste des Fensters aufblinken 2 - Lässt den Button des Fensters in der Taskbar aufblinken 4 - Blinkt kontinuierlich bis zum Ende 8 - Blinkt kontinuierlich bis das Fenster in den Vordergrund geholt wird
$iCount	[optional] Die Anzahl wie oft das Fenster aufblinken soll
$iTimeout	[optional] Der Zeitabstand in dem das Fenster aufblinken soll, in Millisekunden. Falls 0, nutzt die Funktion die Standard-Blinkrate des Cursors.

Rückgabewert

Erfolg:	True
Fehler:	False

Bemerkungen

Diese Funktion wird normalerweise genutzt, um den Anwender darüber zu Informieren, dass das Fenster seine Aufmerksamkeit benötigt, jedoch ohne den Tastaturfokus augenblicklich auf das betreffende Fenster zu setzen.
Wenn ein Fenster "blinkt" erscheint es im Wechsel: aktiver/inaktiver Status. D.h. eine "aktive" Titelleiste wechselt zu "inaktiv" und umgekehrt.

Siehe auch

Suche nach FlashWindowEx in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <WinAPISysWin.au3>

Example()

Func Example()
    Local $hWnd, $idFlash, $idTimeout, $idBtnFlash, $iMsg, $iFlashrate, $iTimeoutrate, $bFlashing = False
    $hWnd = GUICreate("_WinAPI_FlashWindowEx", 350, 170, 340, 125)
    $idFlash = GUICtrlCreateInput("20", 130, 68, 161, 21)
    $idTimeout = GUICtrlCreateInput("500", 130, 99, 161, 21)
    GUICtrlCreateLabel("Bitte gib die Blinkrate und die Pause zwischen den Blinkimpulsen ein:", 10, 24, 340, 41)
    GUICtrlCreateLabel("Blinkrate:", 56, 72, 108, 17)
    GUICtrlCreateLabel("Pause (ms)", 56, 104, 114, 17)
    $idBtnFlash = GUICtrlCreateButton("Blinken!", 113, 136, 125, 25, 0)
    GUISetState(@SW_SHOW)

    While 1
        $iMsg = GUIGetMsg()
        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $idBtnFlash
                If $bFlashing Then
                    _WinAPI_FlashWindowEx($hWnd, 0)
                    $bFlashing = False
                Else
                    $iFlashrate = GUICtrlRead($idFlash)
                    $iTimeoutrate = GUICtrlRead($idTimeout)
                    _WinAPI_FlashWindowEx($hWnd, 2, $iFlashrate, $iTimeoutrate)
                    GUICtrlSetData($idBtnFlash, "Stoppe das Geblinke!")
                    $bFlashing = True
                EndIf
        EndSwitch
    WEnd
EndFunc   ;==>Example