Bild bewegen

Freaky

Hallo,
ich will ein Spiel aus langeweile schreiben und stoße schon an ein Problem.
Wenn ich mit meinem Raumschiff schiesen will, dann fliegt die kugel nach oben, und wenn ich dann nochmal schiesen will dann bleibt die stehen und die neu fliegt weiter oder die erste Kugel fliegt zu Ende und die neue Kugel wartet auf die davor und fliegt erst weiter wenn die erste weg ist.
Wie krige ich nun hin das die sofort hintereinander fliegen ?

Spoiler anzeigen

[autoit]

#include <Array.au3>
#include <Misc.au3>
#include <GUIConstantsEx.au3>
Global $timer = 0
Global $schusse[1], $schuss[2]

[/autoit] [autoit][/autoit] [autoit]

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Spiel", 633, 447)
GUISetBkColor(0x000000)
$raumschiff = GUICtrlCreatePic(@ScriptDir & "\img\raumschiff.jpg", 10, 410, 50, 30)
$schuss[1] = GUICtrlCreatePic(@ScriptDir & "\img\schuss.JPG", 33, 393, 5, 15)
GUICtrlSetState (-1,$GUI_HIDE)
$gegner = GUICtrlCreatePic("", 40, 64, 52, 28)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
If _IsPressed(20) Then
While _IsPressed(20)
Sleep(100)
WEnd
For $i = 1 To UBound($schuss) - 1
If GUICtrlGetState($schuss[$i]) <> 80 Then
GUICtrlSetState($schuss[$i], $GUI_SHOW)
$timer = TimerInit()
Else
$schuss[$i] = GUICtrlCreatePic(@ScriptDir & "\img\schuss.JPG", 33, 393, 5, 15)
_ArrayAdd($schuss, "")
_ArrayAdd($schusse, "")
EndIf
Next
EndIf
For $i = 1 To UBound($schusse) - 1
If GUICtrlGetState($schuss[$i]) = 80 Then
If TimerDiff($timer) >= 100 Then
$schuss_pos = ControlGetPos($Form1, "", $schuss[$i])
GUICtrlSetPos($schuss[$i], $schuss_pos[0], $schuss_pos[1] - 17)
If $schuss_pos[1] <= 0 Then
GUICtrlSetPos($schuss[$i], $schuss_pos[0], 393)
GUICtrlSetState($schuss[$i], $GUI_HIDE)
GUICtrlDelete($schuss[$i])
_ArrayDelete($schuss, "")
_ArrayDelete($schusse, "")
EndIf
$timer = TimerInit()
EndIf
EndIf
Next
ToolTip(UBound($schuss) & @CRLF & UBound($schusse), 0, 0)
WEnd

[/autoit]

name22

Ok hier ein kleiner Tipp am Rande: Mach das mit GDI+

Freaky

Ne, will das so machen

name22

Dann sieht es doof aus

Also im Moment funktioniert in deinem Script ja gar nichts
Du könntest wenigstens die Bilder anhängen...

Freaky

Habe die Bilder angehengt

name22

Bei mir tut sich nichts egal wie oft ich die Leertaste drücke.^^

Freaky

Entfern mal Else in Zeile 31

name22

Und jetzt. Es geht immer noch nicht.^^
Hattest du schon ein funktionierendes Script?

Freaky

Bei mir geht genau das
Das geht bei mir:

Spoiler anzeigen

[autoit]

#include <Array.au3>
#include <Misc.au3>
#include <GUIConstantsEx.au3>
Global $timer = 0
Global $schusse[1], $schuss[2]

