Drucken

Reaker

hallo..wie kann ich folgende listview so wie sie ist ausdrucken?

würde das zb über screenshot funktionieren?

Spoiler anzeigen

[autoit]

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Values(6)", 326, 331, 224, 184)
$ListView1 = GUICtrlCreateListView("value 1|value 2|value 3|value 4|value 5|value 6", 4, 4, 309, 265)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 3, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 4, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 5, 50)
$ListView1_0 = GUICtrlCreateListViewItem("1|12|4|45", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("2|12", $ListView1)
$ListView1_2 = GUICtrlCreateListViewItem("3|12||4", $ListView1)
$ListView1_3 = GUICtrlCreateListViewItem("4|12", $ListView1)
$ListView1_4 = GUICtrlCreateListViewItem("5|12", $ListView1)
$ListView1_5 = GUICtrlCreateListViewItem("6|12", $ListView1)
$print = GUICtrlCreateButton("Print", 28, 284, 101, 25, $WS_GROUP)
$close = GUICtrlCreateButton("close", 180, 284, 105, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $close
Exit
Case $print
;drucken
EndSwitch
WEnd

[/autoit]

Faweyr

Na du könntest das ganze in einer txt abspeichern und dann drucken, hab auch lange für mein Projekt was versucht zu drucken (Adressbuch by Faweyr andere Art kenn ich auch nicht.

Reaker

ja das habe ich mir auch schon so als notlösung gedacht, aber es wäre halt wichtig das so als tabelle darzustellen

**autoBert**

hallo reaker,

wenn du deine Tabelle in einer HTML-Datei speicherst, kannst du diese über den IE ausdrucken siehe [gelöst] Ausdrucken von Gui-Listen,

mfg (Auto)Bert

**funkey**

Druckt die Gui so wie sie ist.

[autoit]

#include <PrintWinAPI.au3>
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Values(6)", 326, 331, 224, 184)
$ListView1 = GUICtrlCreateListView("value 1|value 2|value 3|value 4|value 5|value 6", 4, 4, 309, 265)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 3, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 4, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 5, 50)
$ListView1_0 = GUICtrlCreateListViewItem("1|12|4|45", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("2|12", $ListView1)
$ListView1_2 = GUICtrlCreateListViewItem("3|12||4", $ListView1)
$ListView1_3 = GUICtrlCreateListViewItem("4|12", $ListView1)
$ListView1_4 = GUICtrlCreateListViewItem("5|12", $ListView1)
$ListView1_5 = GUICtrlCreateListViewItem("6|12", $ListView1)
$print = GUICtrlCreateButton("Print", 28, 284, 101, 25, $WS_GROUP)
$close = GUICtrlCreateButton("close", 180, 284, 105, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $close
Exit
Case $print
_Print()
EndSwitch
WEnd

[/autoit] [autoit][/autoit] [autoit]

;http://www.autoitscript.com/forum/index.php?showtopic=78757
Func _Print()
Local $WM_PRINT = 0x317
Local $PRF_CHILDREN = 0x10; Draw all visible child windows.
Local $PRF_CLIENT = 0x4 ; Draw the window's client area.
Local $PRF_OWNED = 0x20 ; Draw all owned windows.
Local $PRF_NONCLIENT = 0x2 ; Draw the window's Title area.
Local $PRF_ERASEBKGND = 0x8 ; Erases the background before drawing the window

[/autoit] [autoit][/autoit] [autoit]

Local $hWnd = WinGetHandle("Values(6)")
Local $pos = WinGetPos("Values(6)")

[/autoit] [autoit][/autoit] [autoit]

_GDIPlus_Startup()
Local $Width = $pos[2]
Local $Height = $pos[3]

[/autoit] [autoit][/autoit] [autoit]

Local $hDC = _WinAPI_GetDC($hWnd)
Local $memDC = _WinAPI_CreateCompatibleDC($hDC)
Local $memBmp = _WinAPI_CreateCompatibleBitmap($hDC, $Width, $Height)
_WinAPI_SelectObject($memDC, $memBmp)

[/autoit] [autoit][/autoit] [autoit]

Local $Ret = _SendMessage($hWnd, $WM_PAINT, $memDC, 0)
$Ret = _SendMessage($hWnd, $WM_PRINT, $memDC, BitOR($PRF_CHILDREN, $PRF_CLIENT, $PRF_OWNED, $PRF_NONCLIENT, $PRF_ERASEBKGND))

[/autoit] [autoit][/autoit] [autoit]

Local $hImage = _GDIPlus_BitmapCreateFromHBITMAP($memBmp)

[/autoit] [autoit][/autoit] [autoit]

;Get Default Printer
Local $s_PrinterName = _GetDefaultPrinter()

[/autoit] [autoit][/autoit] [autoit]

; Create a printer device context
Local $hPrintDc = _WinAPI_CreateDC("winspool", $s_PrinterName)
Local $hGraphic = _GDIPlus_GraphicsCreateFromHDC($hPrintDc)

[/autoit] [autoit][/autoit] [autoit]

; get pixel and twips info
Local $PixelsPerInchY = _WinAPI_GetDeviceCaps($hPrintDc, $__WINAPCONSTANT_LOGPIXELSY); Get Pixels Per Inch Y
Local $TwipsPerPixelY = 1440 / $PixelsPerInchY
Local $PixelsPerInchX = _WinAPI_GetDeviceCaps($hPrintDc, $__WINAPCONSTANT_LOGPIXELSX); Get Pixels Per Inch X
Local $TwipsPerPixelX = 1440 / $PixelsPerInchX

[/autoit] [autoit][/autoit] [autoit]

; get page width and height
Local $PageWidth = _WinAPI_GetDeviceCaps($hPrintDc, $HORZRES); Get width, in millimeters, of the physical screen
Local $PageHeight = _WinAPI_GetDeviceCaps($hPrintDc, $VERTRES); Get height, in millimeters, of the physical screen.

[/autoit] [autoit][/autoit] [autoit]

; set docinfo
Local $s_DocName = "Printing from AutoIt with WinAPI"
Local $DocName = DllStructCreate("char DocName[" & StringLen($s_DocName & Chr(0)) & "]")
DllStructSetData($DocName, "DocName", $s_DocName & Chr(0)); Size of DOCINFO structure
Local $DOCINFO = DllStructCreate($tagDOCINFO); Structure for Print Document info
DllStructSetData($DOCINFO, "Size", 20); Size of DOCINFO structure
DllStructSetData($DOCINFO, "DocName", DllStructGetPtr($DocName)); Set name of print job (Optional)

[/autoit] [autoit][/autoit] [autoit]

; start new print doc
Local $result = _WinAPI_StartDoc($hPrintDc, $DOCINFO)
; start new page
$result = _WinAPI_StartPage($hPrintDc)

[/autoit] [autoit][/autoit] [autoit]

; Draw one image in another
_GDIPlus_GraphicsDrawImageRect($hGraphic, $hImage, 50, 100, $Width, $Height)
; Draw a frame around the inserted image
_GDIPlus_GraphicsDrawRect($hGraphic, 50, 100, $Width, $Height)
; ------------------------ End of Story -----------------------
; End the page
$result = _WinAPI_EndPage($hPrintDc)
; End the print job
$result = _WinAPI_EndDoc($hPrintDc)
; Delete the printer device context
_WinAPI_DeleteDC($hPrintDc)
; End Rest of Resources
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_ImageDispose($hImage)
_WinAPI_ReleaseDC($hWnd, $hDC)
_WinAPI_DeleteDC($memDC)
_WinAPI_DeleteObject($memBmp)
_GDIPlus_Shutdown()
EndFunc ;==>_Print

[/autoit] [autoit][/autoit] [autoit]

;------------------------------ Get Default printer --------------------------------
Func _GetDefaultPrinter()
Local $szDefPrinterName
Local $Size
Local $namesize = DllStructCreate("dword")
DllCall("winspool.drv", "int", "GetDefaultPrinter", "str", '', "ptr", DllStructGetPtr($namesize))
Local $pname = DllStructCreate("char[" & DllStructGetData($namesize, 1) & "]")
DllCall("winspool.drv", "int", "GetDefaultPrinter", "ptr", DllStructGetPtr($pname), "ptr", DllStructGetPtr($namesize))
Return DllStructGetData($pname, 1);msgbox(0,dllstructgetdata($namesize,1),DllStructGetData($pname,1))
EndFunc ;==>_GetDefaultPrinter
#EndRegion

[/autoit]

Reaker

mit dieser printwinapi ist das ergebnis schonmal nicht schlecht, macht nicht viel arbeit und schaut gut aus, allerdings wie bekomme ich das hin dass nur die listview gedruckt wird?

mit html ist so ne sache, ist halt unheimlich kompliziert das darüber zu machen, habs versucht aber bin noch net wirklich weit, da ich die kompletten tabellen codes erst neu lernen muss

nuts

Sehr cool, lässt sich das auf einzelne Controls beschränken?

**autoBert**

Hallo nuts,

habs zwar nicht getestet aber wenn du im obigen Skript von funkey die Zeilen gegen

[autoit]

Local $hWnd = ControlGetHandle("Values(6)","",$ListView1)
Local $pos = ControlGetPos("Values(6)","",$ListView1)

[/autoit]

austauschst sollte es klappen, dass nur die Listview ausgedruckt wird,

mfg (Auto)Bert

nuts

Hey,

ja danke soweit war ich auch gerade
fehlt noch eine Funktion um das ganze Listview zu erfassen, sollten zuviele Items eingetragen sein.

1. Möglichkeit ein virtuelles Listview mit entsprechend kleiner Schritt
Ist nicht schwer, sieht allerdings irgendwann blöd aus.

Könnte man dann quasi einen Zoom einbauen und seitenübergreifend drucken?

**funkey**

Für lange Listen würde ich _FilePrint bevorzugen

Spoiler anzeigen

[autoit]

#include <GuiListView.au3>
#include <File.au3>
#include <string.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Values(6)", 326, 331, 224, 184)
$ListView1 = GUICtrlCreateListView("value 1|value 2|value 3|value 4|value 5|value 6", 0, 0, 309, 265)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 3, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 4, 50)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 5, 50)
$ListView1_0 = GUICtrlCreateListViewItem("1|12|4|45", $ListView1)
$ListView1_1 = GUICtrlCreateListViewItem("2|12", $ListView1)
$ListView1_2 = GUICtrlCreateListViewItem("3|12||4", $ListView1)
$ListView1_3 = GUICtrlCreateListViewItem("4|12", $ListView1)
$ListView1_4 = GUICtrlCreateListViewItem("5|12", $ListView1)
$ListView1_5 = GUICtrlCreateListViewItem("6|12", $ListView1)
$print = GUICtrlCreateButton("Print", 28, 284, 101, 25, $WS_GROUP)
$close = GUICtrlCreateButton("close", 180, 284, 105, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $close
Exit
Case $print
_Print_LV($ListView1)
EndSwitch
WEnd
Exit

[/autoit] [autoit][/autoit] [autoit]

Func _Print_LV($hListView)
;funkey
Local $iMaxAnzahl = 7, $aColumn
Local $iItems = _GUICtrlListView_GetItemCount($hListView)
Local $iColumns = _GUICtrlListView_GetColumnCount($hListView)
Local $file = @ScriptDir & "\listview.txt"
If FileExists($file) Then FileDelete($file)
FileWriteLine($file, _StringRepeat('-', $iMaxAnzahl * $iColumns + $iColumns + 1))
FileWrite($file, '|')
For $y = 0 To $iColumns - 1
$aColumn = _GUICtrlListView_GetColumn($hListView, $y)
FileWrite($file, StringFormat("%" & $iMaxAnzahl & "s", $aColumn[5]) & '|')
Next
FileWrite($file, @CRLF & '|')
For $i = 0 To $iColumns - 1
FileWrite($file, _StringRepeat('-', $iMaxAnzahl) & '|')
Next
FileWrite($file, @CRLF)
For $x = 0 To $iItems - 1
FileWrite($file, '|')
For $y = 0 To $iColumns - 1
FileWrite($file, StringFormat("%" & $iMaxAnzahl & "s", _GUICtrlListView_GetItemText($hListView, $x, $y)) & '|')
Next
FileWrite($file, @CRLF)
Next
FileWriteLine($file, _StringRepeat('-', $iMaxAnzahl * $iColumns + $iColumns + 1))
$print = _FilePrint($file)
EndFunc ;==>_Print_LV

[/autoit]

nuts

Ist was dran.
Dazu müsste man mal eine UDF basteln, _Printfrom_List() mit Übertrag usw.

Mit html gibts wohl bessere Formatierungsmöglichkeiten, ist dafür aber aufwendiger.
Hast sowas schon jemand im Archiv? Sonst versuche ich mich mal daran.

nuts

Hab mal den Anfang und ein Testbeispiel gemacht.
Es muss noch die Gesamtbreite, die Spaltenbreite und der Übertrag mit einbezogen werden.
Bin dran, nur html ist schon strange :wacko:

Spoiler anzeigen

[autoit]

#include<WindowsConstants.au3>
#include<ListViewConstants.au3>
#include<ButtonConstants.au3>
#include<GUIConstantsEx.au3>
#include<Guilistview.au3>
#include<File.au3>
#include<Array.au3>

[/autoit] [autoit][/autoit] [autoit]

Global $sHeader = "Artikelnummer|Art|Nummer|Baureihe|Name|+1" ; Die Überschriften für das Listview und für das "Neuer Eintrag"-Fenster
Global $sDBFile = @ScriptDir & "\datenbank.html" ; Pfad und Name der Datenbank-Datei
If not FileExists($sDBFile) Then _FileCreate($sDBFile)

[/autoit] [autoit][/autoit] [autoit]

;global $open = Fileopen($sDBFile,2)
;ConsoleWrite(_ArrayToHTMLTable($a,true,false))
;_FileWriteFromArray($sDBFile,_ArrayToHTMLTable($a,true,false))
;FileWrite($open, _ArrayToHTMLTable($a,true,true))
;MsgBox(1, "",_ArrayToHTMLTable($a,true,true))

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

#Region Hauptfenster
Global $hGui = GUICreate("Listview-Datenbank-Beispiel", 600, 480) ; Hauptfenster erstellen
Global $hListView = GUICtrlCreateListView($sHeader, 0, 0, 600, 420, $LVS_SHOWSELALWAYS) ; Listview erstellen

[/autoit] [autoit][/autoit] [autoit]

Global $hLVHandle = GUICtrlGetHandle($hListView) ; das Handle vom Listview wird für die UDF-Listview-Funktionen benötigt
_GUICtrlListView_SetColumn($hLVHandle, 0, "Artikelnummer", 120, 0)
_GUICtrlListView_SetColumn($hLVHandle, 1, "Art", 60, 0)
_GUICtrlListView_SetColumn($hLVHandle, 2, "Nummer", 90, 0)
_GUICtrlListView_SetColumn($hLVHandle, 3, "Baureihe", 100, 0)
_GUICtrlListView_SetColumn($hLVHandle, 4, "Name", 120, 0)
_GUICtrlListView_SetColumn($hLVHandle, 5, "+1", 12, 0)

[/autoit] [autoit][/autoit] [autoit]

[/autoit] [autoit][/autoit] [autoit]

GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg(1) ; Message-Event holen (1) = erweiterter Modus
Switch $nMsg[0] ; anhand der Control-ID das entsprechende Case aufrufen

[/autoit] [autoit][/autoit] [autoit]

Case $hNew
local $array = _Listviewtoarray($hLVHandle)
_ArrayDisplay($array)
_test($array)

[/autoit] [autoit][/autoit] [autoit]

Case $GUI_EVENT_CLOSE ; User hat auf das Schließen-Symbol geklickt (bzw. die ESC-Taste gedrückt)
Switch $nMsg[1] ; erweiterte Abfrage für welches Fenster
Case $hGui ; User will das Hauptfenster schließen
Exit
EndSwitch
EndSwitch
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _Listviewtoarray($hwnd)
local $col, $getcol, $lcount, $atext, $counter = 1
$col = _GUICtrlListView_GetColumnCount($hwnd)
$lcount = _GUICtrlListView_GetItemCount($hwnd)
local $alistview [$lcount+1][$col]
for $y = 0 to $col-1
$getcol= _GUICtrlListView_GetColumn($hwnd, $y)
$alistview[0][$y] = $getcol[5]
next
for $i= 0 to $lcount -1
$atext = _GUICtrlListView_GetItemTextArray($hwnd,$i)
for $x = 0 to $atext[0] -1
$alistview[$counter][$x] = $atext[$x+1]
next
$counter += 1
next
return $alistview
$counter = 1
endfunc

[/autoit] [autoit][/autoit] [autoit]

func _test($array)
local $open = Fileopen($sDBFile,2)
local $html = _ArrayToHTMLTable($array,true,true)
FileWrite($open, $html)
fileclose($open)
endfunc

[/autoit] [autoit][/autoit] [autoit]

; #FUNCTION# ===================================================================
; Name ..........: _ArrayToHTMLTable
; Description ...: Creates a HTML-table from a 2dim-array
; AutoIt Version : V3.3.0.0
; Syntax ........: _ArrayToHTMLTable(ByRef $aArray[, $bHeader = True[, $bBorder = True[, $sStyle = 'width:100%']]])
; Parameter(s): .: $aArray -
; $bHeader - Optional: (Default = True) :
; $bBorder - Optional: (Default = True) :
; $sStyle - Optional: (Default = width: 100%) : StyleSheet
; Return Value ..: Success - string
; Failure - empty string
; @ERROR -
; Author(s) .....: Thorsten Willert
; Modified ......: Nuts (http://www.autoit.de)
; Date ..........: Wed Jul 01 18:07:39 CEST 2009
; Version .......: 1.0
; ==============================================================================
Func _ArrayToHTMLTable(ByRef $aArray, $bHeader = True, $bBorder = True, $sStyle = 'width:100%')
Local $iD1 = UBound($aArray,1)
If @error Then
SetError(1)
Return ''
EndIf
Local $iD2 = UBound($aArray,2)
If @error Then
SetError(1)
Return ''
EndIf

[/autoit] [autoit][/autoit] [autoit]

Local $sTable = ""
If $sStyle <> '' Then $sStyle = ' style="' & $sStyle & '"'
$sStyle &= '>'

[/autoit] [autoit][/autoit] [autoit]

If $bBorder Then
$sTable &= '<table border="1"'
Else
$sTable &= '<table'
EndIf
$sTable &= $sStyle & @CRLF

[/autoit] [autoit][/autoit] [autoit]

Local $iStart = 0
If $bHeader Then
$iStart = 1
$sTable &= '<tr>' & @CRLF
For $i = 0 To $iD2 -1
$sTable &= @TAB & '<th align="left">' & $aArray[0][$i] & '</th>' & @CRLF
Next
$sTable &= '</tr>' & @CRLF
EndIf

[/autoit] [autoit][/autoit] [autoit]

For $i = $iStart To $iD1 -1
$sTable &= '<tr>' & @CRLF
For $j = 0 To $iD2 -1
$sTable &= @TAB & '<td>' & $aArray[$i][$j] & '</td>' & @CRLF
Next
$sTable &= '</tr>' & @CRLF
Next

[/autoit] [autoit][/autoit] [autoit]

$sTable &= '</table>' & @CRLF

[/autoit] [autoit][/autoit] [autoit]

Return $sTable
EndFunc ;==> _ArrayToHTMLTable

[/autoit]

**Andy**

Hi,
wäre es nicht einfacher die Liste in eine Tabellenkalkulation zu kopieren und von dort aus auszudrucken ?

nuts

Ist aber dann nicht universal einsetzbar.

Keine Tabellenkalkulation auf dem Pc, keine Druckfunktion.

**Andy**

Zitat

Keine Tabellenkalkulation auf dem Pc, keine Druckfunktion.

Andersrum wird ein Schuh draus, WENN Tabellenkalkulation auf dem PC, DANN sind nahezu alle Möglickeiten der Darstellung der Tabelle möglich, incl Drucken, Diagramme, PDF, XML, und auch ggf HTML^^

Ich glaube kaum, daß man über eine "einfache" HTML-Tabelle auch nur annähernd die Ausgabemöglichkeiten hat.
Wäre mal eine Anwendung für meine OpenOffice-UDF schöne Idee!

nuts

Dem stimme ich im Prinzip zu (html schaff mich auch grad voll, wird wohl nur was ganz einfaches ).
Trotzdem sollte es eine Funktion werden, die ohne Fremdsoftware auskommt.
Wenn jemand eine bessere Idee als html hat, nur her damit.

edit \ Wie wärs wenn du ein Bsp. mit deiner OpenOffice UDF machst und ich quäle html noch ein bisschen?

**Andy**

Zitat

Wie wärs wenn du ein Bsp. mit deiner OpenOffice UDF machst und ich quäle html noch ein bisschen

Gute Idee^^