Funktionreferenz


_WinAPI_GetWindowSubclass

Beschreibung anzeigen in

Ruft die Referenzdaten für den angegebenen Callback der Fenster-Unterklasse ab

#include <WinAPIShellEx.au3>
_WinAPI_GetWindowSubclass ( $hWnd, $pSubclassProc, $idSubClass )

Parameter

$hWnd Handle des Fensters, von dem eine Unterklasse erstellt wird.
$pSubclassProc Ein Zeiger auf eine Fensterprozedur. Dieser Zeiger und die Unterklassen-ID identifizieren diesen Unterklassen-Callback eindeutig.
(Siehe MSDN für mehr Informationen)
$idSubClass Die ID der Unterklasse.

Rückgabewert

Erfolg: Die Referenzdaten ($pData), die an die Funktion _WinAPI_SetWindowSubclass() übergeben werden.
Fehler: setzt das @error Flag auf ungleich 0.

Verwandte Funktionen

_WinAPI_SetWindowSubclass

Siehe auch

Suche nach GetWindowSubclass in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIShellEx.au3>
#include <WindowsNotifsConstants.au3>

Local $hGUI = GUICreate('Unterklasse: 3 Eingabesteuerelemente', 500, 300)
GUICtrlCreateLabel("Doppelklicken, um Informationen zur Unterklasse anzuzeigen", 10, 30)
Global $g_idInput01 = GUICtrlCreateInput('', 10, 50, 380, 20)
GUICtrlCreateLabel("Doppelklicken, um Informationen zur Unterklasse anzuzeigen", 10, 100)
Global $g_idInput02 = GUICtrlCreateInput('', 10, 120, 380, 20)

GUICtrlCreateLabel("Neue Info-Nummer für die erste Eingabe eingeben." & @CRLF & "Anschließend auf Erste Eingabe doppelklicken, um die neuen Referenzdaten anzuzeigen.", 10, 180)
Global $idInput03 = GUICtrlCreateInput('', 10, 220, 380, 20)

Local $hInputSubClassProc = DllCallbackRegister('_InputSubClassProc', 'LRESULT', 'HWND;UINT;WPARAM;LPARAM;UINT_PTR;DWORD_PTR')
Global $g_pInputSubClassProc = DllCallbackGetPtr($hInputSubClassProc)

If $g_pInputSubClassProc = 0 Then
    MsgBox($MB_ICONERROR, 'Subclass Test', 'Aufruf von DllCallbackRegister fehlgeschlagen')
    Exit
EndIf

_WinAPI_SetWindowSubclass(GUICtrlGetHandle($g_idInput01), $g_pInputSubClassProc, 1000, 111)
If @error Then
    MsgBox($MB_ICONERROR, 'Subclass Test', 'Aufruf von WinProc für inp010 fehlgeschlagen.')
    Exit
EndIf

_WinAPI_SetWindowSubclass(GUICtrlGetHandle($g_idInput02), $g_pInputSubClassProc, 2000, 222)
If @error Then
    MsgBox($MB_ICONERROR, 'Subclass Test', 'Aufruf von  WinProc für inp020 fehlgeschlagen')
    Exit
EndIf

GUISetState()

Local $iNewRefData
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $idInput03
            $iNewRefData = Number(GUICtrlRead($idInput03))
            ; Referenzdatennummer aktualisieren
            _WinAPI_SetWindowSubclass(GUICtrlGetHandle($g_idInput01), $g_pInputSubClassProc, 1000, $iNewRefData)
            ToolTip(">>> Referenzdaten außerhalb der Unterklasse = " & _WinAPI_GetWindowSubclass(GUICtrlGetHandle($g_idInput01), $g_pInputSubClassProc, 1000) & @CRLF)
    EndSwitch
WEnd

_WinAPI_RemoveWindowSubclass(GUICtrlGetHandle($g_idInput01), $g_pInputSubClassProc, 1000)
_WinAPI_RemoveWindowSubclass(GUICtrlGetHandle($g_idInput02), $g_pInputSubClassProc, 2000)
DllCallbackFree($hInputSubClassProc)

Func _InputSubClassProc($hWnd, $iMsg, $wParam, $lParam, $iSubClassID, $iRefData)
    Switch $iMsg
        Case $WM_LBUTTONDBLCLK
            Switch $iSubClassID
                Case 1000
                    GUICtrlSetData($g_idInput01, 'Es wurde doppelt angeklickt., data = ' & $iRefData)
                Case 2000
                    GUICtrlSetData($g_idInput02, 'Es wurde doppelt angeklickt., data = ' & $iRefData)
            EndSwitch
            ToolTip("$IdSubclaa = " & $iSubClassID & @CRLF & "Referenzdaten = " & _WinAPI_GetWindowSubclass($hWnd, $g_pInputSubClassProc, $iSubClassID) & @CRLF)
    EndSwitch

    Return _WinAPI_DefSubclassProc($hWnd, $iMsg, $wParam, $lParam)
EndFunc   ;==>_InputSubClassProc