[/autoit] [autoit][/autoit] [autoit]

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Spiel", 633, 447)
GUISetBkColor(0x000000)
$raumschiff = GUICtrlCreatePic(@ScriptDir & "\img\raumschiff.jpg", 10, 410, 50, 30)
$schuss[1] = GUICtrlCreatePic(@ScriptDir & "\img\schuss.JPG", 33, 393, 5, 15)
GUICtrlSetState (-1,$GUI_HIDE)
$gegner = GUICtrlCreatePic("", 40, 64, 52, 28)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
If _IsPressed(20) Then
While _IsPressed(20)
Sleep(100)
WEnd
For $i = 1 To UBound($schuss) - 1
If GUICtrlGetState($schuss[$i]) <> 80 Then
GUICtrlSetState($schuss[$i], $GUI_SHOW)
$timer = TimerInit()
$schuss[$i] = GUICtrlCreatePic(@ScriptDir & "\img\schuss.JPG", 33, 393, 5, 15)
_ArrayAdd($schuss, "")
_ArrayAdd($schusse, "")
EndIf
Next
EndIf
For $i = 1 To UBound($schusse) - 1
If GUICtrlGetState($schuss[$i]) = 80 Then
If TimerDiff($timer) >= 100 Then
$schuss_pos = ControlGetPos($Form1, "", $schuss[$i])
GUICtrlSetPos($schuss[$i], $schuss_pos[0], $schuss_pos[1] - 17)
If $schuss_pos[1] <= 0 Then
GUICtrlSetPos($schuss[$i], $schuss_pos[0], 393)
GUICtrlSetState($schuss[$i], $GUI_HIDE)
GUICtrlDelete($schuss[$i])
_ArrayDelete($schuss, "")
_ArrayDelete($schusse, "")
EndIf
$timer = TimerInit()
EndIf
EndIf
Next
ToolTip(UBound($schuss) & @CRLF & UBound($schusse), 0, 0)
WEnd

[/autoit]

name22

Ich bin vielleicht doof...
Ich hab jetzt erst gesehen, dass du bei den Pfaden noch ein img davor gesetzt hast.
Ich dachte zuerst, dass wird ein größeres Projekt, da ich Begriffe wie Raumschiff o.Ä. gelesen habe. Deswegen habe ich dir auch GDI+ empfohlen...

~~Wieso verwendest du eigentlich Arrays, wenn man sowieso nur einen Schuss abgeben kann solange der andere nicht verschwunden ist?~~
Ach so das ist ja gar nicht gewollt. :wacko:

Ich glaube immer noch, dass das einfacher in GDI+ zu realisieren ist... Wenn du möchtest könnte ich dir dabei helfen.

Freaky

Ich will ja mehrer Schüsse abgeben
Er soll Max 5 Schüsse abgeben aber ich kriege nichtmal 2 hin

Über das Forum könnte das glaube ich nichts werden
Wennschon dann über ICQ da kann ich dir 12345678 Fragen stellen ohne immer ein Post zu machen :D:D:D:D:D

name22

Tadaaa
Nur um zu zeigen, dass GDI+ dafür besser geeignet ist.

Spoiler anzeigen

[autoit]

#include <GDIPlus.au3>
#include <GUIConstants.au3>
#include <Misc.au3>

[/autoit] [autoit][/autoit] [autoit]

$iGUIWidth = 400
$iGUIHeight = 400
$GUIColorBG = 0xFF000000

[/autoit] [autoit][/autoit] [autoit]

$iShots = 0
$iMaxShots = 5
$iShotSpeed = 5
$iCoolDownTime = 500
$iTimerShot = $iCoolDownTime * - 1

[/autoit] [autoit][/autoit] [autoit]

$hWnd = GUICreate("Test", $iGUIWidth, $iGUIHeight)
GUISetState()

[/autoit] [autoit][/autoit] [autoit]

_GDIPlus_Startup()

[/autoit] [autoit][/autoit] [autoit]

$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hWnd)
$hBitmap = _GDIPlus_BitmapCreateFromGraphics($iGUIWidth, $iGUIHeight, $hGraphic)
$hBuffer = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsSetSmoothingMode($hBuffer, 2)
_GDIPlus_GraphicsClear($hGraphic, $GUIColorBG)

[/autoit] [autoit][/autoit] [autoit]

$hImage_Ship = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\Raumschiff.jpg")
$hBrush_Shot = _GDIPlus_BrushCreateSolid(0xFFFFFFFF)

[/autoit] [autoit][/autoit] [autoit]

Dim $aShot[2][2]

[/autoit] [autoit][/autoit] [autoit]

$iX_Ship = $iGUIWidth / 2 - 25
$iY_Ship = $iGUIHeight - 30

[/autoit] [autoit][/autoit] [autoit]

AdlibRegister("_ReDraw", 20)

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
AdlibUnRegister()
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_GraphicsDispose($hBuffer)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_ImageDispose($hImage_Ship)
_GDIPlus_BrushDispose($hBrush_Shot)
_GDIPlus_Shutdown()
Exit
EndSwitch
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _ReDraw()
If _IsPressed("27") And $iX_Ship > 0 Then $iX_Ship += 2
If _IsPressed("25") And $iX_Ship < $iGUIWidth Then $iX_Ship -= 2
If _IsPressed("20") And TimerDiff($iTimerShot) >= $iCoolDownTime And UBound($aShot) < $iMaxShots Then
_Array2DAdd($aShot, $iX_Ship + 23 & "|" & $iY_Ship - 10)
$iTimerShot = TimerInit()
EndIf

