Suche Helfer für ein "AutoIt Kinderpaket" - Jeder ist herzlichst eingeladen!

der Scripter

Hier ist ein kleines Mausklickzähler Prog:

Spoiler anzeigen

[autoit]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Include <GuiButton.au3>
#Include <Misc.au3>
#Region ### START Koda GUI section ### Form=C:\Dokumente und Einstellungen\Sebastian\Desktop\autoit\mousecount\clickcount.kxf
$Form1 = GUICreate("Form1", 592, 150, 352, 491)
$Label1 = GUICtrlCreateLabel("Wie oft hat deine Maus heute gepiept?", 0, 0, 590, 52)
GUICtrlSetFont(-1, 20, 800, 0, "MS Sans Serif")
GUICtrlSetBkColor(-1, 0x008000)
$Label2 = GUICtrlCreateLabel("Linksklicks:", 0, 52, 590, 48)
GUICtrlSetFont(-1, 20, 800, 0, "MS Sans Serif")
GUICtrlSetBkColor(-1, 0xA6CAF0)
$Label3 = GUICtrlCreateLabel("Rechtsklicks:", 0, 102, 590, 48)
GUICtrlSetFont(-1, 20, 800, 0, "MS Sans Serif")
GUICtrlSetBkColor(-1, 0xFFFBF0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
$countl=0
$countr=0
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit

[/autoit] [autoit][/autoit] [autoit]

EndSwitch
if _IsPressed('01') Then
$countl=$countl+1
GUICtrlSetData($label2,"Linksklicks: " & $countl)
EndIf
if _IsPressed('02') Then
$countr = $countr+1
GUICtrlSetData($label3, "Rechtsklicks: " &$countr)
endif
sleep(100)
WEnd

[/autoit] [autoit][/autoit] [autoit][/autoit]

Darf bearbeitet werden.

Es ist net so schön :=)

PokerFace

So hier ist die erste Version des Kinderpackets.
Natürlich ist sie noch ein wenig bedürftigt und das Mathe Programm ist NOCH nicht dabei.
Ich werde mich sofort drum kümmern das Mathe Programm umfangreich zu testen!

Commander21

Zitat von PokerFace

Ich werde mich sofort drum kümmern das Mathe Programm umfangreich zu testen!

Tu dass. Sobald die Aktuelle Version vertig ist, werde ich dir das Programm nochmal zuschicken. Dann können wir ja beide testen, ob noch Bugs enthalten sind.
Weitere Funktionen folgen noch...

**eukalyptus**

Hir ist mal die Betaversion von meinem Beitrag.

Ein Bild-Puzzle-Spiel

Spoiler anzeigen

[autoit]

#include <GUIConstantsEx.au3>
#include <Array.au3>
#include <File.au3>
#include <GDIPlus.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

Opt("GUIOnEventMode", 1)

[/autoit] [autoit][/autoit] [autoit]

Global $iTile = 0, $iSize, $hLabel[5][5], $aField[5][5][3]

[/autoit] [autoit][/autoit] [autoit]

Global $aFiles = _FileListToArray(@ScriptDir, "*.jpg", 1)
_ArrayCombine($aFiles, _FileListToArray(@ScriptDir, "*.bmp", 1))
_ArrayCombine($aFiles, _FileListToArray(@ScriptDir, "*.tif", 1))
_ArrayCombine($aFiles, _FileListToArray(@ScriptDir, "*.gif", 1))
_ArrayCombine($aFiles, _FileListToArray(@ScriptDir, "*.png", 1))

[/autoit] [autoit][/autoit] [autoit]

If Not IsArray($aFiles) Or $aFiles[0] < 1 Then
MsgBox(0, "Error", "Keine Bilder gefunden")
Exit
EndIf

[/autoit] [autoit][/autoit] [autoit]

_GDIPlus_Startup()

[/autoit] [autoit][/autoit] [autoit]

Global $hImage, $iWidth, $iHeight
Global $hPenWhite = _GDIPlus_PenCreate(0x44FFFFFF, 2)
Global $hPenBlack = _GDIPlus_PenCreate(0x44000000, 2)
Global $hBrushBK = _GDIPlus_BrushCreateSolid(0xFF6C99B4)

[/autoit] [autoit][/autoit] [autoit]

