Tabitem mit Rechtsklick entfernen

**chip**

Ich versuche gerade hinzubekommen, dass ich mit einem Rechtsklick auf ein Tabitem dieses entfernen kann mit:

[autoit]

_GUICtrlTab_DeleteItem()

[/autoit]

Habe es so versucht:

[autoit]

$msg = GUIGetMsg()

[/autoit][autoit][/autoit][autoit]

Switch $msg
Case $GUI_EVENT_SECONDARYDOWN
$controlerdaten = GUIGetCursorInfo ()
_ArrayDisplay($controlerdaten)
EndSwitch

[/autoit]

Um so an die Id des Tabitems zu gelangen, allerdings wird hier dann nur die ID des Tabs an sicht zurückgegeben. Hat vielleicht jemand eine Idee wie ich an die ID des Tabitems komme auf den der Rechtsklick ausgeführt wurde?

zptsvhbfa

chip

Ich weiss nicht ob ich deine Frage richtig verstanden hab. Aber probiers doch mit dem AutoIt Window Info Tool.

LG Daniel

**chip**

Bringt mir nichts da ich die Tabitems dynamisch zur Laufzeit erzeugen lasse und ich über das AutoIt Window Info Tool auch sonst nicht rausbekomme auf welches Tabitem der Rechtsklick ausgeführt wird.

**Schnitzel**

Wenn du sie dynamisch erzeugst dann speicher dir die ID in einem Array.

**chip**

Es geht mir doch garnicht darum die IDs der Tabs zu speichern, die habe ich schon. Es geht darum rauszufinden wie die ID des Tab-Elementes ist auf den der rechtsklick ausgeführt wurde. Wie gesagt bekommt man mit GUIGetCursorInfo () nur die ID des Tab und nicht des Tabitems.

**Schnitzel**

Oh sry^^

dann wohl eher das:

[autoit]

_GUICtrlTreeView_GetSelection

[/autoit]

**chip**

Wiso Treeview? Sind mit GUICtrlCreateTabItem erstellte Tabitems.

**Schnitzel**

oh mann ich bin aber auch von der Rolle

öhm hast dus schonmal mit

[autoit]

Guictrlread;oder
_GUICtrlTab_GetCurSel

[/autoit]

probiert?

**chip**

Hatte ich auch schon probiert. Problem daran ist halt, dass man ja auch auf eine anderes Tabitem einen rechtsklick machne kann, welches nicht gerade selectiert ist.

SEuBo

So?

Spoiler anzeigen

[autoit]

#include <GuiConstantsEx.au3>
#include <GuiTab.au3>

[/autoit] [autoit][/autoit] [autoit]

Local $tRect, $sRect, $hTab

[/autoit] [autoit][/autoit] [autoit]

; Create GUI
GUICreate("Tab Control Get Item RectEx", 400, 300)
$hTab = GUICtrlCreateTab(2, 2, 396, 296)
GUISetState()

[/autoit] [autoit][/autoit] [autoit]

; Add tabs
_GUICtrlTab_InsertItem($hTab, 0, "Tab 1")
_GUICtrlTab_InsertItem($hTab, 1, "Tab 2")
_GUICtrlTab_InsertItem($hTab, 2, "Tab 3")
_GUICtrlTab_InsertItem($hTab, 3, "Tab 4")
_GUICtrlTab_InsertItem($hTab, 4, "Tab 5")
_GUICtrlTab_InsertItem($hTab, 5, "Tab 6")
_GUICtrlTab_InsertItem($hTab, 6, "Tab 7")

[/autoit] [autoit][/autoit] [autoit]

; Loop until user exits
Do
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
Exit
Case $GUI_EVENT_SECONDARYDOWN
ContinueLoop
Case $GUI_EVENT_SECONDARYUP
$iOld = Opt("MouseCoordMode",2)
$aMP = MouseGetPos()
Opt("MouseCoordMode",$iOld)
$tPoint = DllStructCreate($tagPOINT)
DllStructSetData($tPoint, "X", $aMP[0])
DllStructSetData($tPoint, "Y", $aMP[1])