[/autoit] [autoit][/autoit] [autoit]

_GDIPlus_GraphicsClear($hBuffer, $GUIColorBG)
For $i = 1 To UBound($aShot) - 1
If $aShot[$i][1] <> "" Then
_GDIPlus_GraphicsFillRect($hBuffer, $aShot[$i][0], $aShot[$i][1], 5, 10, $hBrush_Shot)
$aShot[$i][1] -= $iShotSpeed
EndIf
Next
For $i = 1 To UBound($aShot) - 1
If $aShot[$i][1] <= 0 Then
_Array2DDelete($aShot, $i)
ExitLoop
EndIf
Next
_GDIPlus_GraphicsDrawImageRect($hBuffer, $hImage_Ship, $iX_Ship, $iY_Ship, 50, 30)
_GDIPlus_GraphicsDrawImageRect($hGraphic, $hBitmap, 0, 0, $iGUIWidth, $iGUIHeight)
EndFunc ;==>_ReDraw

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

;------------------------------------------------------------------------------------------------------------
;
; Function _Array2DAdd(ByRef $avArray, $sValue='')
;
; Description Redim Array Size and add an Array element at last position
; Works with any occurences in 2nd Dimension
; Works also with 1D-Array
;
; Parameter $avArray Given Array
; optional $sValue Value of new Element, parts must be seperate with '|'
;
; Return Succes -1
; Failure 0 and set @error
; @error = 1 given array is not array
; @error = 2 given parts of Element too less/much
;
; Author BugFix ([email='bugfix@autoit.de'][/email])
;------------------------------------------------------------------------------------------------------------
Func _Array2DAdd(ByRef $avArray, $sValue='')
If ( Not IsArray($avArray) ) Then
SetError(1)
Return 0
EndIf
Local $i
Local $UBound2nd = UBound($avArray,2)
If @error = 2 Then
ReDim $avArray[UBound($avArray)+1]
$avArray[UBound($avArray)-1] = $sValue
Else
Local $arValue
ReDim $avArray[UBound($avArray)+1][$UBound2nd]
If $sValue = '' Then
For $i = 0 To $UBound2nd-2
$sValue &= '|'
Next
EndIf
$arValue = StringSplit($sValue, '|')
If $arValue[0] <> $UBound2nd Then
SetError(2)
Return 0
EndIf
For $i = 0 To $UBound2nd-1
$avArray[UBound($avArray)-1][$i] = $arValue[$i+1]
Next
EndIf
Return -1
EndFunc ;==>_Array2DAdd

[/autoit] [autoit][/autoit] [autoit]

;----------------------------------------------------------------------------------------------------------------------
; Fuction _Array2DDelete(ByRef $ARRAY, $iDEL)
;
; Description Delete one row on a given index in an 1D/2D -Array
;
; Parameter $ARRAY the array, where one row will deleted
; $iDEL Row-Index to delete
;
; Return Succes -1 ByRef $ARRAY
; Failure 0 set @error = 1; given array are not array
; set @error = 2; index is out of range
;
; Author BugFix ([email='bugfix@autoit.de'][/email])
;----------------------------------------------------------------------------------------------------------------------
Func _Array2DDelete(ByRef $ARRAY, $iDEL)
If ( Not IsArray($ARRAY) ) Then
SetError(1)
Return 0
EndIf
If ( $iDEL < 0 ) Or ( $iDEL > UBound($ARRAY)-1 ) Then
SetError(2)
Return 0
EndIf
Local $i, $k, $l
Local $UBound2nd = UBound($ARRAY,2)
If @error = 2 Then
Local $arTmp[UBound($ARRAY)-1]
$k = 0
For $i = 0 To UBound($ARRAY)-1
If $i <> $iDEL Then
$arTmp[$k] = $ARRAY[$i]
$k += 1
EndIf
Next
Else
Local $arTmp[UBound($ARRAY)-1][$UBound2nd]
$k = 0
For $i = 0 To UBound($ARRAY)-1
If $i <> $iDEL Then
For $l = 0 To $UBound2nd-1
$arTmp[$k][$l] = $ARRAY[$i][$l]
Next
$k += 1
EndIf
Next
EndIf
$ARRAY = $arTmp
Return -1
EndFunc ;==>_Array2DDelete