Global $hGui = GUICreate("SchiebePuzzle", 452, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
GUISetOnEvent($GUI_EVENT_RESTORE, "_ReDraw")
GUISetBkColor(0x6C99B4)
GUICtrlCreateLabel("", 4, 4, 444, 444)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetBkColor(-1, 0x558097)
GUICtrlCreateLabel("", 6, 6, 442, 442)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetBkColor(-1, 0x88B8D8)
GUICtrlCreateLabel("", 6, 6, 440, 440)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetBkColor(-1, 0x6C99B4)

[/autoit] [autoit][/autoit] [autoit]

GUICtrlCreateLabel("Anzahl der Felder:", 10, 468, 90, 20)
Global $hInput = GUICtrlCreateInput(3, 100, 465, 30, 20, $ES_READONLY)
GUICtrlCreateUpdown(-1)
GUICtrlSetLimit(-1, 5, 2)
GUICtrlSetOnEvent(-1, "_SetTile")
GUICtrlCreateButton("Mischen", 160, 465, 80, 20)
GUICtrlSetOnEvent(-1, "_Randomize")
GUICtrlCreateButton("Neues Bild", 260, 465, 80, 20)
GUICtrlSetOnEvent(-1, "_LoadRandomImage1")
GUICtrlCreateButton("Beenden", 360, 465, 80, 20)
GUICtrlSetOnEvent(-1, "_Exit")
GUISetState()
Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
GUIRegisterMsg($WM_PAINT, '_Redraw')
_LoadRandomImage()
_SetTile()

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

While 1
Sleep(100)
WEnd

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

Func _MoveField()
Local $iX, $iY, $iNX, $iNY, $iDir
For $i = 0 To $iTile - 1
For $j = 0 To $iTile - 1
If $hLabel[$i][$j] = @GUI_CtrlId Then
$iX = $i
$iY = $j
ExitLoop 2
EndIf
Next
Next
If $aField[$iX][$iY][2] <> 2 Then Return
$iNX = $iX
$iNY = $iY
Select
Case $iX > 0 And $aField[$iX - 1][$iY][2] = 0
$iNX = $iX - 1
$iDir = 1
Case $iX < $iTile - 1 And $aField[$iX + 1][$iY][2] = 0
$iNX = $iX + 1
$iDir = 2
Case $iY > 0 And $aField[$iX][$iY - 1][2] = 0
$iNY = $iY - 1
$iDir = 3
Case $iY < $iTile - 1 And $aField[$iX][$iY + 1][2] = 0
$iNY = $iY + 1
$iDir = 4
EndSelect
For $i = 0 To $iSize Step 5
Switch $iDir
Case 1
_DrawField($iX, $iY, -$i, 0)
Case 2
_DrawField($iX, $iY, $i, 0)
Case 3
_DrawField($iX, $iY, 0, -$i)
Case 4
_DrawField($iX, $iY, 0, $i)
EndSwitch
Sleep(10)
Next
$aField[$iNX][$iNY][0] = $aField[$iX][$iY][0]
$aField[$iNX][$iNY][1] = $aField[$iX][$iY][1]
$aField[$iNX][$iNY][2] = $aField[$iX][$iY][2]
$aField[$iX][$iY][2] = False
GUICtrlSetBkColor($hLabel[$iX][$iY], 0x6C99B4)
_DrawField($iNX, $iNY)
_SetFreeField()
EndFunc ;==>_MoveField

[/autoit] [autoit][/autoit] [autoit]

Func _LoadRandomImage1()
_WinAPI_RedrawWindow($hGui)
_LoadRandomImage()
_ReDraw()
EndFunc ;==>_LoadRandomImage1

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

Func _LoadRandomImage($Orig = False)
Local $iRandom = Random(1, $aFiles[0], 1)
If $iRandom = 0 Or $aFiles[0] = 1 Then $iRandom = 1
If $Orig = False Then $hImage = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\" & $aFiles[$iRandom])
$iWidth = _GDIPlus_ImageGetWidth($hImage)
$iHeight = _GDIPlus_ImageGetHeight($hImage)
For $i = 0 To $iTile - 1
For $j = 0 To $iTile - 1
GUICtrlSetCursor($hLabel[$i][$j], 2)
$aField[$i][$j][0] = $i * $iSize
$aField[$i][$j][1] = $j * $iSize
$aField[$i][$j][2] = 1
Next
Next
$aField[0][0][2] = 0
$aField[1][0][2] = 2
$aField[0][1][2] = 2
GUICtrlSetCursor($hLabel[1][0], 0)
GUICtrlSetCursor($hLabel[0][1], 0)
EndFunc ;==>_LoadRandomImage

[/autoit] [autoit][/autoit] [autoit]

Func _Randomize()
GUIRegisterMsg($WM_PAINT, '')
Local $iX = 0, $iY = 0, $iNX, $iNY, $iDir
For $i = 0 To $iTile - 1
For $j = 0 To $iTile - 1
If $aField[$i][$j][2] = 0 Then
$iX = $i
$iY = $j
ExitLoop 2
EndIf
Next
Next
For $c = 1 To 500
Do
$iNX = $iX
$iNY = $iY
$iDir = Random(1, 4, 1)
Select
Case $iDir = 2 And $iX > 0
$iNX = $iX - 1
Case $iDir = 1 And $iX < $iTile - 1
$iNX = $iX + 1
Case $iDir = 4 And $iY > 0
$iNY = $iY - 1
Case $iDir = 3 And $iY < $iTile - 1
$iNY = $iY + 1
EndSelect
Until $iX <> $iNX Or $iY <> $iNY
$aField[$iX][$iY][0] = $aField[$iNX][$iNY][0]
$aField[$iX][$iY][1] = $aField[$iNX][$iNY][1]
$aField[$iX][$iY][2] = $aField[$iNX][$iNY][2]
$aField[$iNX][$iNY][2] = False
GUICtrlSetBkColor($hLabel[$iNX][$iNY], 0x6C99B4)
_DrawField($iX, $iY)
$iX = $iNX
$iY = $iNY
Next
_ReDraw()
_SetFreeField()
GUIRegisterMsg($WM_PAINT, '_Redraw')
EndFunc ;==>_Randomize

[/autoit] [autoit][/autoit] [autoit]

Func _SetFreeField()
For $i = 0 To $iTile - 1
For $j = 0 To $iTile - 1
GUICtrlSetCursor($hLabel[$i][$j], 2)
If $aField[$i][$j][2] <> 0 Then $aField[$i][$j][2] = 1
Next
Next
For $i = 0 To $iTile - 1
For $j = 0 To $iTile - 1
If $aField[$i][$j][2] = False Then
If $i > 0 Then
GUICtrlSetCursor($hLabel[$i - 1][$j], 0)
$aField[$i - 1][$j][2] = 2
EndIf
If $i < $iTile - 1 Then
GUICtrlSetCursor($hLabel[$i + 1][$j], 0)
$aField[$i + 1][$j][2] = 2
EndIf
If $j > 0 Then
GUICtrlSetCursor($hLabel[$i][$j - 1], 0)
$aField[$i][$j - 1][2] = 2
EndIf
If $j < $iTile - 1 Then
GUICtrlSetCursor($hLabel[$i][$j + 1], 0)
$aField[$i][$j + 1][2] = 2
EndIf
EndIf
Next
Next
EndFunc ;==>_SetFreeField

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

Func _DrawField($x, $y, $iOX = 0, $iOY = 0)
If $aField[$x][$y][2] = False Then Return
Local $iX = $aField[$x][$y][0]
Local $iY = $aField[$x][$y][1]
Switch True
Case $iOX > 0
_GDIPlus_GraphicsFillRect($hGraphics, 6 + $x * $iSize, 6 + $y * $iSize, $iOX, $iSize, $hBrushBK)
Case $iOX < 0
_GDIPlus_GraphicsFillRect($hGraphics, 6 + $x * $iSize + $iSize + $iOX, 6 + $y * $iSize, -$iOX, $iSize, $hBrushBK)
Case $iOY > 0
_GDIPlus_GraphicsFillRect($hGraphics, 6 + $x * $iSize, 6 + $y * $iSize, $iSize, $iOY, $hBrushBK)
Case $iOY < 0
_GDIPlus_GraphicsFillRect($hGraphics, 6 + $x * $iSize, 6 + $y * $iSize + $iSize + $iOY, $iSize, -$iOY, $hBrushBK)
EndSwitch
_GDIPlus_GraphicsDrawImageRectRect($hGraphics, $hImage, $iX, $iY, $iSize, $iSize, 6 + $x * $iSize + $iOX, 6 + $y * $iSize + $iOY, $iSize, $iSize)
_GDIPlus_GraphicsDrawLine($hGraphics, 6 + $x * $iSize + $iOX, 7 + $y * $iSize + $iOY, $iSize + 6 + $x * $iSize + $iOX, 7 + $y * $iSize + $iOY, $hPenWhite)
_GDIPlus_GraphicsDrawLine($hGraphics, 7 + $x * $iSize + $iOX, 6 + $y * $iSize + $iOY, 7 + $x * $iSize + $iOX, $iSize + 6 + $y * $iSize + $iOY, $hPenWhite)
_GDIPlus_GraphicsDrawLine($hGraphics, 6 + $x * $iSize + $iOX, $iSize + 5 + $y * $iSize + $iOY, $iSize + 6 + $x * $iSize + $iOX, $iSize + 5 + $y * $iSize + $iOY, $hPenBlack)
_GDIPlus_GraphicsDrawLine($hGraphics, $iSize + 5 + $x * $iSize + $iOX, 6 + $y * $iSize + $iOY, $iSize + 5 + $x * $iSize + $iOX, $iSize + 6 + $y * $iSize + $iOY, $hPenBlack)
EndFunc ;==>_DrawField

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

Func _SetTile()
If $iTile = GUICtrlRead($hInput) Then Return
GUIRegisterMsg($WM_PAINT, '')
For $i = 0 To 4
For $j = 0 To 4
GUICtrlDelete($hLabel[$i][$j])
Next
Next
$iTile = GUICtrlRead($hInput)
$iSize = Round(440 / $iTile)
For $i = 0 To $iTile - 1
For $j = 0 To $iTile - 1
$hLabel[$i][$j] = GUICtrlCreateLabel("", 6 + $i * $iSize, 6 + $j * $iSize, $iSize, $iSize)
GUICtrlSetCursor(-1, 2)
GUICtrlSetOnEvent(-1, "_MoveField")
Next
Next
_LoadRandomImage(True)
_ReDraw()
GUIRegisterMsg($WM_PAINT, '_Redraw')
EndFunc ;==>_SetTile

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

Func _ReDraw()
For $i = 0 To $iTile - 1
For $j = 0 To $iTile - 1
_DrawField($i, $j)
Next
Next
EndFunc ;==>_ReDraw

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

Func _ArrayCombine(ByRef $aArray, $aNew)
If Not IsArray($aNew) Then Return
Local $iArray = UBound($aArray) - 1, $iNew = UBound($aNew) - 1
Local $aReturn[$iArray + $iNew + 1]
For $i = 1 To $iArray
$aReturn[$i] = $aArray[$i]
Next
For $i = 1 To $iNew
$aReturn[$i + $iArray] = $aNew[$i]
Next
$aReturn[0] = $iArray + $iNew
$aArray = $aReturn
EndFunc ;==>_ArrayCombine

[/autoit] [autoit][/autoit] [autoit]

Func _Exit()
_GDIPlus_Shutdown()
Exit
EndFunc ;==>_Exit

[/autoit]

Ist zwar noch nicht fertig, aber bereits spielbar.

Dazu benötigt man dann noch Bilder (jpg,bmp,tif,png,gif) im Format 440x440...

Zum testen hab ich ein Bild angefügt.
Ja, ich weiß selber, daß dieses Bild nicht unbedingt in ein Kinderspiel passt
Ich hab aber momentan kein anderes gefunden

lgE

**peethebee**

Hi,

Ich will ja nicht zu oft was sagen, aber nachdem es hier um den Titel geht...
http://www.duden-suche.de/suche/trefferliste.php?suchbegriff[AND]=paket&suche=homepage&treffer_pro_seite=10&modus=title&level=125&x=0&y=0

peethebee

DeepRed92

Warum wird dieser Thread nicht unter Projekte verschoben?

eukalyptus: Dein Spiel ist ja echt Klasse Ich hab mal noch ein Bild von einem (unserem) Hund hinzugefügt.

SeriousBEN

Ich hätte da noch ne idee.

man könnte per soundplay ein wort diktieren und das Kind muss es Korrekt in eine Inputbox eintippen.

evtl. wird dazu noch ein hübsches bild angezeigt, ich kann mir am wochenende mal gedanken dazu machen.

VLG

BEN

Ashpool

Zitat von peethebee

Ich will ja nicht zu oft was sagen, aber nachdem es hier um den Titel geht...
http://www.duden-suche.de/suche/trefferl…vel=125&x=0&y=0

Du sprichst mir aus der Seele!
Es tut einfach weh, immer dieses ..ck.. zu lesen, obwohl ich nicht verstehe, warum das bei der letzten Rechtschreibreform nicht angepasst wurde.

PokerFace

Neue Version im 1# Post!

Lololo124

warum schliest sich wortsturz in dem paket immer bei mir?

Click Ctrl-C to copy. (hides when lost focus)

PokerFace

Mir ist gerade auch aufgefallen, dass es sofort ausgeht!
Ich werde mich drum kümmern

**Oscar**

Bitte Fehlermeldungen zu Wortsturz direkt an mich.
Der Fehler (Programm beendet sich sofort) liegt an dem letzten @crlf in der Wortliste.

Bitte die aktuelle Version (1.3) von "Wortsturz" benutzen! Die 0.9 war nur eine Vorab-Version.

**Alina**

Mathe Trainer --> Prifi --> Arbeit schreiben
Hier ist ein Fehler. Teste es mal. Ist irgendwie ein Funktionsfehler auf Line -1

Commander21

Die Funktion ist ja auch noch nicht fertig.
Arbeite aber bald weiter daran...

FunH@cker

hey hat jemand ma ein skript geschieben das internet seiten sperrt oder so was ?
Da ich das sehr nützlich finde
Sonst versuch ich ma damit anzufangen ,wenn noch niemand was dafür hat

Sithlord95

hi ich hätte ne idee
wie wärs mit nem geographie spiel(ich mag erdkunde zwar nicht aber sowas gehört ja zum allgemein wissen)
also zum beispiel wo man die großen länder in europa eintragen muss
oder zum beispiel die bundesländer

und wie wärs mit nem spiel wo man mit dem mauszeiger bestimmten linien folgen muss wenn man daneben geht piept es?
also zumbeispiel das man einer gui nachfährt ... so nachdem schema is zwarn och keien gui dabei aber nur zu verdeutlichung

[autoit]

while 1
$pos = mousegetpos()
$Pixel = pixelgetcolor($pos[0],$pos[1])
if $Pixel = 16777215 Then
beep(1000,200)
EndIf
Sleep(50)
WEnd

[/autoit]

leider bin ich momentan noch mit dem autoit task manager beschäftigt
aber falls einer lust hat das zu verwirklichen und keien eigene idee hat ,nur zu^^

mfg

**Oscar**

Ich hatte mal angefangen mit einem embedded IE und einer Blacklist:

Spoiler anzeigen

[autoit]

#include<StaticConstants.au3>
#include<GuiStatusBar.au3>
#include<EditConstants.au3>
#include<GUIConstantsEx.au3>
#include<IE.au3>
#include<WindowsConstants.au3>
Global Const $WS_EX_COMPOSITED = 0x2000000

[/autoit] [autoit][/autoit] [autoit]

$oIE = _IECreateEmbedded()

[/autoit] [autoit][/autoit] [autoit]

$hGui = GUICreate('IE-Kontrolle', 1024, 768, -1, -1, BitOr($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_SIZEBOX, $WS_CLIPCHILDREN), $WS_EX_COMPOSITED)
GUISetBkColor(0xDDDDDD)

[/autoit] [autoit][/autoit] [autoit]

GUICtrlCreateLabel('Adresse', 4, 27, 55, 20, $SS_RIGHT)
GUICtrlSetFont(-1, 9, 400, 0, 'Verdana')
GUICtrlSetColor(-1, 0x888888)
GUICtrlSetResizing(-1, $GUI_DOCKALL)

[/autoit] [autoit][/autoit] [autoit]

$hURL = GUICtrlCreateInput('', 64, 25, 948, 20, $ES_WANTRETURN, $WS_EX_STATICEDGE)
GUICtrlSetFont(-1, 9, 400, 0, 'Arial')
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKRIGHT+$GUI_DOCKTOP+$GUI_DOCKHEIGHT)