[/autoit] [autoit][/autoit] [autoit]

For $i = 0 To 6 ; Alle Tabs
$tRect = _GUICtrlTab_GetItemRectEx($hTab, $i)
If _WinAPI_PtInRect($tRect, $tPoint) Then
_GUICtrlTab_DeleteItem($hTab, $i)
ExitLoop
EndIf
Next
EndSwitch
Until False
GUIDelete()

[/autoit] [autoit][/autoit] [autoit][/autoit]

**chip**

Also bei mir passiert bei dem Script leider garnichts bei einem Rechtsklick.

SEuBo

Passiert ja auch erst wenn du die rechte Maustaste loslässt.

http://www.youtube.com/watch?v=yha0Sb0_y2g
(intelligenterweise hab ich die Maus selbst nicht mit aufgenommen -.-)

**Oscar**

SEuBo: Dein Beispiel funktioniert bei mir auch nicht. Liegt vielleicht an Win7, 64 Bit?!

Aber so geht es auch:

Spoiler anzeigen

[autoit]

#include <GuiTab.au3>

[/autoit] [autoit][/autoit] [autoit]

; Create GUI
$hGui = GUICreate("Tab Control Get Item RectEx", 400, 300)
$hTab = GUICtrlCreateTab(2, 2, 396, 296)
GUISetState()

[/autoit] [autoit][/autoit] [autoit]

; Add tabs
_GUICtrlTab_InsertItem($hTab, 0, "Tab 1")
_GUICtrlTab_InsertItem($hTab, 1, "Tab 2")
_GUICtrlTab_InsertItem($hTab, 2, "Tab 3")
_GUICtrlTab_InsertItem($hTab, 3, "Tab 4")
_GUICtrlTab_InsertItem($hTab, 4, "Tab 5")
_GUICtrlTab_InsertItem($hTab, 5, "Tab 6")
_GUICtrlTab_InsertItem($hTab, 6, "Tab 7")

[/autoit] [autoit][/autoit] [autoit]

; Loop until user exits
Do
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
Exit
EndSwitch
$aInfo = GUIGetCursorInfo($hGui)
If $aInfo[3] Then
$aHit = _GUICtrlTab_HitTest($hTab, $aInfo[0], $aInfo[1])
If $aHit[1] <> 1 Then
_GUICtrlTab_DeleteItem($hTab, $aHit[0])
Do
$aInfo = GUIGetCursorInfo($hGui)
Until Not $aInfo[3]
EndIf
EndIf
Until False

[/autoit]

**chip**

Perfekt genau so wollte ich das. Danke :).

**Oscar**

Geht sogar noch einfacher:

Spoiler anzeigen

[autoit]

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>

[/autoit] [autoit][/autoit] [autoit]

; Create GUI
$hGui = GUICreate("Tab Control Get Item RectEx", 400, 300)
$hTab = GUICtrlCreateTab(2, 2, 396, 296)
GUISetState()

[/autoit] [autoit][/autoit] [autoit]

; Add tabs
_GUICtrlTab_InsertItem($hTab, 0, "Tab 1")
_GUICtrlTab_InsertItem($hTab, 1, "Tab 2")
_GUICtrlTab_InsertItem($hTab, 2, "Tab 3")
_GUICtrlTab_InsertItem($hTab, 3, "Tab 4")
_GUICtrlTab_InsertItem($hTab, 4, "Tab 5")
_GUICtrlTab_InsertItem($hTab, 5, "Tab 6")
_GUICtrlTab_InsertItem($hTab, 6, "Tab 7")

[/autoit] [autoit][/autoit] [autoit]

; Loop until user exits
Do
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
Exit
Case $GUI_EVENT_SECONDARYUP
$aInfo = GUIGetCursorInfo($hGui)
$aHit = _GUICtrlTab_HitTest($hTab, $aInfo[0], $aInfo[1])
If $aHit[1] <> 1 Then _GUICtrlTab_DeleteItem($hTab, $aHit[0])
EndSwitch
Until False

[/autoit]