Edit "unklickbar" machen

  • Hallo Leute

    Ich habe immer noch ein Problem, das in meinem letzten Thread nicht ganz gelöst wurde.
    Kann ich ein Edit "unklickbar" machen, d.h. dass der Cursor dort gar nicht hineindarf UND gleichzeitig können noch Strings an das Edit gesendet werden?
    Wäre echt spitze wenn mir wer helfen könnte

    Padmak

    Edit: Im Prinzip so wie CMD.
    Dort kann man auch nicht den Text markieren o.Ä.

    Einmal editiert, zuletzt von Padmak (15. Februar 2009 um 16:25)

  • Benutz doch Labels, oder verstecke was vor dem Edit, was durchsichtig ist...
    Edit: Verdammt, zu langsam ;)

  • Danke @Raupi, das hab ich schon mal probiert, da ist es aber nicht gegangen.
    Nun hab ich das Problem dass die Schrift so dunkelgrau ist (0x808080) und nicht hellgrau (0x0C0C0C) wie sie sein soll.
    Ne Idee?

    Padmak

    • Offizieller Beitrag

    Meinst Du vielleicht sowas:

    [autoit]


    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <EditConstants.au3>

    [/autoit][autoit][/autoit][autoit]

    GUICreate("My GUI edit", 400, 300)
    $myedit = GUICtrlCreateEdit("", 5, 5, 390, 200, $ES_AUTOVSCROLL + $WS_VSCROLL)
    $input = GUICtrlCreateInput("", 5, 270, 390, 20)
    GUICtrlSetState(-1, $GUI_FOCUS)
    GUISetState()
    GUIRegisterMsg($WM_COMMAND, 'MY_WM_COMMAND')
    Do
    $msg = GUIGetMsg()
    If $msg = $input Then
    GUICtrlSetData($myedit, GUICtrlRead($myedit) & GUICtrlRead($input) & @CRLF)
    GUICtrlSetData($input, "")
    EndIf
    Until $msg = $GUI_EVENT_CLOSE

    [/autoit][autoit][/autoit][autoit]

    Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nID = BitAND($wParam, 0x0000FFFF)
    If $nID = $myedit Then GUICtrlSetState($input, $GUI_FOCUS)
    Return $GUI_RUNDEFMSG
    EndFunc

    [/autoit]
    • Offizieller Beitrag

    It's not a bug. It's a Feature! :D

    Wenn das nicht erwünscht ist, dann halt mit zusätzlichem Button:

    Spoiler anzeigen
    [autoit]


    #include <ButtonConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <EditConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    GUICreate("My GUI edit", 400, 300)
    $myedit = GUICtrlCreateEdit("", 5, 5, 390, 200, $ES_AUTOVSCROLL + $WS_VSCROLL)
    $input = GUICtrlCreateInput("", 5, 270, 300, 20)
    GUICtrlSetState(-1, $GUI_FOCUS)
    $go = GUICtrlCreateButton("senden", 320, 270, 70, 20, $BS_DEFPUSHBUTTON)
    GUISetState()
    GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")
    Do
    $msg = GUIGetMsg()
    If $msg = $go Then
    GUICtrlSetData($myedit, GUICtrlRead($myedit) & GUICtrlRead($input) & @CRLF)
    GUICtrlSetData($input, "")
    EndIf
    Until $msg = $GUI_EVENT_CLOSE

    [/autoit] [autoit][/autoit] [autoit]

    Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nID = BitAND($wParam, 0x0000FFFF)
    If $nID = $myedit Then GUICtrlSetState($input, $GUI_FOCUS)
    Return $GUI_RUNDEFMSG
    EndFunc

    [/autoit]
  • Zitat

    Danke @Raupi, das hab ich schon mal probiert, da ist es aber nicht gegangen.
    Nun hab ich das Problem dass die Schrift so dunkelgrau ist (0x808080) und nicht hellgrau (0x0C0C0C) wie sie sein soll.
    Ne Idee?

    Padmak

    $ES_READONLY verändert nicht die Schriftfarbe und hat die gleiche Funktion. Aber die Hintergrundfarbe is anders :)

  • Oscar
    Ist ja ganz schön aber viel zu umständlich :D
    Danke trotzdem *archivier*

    Ok das ist perfekt :D
    Wenn man aber jetzt das Edit voll hat, also dass nach unten gescrollt wird, und man dann per scrollbalken nach oben geht, und dann was schreiben will ist man nicht unten
    Kann man das noch ändern?

    blubbstar
    Es geht hier nicht um $ES_READONLY sondern um $GUI_DISABLE
    Dann sag mir doch bitte ne Hintergrundfarbe, bei der dann die Schrift 0x0C0C0C ist :D

    Padmak

    Edit: UUUH hab gerade entdeckt dass man das Edit dann nicht mehr scrollen kann (Raupis Lösung)
    Das ist ja Fatal^^

    Einmal editiert, zuletzt von Padmak (15. Februar 2009 um 16:08)

    • Offizieller Beitrag

    Probier mal das :

    Spoiler anzeigen
    [autoit]

    #include <EditConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <GuiEdit.au3>
    #include <ScrollBarConstants.au3>
    Global $sTempText
    GUICreate("My GUI edit", 400, 300)
    $myedit = GUICtrlCreateEdit("", 5, 5, 390, 200, $ES_AUTOVSCROLL + $WS_VSCROLL)
    $input = GUICtrlCreateInput("", 5, 270, 390, 20)
    GUICtrlSetState(-1, $GUI_FOCUS)
    GUISetState()
    GUIRegisterMsg($WM_COMMAND, 'MY_WM_COMMAND')
    Do
    $msg = GUIGetMsg()
    If $msg = $input Then
    If $StempText <> GUICtrlRead($input) Then
    GUICtrlSetData($myedit, GUICtrlRead($myedit) & GUICtrlRead($input) & @CRLF)
    GUICtrlSetData($input, "")
    _GUICtrlEdit_Scroll($myedit,$SB_SCROLLCARET)
    Else
    GUICtrlSetData($input, $StempText)
    EndIf
    EndIf
    Until $msg = $GUI_EVENT_CLOSE

    [/autoit] [autoit][/autoit] [autoit]

    Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nID = BitAND($wParam, 0x0000FFFF)
    If $nID = $myedit Then
    $StempText = GUICtrlRead($input)
    GUICtrlSetState($input, $GUI_FOCUS)
    Endif
    Return $GUI_RUNDEFMSG
    EndFunc

    [/autoit]
    • Offizieller Beitrag

    Geht auch anders:

    Spoiler anzeigen
    [autoit]


    #include <ButtonConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>
    #include <EditConstants.au3>
    #include <GuiEdit.au3>

    [/autoit] [autoit][/autoit] [autoit]

    GUICreate("My GUI edit", 400, 300)
    $myedit = GUICtrlCreateEdit("", 5, 5, 390, 200, BitOR($ES_MULTILINE, $ES_AUTOVSCROLL, $WS_VSCROLL))
    $input = GUICtrlCreateInput("", 5, 270, 300, 20)
    GUICtrlSetState(-1, $GUI_FOCUS)
    $go = GUICtrlCreateButton("senden", 320, 270, 70, 20, $BS_DEFPUSHBUTTON)
    GUISetState()
    GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")
    Do
    $msg = GUIGetMsg()
    If $msg = $go Then
    GUICtrlSetData($myedit, GUICtrlRead($myedit) & GUICtrlRead($input) & @CRLF)
    _GUICtrlEdit_LineScroll($myedit, 0, _GUICtrlEdit_GetLineCount($myedit))
    GUICtrlSetData($input, "")
    EndIf
    Until $msg = $GUI_EVENT_CLOSE

    [/autoit] [autoit][/autoit] [autoit]

    Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nID = BitAND($wParam, 0x0000FFFF)
    If $nID = $myedit Then GUICtrlSetState($input, $GUI_FOCUS)
    Return $GUI_RUNDEFMSG
    EndFunc

    [/autoit]
    • Offizieller Beitrag

    Meine Lösung hat immer noch 2 Macken. Wenn du 2 mal in das Edit klickst wird der Cursor nicht mehr an das Ende des Input gesetzt sondern der Text ausgewählt .Und 2. wenn du in der Input was stehen hast , in des Edit klickst und versuchst dann Return zu drücken wird der Inhalt der Input nicht in das Edit übernommen . Also immer noch nicht Perfekt.