[/autoit] [autoit][/autoit] [autoit]

GUICtrlCreateObj($oIE, 0, 48, 1024, 696)
GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)

[/autoit] [autoit][/autoit] [autoit]

$hStatus = _GUICtrlStatusBar_Create($hGUI)
_GUICtrlStatusBar_SetText($hStatus, 'Fertig.')
_IENavigate($oIE, 'about:blank')
GUISetState()
GUIRegisterMsg($WM_SIZE, 'WM_SIZE')
ControlFocus($hGui, '', $hURL)
Global $oldURL = 'about:blank'
Global $aBadURL[5] = ['www.google.de','www.ebay.de','','',''] ; hier alle zu sperrenden URLs eintragen (Blacklist)
While True
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
Case $hURL
$sURL = StringReplace(GUICtrlRead($hURL), 'http://', '')
_IENavigate($oIE, $sURL, 0)
EndSwitch
$sURL = _IEPropertyGet($oIE, "locationurl")
If StringLeft($sURL, 7) <> 'http://' Then $sURL = 'http://' & $sURL
If StringRight($sURL, 1) <> '/' Then $sURL &= '/'
$aURL = StringRegExp($sURL, '(http://){1}(.+?)/', 3)
If IsArray($aURL) Then
If $aURL[1] <> $oldURL Then
$oldURL = $aURL[1]
$bCheck = True
_GUICtrlStatusBar_SetText($hStatus, 'Bitte warten...')
If $aURL[1] <> 'about:blank' Then
TCPStartup()
$sIP = TCPNameToIP($aURL[1])
TCPShutdown()
Else
$sIP = ''
EndIf
If $sIP <> '' Then
TCPStartup()
For $i = 0 To UBound($aBadURL)-1
If $sIP = TCPNameToIP($aBadURL[$i]) Then
Beep(400, 200)
_GUICtrlStatusBar_SetText($hStatus, 'Diese Seite darfst Du nicht aufrufen!')
GUICtrlSetData($hURL, '')
_IENavigate($oIE, 'about:blank')
$bCheck = False
ControlFocus($hGui, '', $hURL)
Sleep(1000)
ExitLoop
EndIf
Next
TCPShutdown()
If $bCheck Then
If StringLeft($aURL[1], 7) <> 'http://' Then
$sURL = 'http://' & $aURL[1]
GUICtrlSetData($hURL, $aURL[1])
EndIf
_IENavigate($oIE, $aURL[1])
If @error Then
Beep(400, 200)
_GUICtrlStatusBar_SetText($hStatus, 'Beim laden der Seite ist ein Fehler aufgetreten!')
Else
_GUICtrlStatusBar_SetText($hStatus, 'Fertig.')
EndIf
EndIf
ElseIf $aURL[1] <> 'about:blank' Then
Beep(400, 200)
_GUICtrlStatusBar_SetText($hStatus, 'Diese Seite existiert nicht!')
Else
_GUICtrlStatusBar_SetText($hStatus, 'Fertig.')
EndIf
EndIf
EndIf
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func WM_SIZE($hWnd, $iMsg, $iwParam, $ilParam)
_GUICtrlStatusBar_Resize($hStatus)
Return $GUI_RUNDEFMSG
EndFunc