[/autoit]

Ich hätte schon Lust auf so einen Retro Shooter, aber über die 12345678 Fragen müssen wir noch mal reden.

zocker5656

Ich hab mal ein anderes Raumschiff gebastelt das andere sah irgendwie ein wenig altmodisch aus
[Blockierte Grafik: http://i.imagehost.org/0572/raumschiff.jpg]

name22

Zitat

das andere sah irgendwie ein wenig altmodisch aus

Es ist ja auch ein Retro Shooter

Freaky

Danke für das Raumschiff und für das Script
Leider ist da ein Bug wenn man zu weit nach links geht, kann man nicht mehr nach rechts

So mal gucken was ich alles hinbekomme damit

name22

Ich hatte nur die zwei If Abfragen bei _IsPressed vertauscht
So stimmt es und man kann nicht zur Seite raus:

Spoiler anzeigen

[autoit]

#include <GDIPlus.au3>
#include <GUIConstants.au3>
#include <Misc.au3>

[/autoit] [autoit][/autoit] [autoit]

$iGUIWidth = 400
$iGUIHeight = 400
$GUIColorBG = 0xFF000000

[/autoit] [autoit][/autoit] [autoit]

$iShots = 0
$iMaxShots = 5
$iShotSpeed = 5
$iCoolDownTime = 500
$iTimerShot = $iCoolDownTime * - 1

[/autoit] [autoit][/autoit] [autoit]

$hWnd = GUICreate("Test", $iGUIWidth, $iGUIHeight)
GUISetState()

[/autoit] [autoit][/autoit] [autoit]

_GDIPlus_Startup()

[/autoit] [autoit][/autoit] [autoit]

$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hWnd)
$hBitmap = _GDIPlus_BitmapCreateFromGraphics($iGUIWidth, $iGUIHeight, $hGraphic)
$hBuffer = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsSetSmoothingMode($hBuffer, 2)
_GDIPlus_GraphicsClear($hGraphic, $GUIColorBG)

[/autoit] [autoit][/autoit] [autoit]

$hImage_Ship = _GDIPlus_ImageLoadFromFile(@ScriptDir & "\Raumschiff.jpg")
$hBrush_Shot = _GDIPlus_BrushCreateSolid(0xFFFFFFFF)

[/autoit] [autoit][/autoit] [autoit]

Dim $aShot[2][2]

[/autoit] [autoit][/autoit] [autoit]

$iX_Ship = $iGUIWidth / 2 - 25
$iY_Ship = $iGUIHeight - 30

[/autoit] [autoit][/autoit] [autoit]

AdlibRegister("_ReDraw", 20)

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
AdlibUnRegister()
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_GraphicsDispose($hBuffer)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_ImageDispose($hImage_Ship)
_GDIPlus_BrushDispose($hBrush_Shot)
_GDIPlus_Shutdown()
Exit
EndSwitch
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _ReDraw()
If _IsPressed("27") And $iX_Ship < $iGUIWidth - 50 Then $iX_Ship += 2
If _IsPressed("25") And $iX_Ship > 0 Then $iX_Ship -= 2
If _IsPressed("20") And TimerDiff($iTimerShot) >= $iCoolDownTime And UBound($aShot) < $iMaxShots Then
_Array2DAdd($aShot, $iX_Ship + 23 & "|" & $iY_Ship - 10)
$iTimerShot = TimerInit()
EndIf

[/autoit] [autoit][/autoit] [autoit]

_GDIPlus_GraphicsClear($hBuffer, $GUIColorBG)
For $i = 1 To UBound($aShot) - 1
If $aShot[$i][1] <> "" Then
_GDIPlus_GraphicsFillRect($hBuffer, $aShot[$i][0], $aShot[$i][1], 5, 10, $hBrush_Shot)
$aShot[$i][1] -= $iShotSpeed
EndIf
Next
For $i = 1 To UBound($aShot) - 1
If $aShot[$i][1] <= 0 Then
_Array2DDelete($aShot, $i)
ExitLoop
EndIf
Next
_GDIPlus_GraphicsDrawImageRect($hBuffer, $hImage_Ship, $iX_Ship, $iY_Ship, 50, 30)
_GDIPlus_GraphicsDrawImageRect($hGraphic, $hBitmap, 0, 0, $iGUIWidth, $iGUIHeight)
EndFunc ;==>_ReDraw

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