[/autoit]

Habe das Projekt aber aufgegeben. Vielleicht kannst Du ja Teile davon gebrauchen.
Für die ganz Kleinen wäre wohl eine Whitelist auch besser geeignet. Blacklist macht viel Arbeit beim zusammentragen und pflegen der URLs. Inidatei wäre vermutlich auch besser, als das im obigen Script verwendete Array.

Der Grund für die Aufgabe des Projekts war aber, das eine browserbasierte Filterung nicht so wirklich funktioniert. Man müsste das dann schon universell für alle Browser programmieren, weil es sonst schon reichen würde einen anderen Browser zu installieren. Besser wäre eine tiefer ansetzende Lösung auf TCP-Ebene. Würde im Prinzip auf einen Proxy rauslaufen. Weiß aber nicht, ob AutoIt dafür dann so die geeignete Programmiersprache ist?!

Lololo124

Wen ich mehr zeit habe(schule beginnt am montag ja wieder und da muss ich noch n paar dinge erledigen) setz ich mich mal an die idee von SithLord.
Gruß Roggazzz

ScripterDrîzzt

falls noch i-wo hilfe benötigt ist würde ich mich hier bereit erklären sagt mir einfach per PN bescheid =)

GerhardSchr

hi
ich hatte mal im forum eine Kindersicherung gefunden, wenn man die noch ein bisschen anpasst, z.B. mit entsprechender Uhrzeit, dann ist das eventuell nicht mehr so viel arbeit

Gruß GerhardSchr