;------------------------------------------------------------------------------------------------------------
;
; Function _Array2DAdd(ByRef $avArray, $sValue='')
;
; Description Redim Array Size and add an Array element at last position
; Works with any occurences in 2nd Dimension
; Works also with 1D-Array
;
; Parameter $avArray Given Array
; optional $sValue Value of new Element, parts must be seperate with '|'
;
; Return Succes -1
; Failure 0 and set @error
; @error = 1 given array is not array
; @error = 2 given parts of Element too less/much
;
; Author BugFix ([email='bugfix@autoit.de'][/email])
;------------------------------------------------------------------------------------------------------------
Func _Array2DAdd(ByRef $avArray, $sValue='')
If ( Not IsArray($avArray) ) Then
SetError(1)
Return 0
EndIf
Local $i
Local $UBound2nd = UBound($avArray,2)
If @error = 2 Then
ReDim $avArray[UBound($avArray)+1]
$avArray[UBound($avArray)-1] = $sValue
Else
Local $arValue
ReDim $avArray[UBound($avArray)+1][$UBound2nd]
If $sValue = '' Then
For $i = 0 To $UBound2nd-2
$sValue &= '|'
Next
EndIf
$arValue = StringSplit($sValue, '|')
If $arValue[0] <> $UBound2nd Then
SetError(2)
Return 0
EndIf
For $i = 0 To $UBound2nd-1
$avArray[UBound($avArray)-1][$i] = $arValue[$i+1]
Next
EndIf
Return -1
EndFunc ;==>_Array2DAdd

[/autoit] [autoit][/autoit] [autoit]

;----------------------------------------------------------------------------------------------------------------------
; Fuction _Array2DDelete(ByRef $ARRAY, $iDEL)
;
; Description Delete one row on a given index in an 1D/2D -Array
;
; Parameter $ARRAY the array, where one row will deleted
; $iDEL Row-Index to delete
;
; Return Succes -1 ByRef $ARRAY
; Failure 0 set @error = 1; given array are not array
; set @error = 2; index is out of range
;
; Author BugFix ([email='bugfix@autoit.de'][/email])
;----------------------------------------------------------------------------------------------------------------------
Func _Array2DDelete(ByRef $ARRAY, $iDEL)
If ( Not IsArray($ARRAY) ) Then
SetError(1)
Return 0
EndIf
If ( $iDEL < 0 ) Or ( $iDEL > UBound($ARRAY)-1 ) Then
SetError(2)
Return 0
EndIf
Local $i, $k, $l
Local $UBound2nd = UBound($ARRAY,2)
If @error = 2 Then
Local $arTmp[UBound($ARRAY)-1]
$k = 0
For $i = 0 To UBound($ARRAY)-1
If $i <> $iDEL Then
$arTmp[$k] = $ARRAY[$i]
$k += 1
EndIf
Next
Else
Local $arTmp[UBound($ARRAY)-1][$UBound2nd]
$k = 0
For $i = 0 To UBound($ARRAY)-1
If $i <> $iDEL Then
For $l = 0 To $UBound2nd-1
$arTmp[$k][$l] = $ARRAY[$i][$l]
Next
$k += 1
EndIf
Next
EndIf
$ARRAY = $arTmp
Return -1
EndFunc ;==>_Array2DDelete

[/autoit]

**UEZ**

Kannst ja mal dir AUTOITEROIDS anschauen! Vielleicht hilft dir das Skript!

Gruß,
UEZ

name22

UEZ meinst du nicht das ist ein wenig zu viel auf einmal für einen GDI+ Anfänger.
Obwohl es natürlich die absolute Musterlösung eines AutoIt Spiels darstellt.

**UEZ**

Nun ja, GDI+ ist dar eigentlich nicht so viel drinne! Es werden ja nur Linien und Punkte gezeichnet!

Die eigentliche Herausforderung ist das Verwalten aller Objekte, Kollision, Berechnungen, etc.

Ich weiß auch nicht, ob das Skript einigermaßen verständlich ist!

Gruß,
UEZ

Freaky

Ich will jetzt oben Gegner hinmachen, wie krige ich das mit GDI+ hin das die sich nach Rechst und Links bewegen und wenn ne Kugel die berüht das die dann sterben ?