Versuch das mal:
[autoit]Func _GetHwndByPID($PID)
$aWinList = WinList()
For $i = 1 To $aWinList[0][0]
If WinGetProcess($aWinList[$i][1]) = $PID Then Return $aWinList[$i][1]
Next
Return SetError(1, 0, 0)
EndFunc
Das Handle ändert sich nicht bei Titelwechsel, es bleibt immer gleich.
Hmm komische Sache. Also erstmal zu den Fehlern im Script:
In Zeile 12 gibst du die pid und das handle vom linken fenster aus, das muss natürlich aufs rechte fenster geändert werdenIn Zeile 57 wird glaube ich die falsche Array Spalte verwendet (handle statt title), müsste denke ich so lautenIf WinGetProcess($aWinList[$i][0]) = $PID Then Return $aWinList[$i][1]
Ich bekomme allerdings nur fürs linke Fenster ein Handle zurück. Beim rechten wird die if Bedingung nicht erfüllt, obwol das Fenster im array von winlist vorhanden ist. Um das zu prüfen hatte ich noch ein arraydislay eingebaut bevor die For Schleife startet.
EDIT: Beim ersten Fenster kommt im übrigen auch nur dann ein Handle zurück, wenn explorer.exe mit einem Parameter gestartet wird also z.B. explorer.exe "C:\".
Es geht eigentlich viel einfacher, mußt nur schauen, ob evtl bei Win7 eine andere CLASS verwendet wird:
Edit: Hatte noch zu kompliziert gedacht, noch kürzer:
[autoit]$old = Opt("WinTitleMatchMode", 4)
ShellExecute("explorer.exe")
ShellExecute("explorer.exe")
$WinList = WinList("CLASSNAME=ExploreWClass")
$hWnd_left = $WinList[1][1]
$hWnd_right = $WinList[2][1]
Opt("WinTitleMatchMode", $old) ; wichtig, sonst können die Window Funcs nicht mit dem Handle arbeiten!
[/autoit][autoit][/autoit][autoit]WinMove($hWnd_left,"",0,0,@DesktopWidth/2,@DesktopHeight-480-60)
WinMove($hWnd_right,"",@DesktopWidth/2,0,@DesktopWidth/2,@DesktopHeight-480-60)
Dann kannst du mit
WinActivate($hWnd)
[/autoit]das jeweilige Fenster aktivieren und deine Aktionen ausführen. Du kannst dann als Titel "[ACTIVE]" verwenden und greifst somit auf das eben aktivierte Fenster zu.
Krass! Jetzt kommen die Profis 
Vielen Dank. Das Skript funktioniert auch bei mir - allerdings musste ich noch nach dem Aufruf der 2 Explorer ein Sleep(1000) einsetzen müssen, weil es sonst nicht zuverlässig funktioniert hat (zumindest auf meinem langsamen Laptop).
Mir geht es natürlich darum, mein Skript zum laufen zu bekommen - allerdings möchte ich das ganze auch verstanden wissen - schon alleine um euch beim nächsten mal nicht wieder quälen zu müssen.
BugFix : Dein Skript habe ich teilweise verstanden. Was ich nicht verstehe ist, warum es auch dann noch funktioniert, wenn ich vor dem Starten des Skripts einen Explorer manuell gestartet habe. Es sind dann 3 Explorer in Winlist gelistet und wenn er dann fix auf 1 und 2 zugreift, dann müsste das erste Explorer-Fenster ja "verändert" werden. Wird es aber nicht. Kapiere ich nicht.
Was mich natürlich noch mehr interessiert ist, warum die Lösungsansätze davor nicht funktioniert haben. Warum hat der Ansatz von m-obi über die PIDs nicht geklappt. Warum wurde die entsprechende PID nicht gefunden?
Ich weiß noch nicht, ob ich es jetzt schaffen werde, die Adresse der Explorer zu verändern, ohne dass das Explorer Fenster aktiv wird.
Falls das nicht anders geht, muss ich eben hoffen, dass das ständige "rumblinken" der Fenster schnell geht und nicht zu sehr stört...
Vielen Dank!!!
Jetzt mal eine ganz blöde Frage! Warum machst du das ganze über den Explorer? Du kannst doch auch Dateien direkt mit AutoIt einsortieren, z.B. mit FileMove.
Man kann ja eine einfache Gui machen, wo man den Quell und den Zielpfad einstellt, und dann wars das schon. Was hast du eigentlich genau vor?
Es sind dann 3 Explorer in Winlist gelistet und wenn er dann fix auf 1 und 2 zugreift, dann müsste das erste Explorer-Fenster ja "verändert" werden. Wird es aber nicht. Kapiere ich nicht.
Ist auch so wie du vermutest. Wenn das bei dir trotzdem funktioniert ist das reiner Zufall und hängt mit der Array Sortierung zusammen. Denke mal das wird alphabetisch sortiert und deine zwei Fenster landen dann eben vor dem anderen Fenster. Kannst dir das Array von winlist einfach mal mit _arraydisplay ausgeben lassen. Bei mir wird das falsche Fenster bewegt, gerade getestet.
Um dieses Problem zu umgehen könnte man winlist aber vor und nach den beiden shellexecutes ausführen und dann die Inhalte der Arrays abgleichen um die vorher schon vorhandenen Fenster auszuschliessen.
Unter Vista muss als Klasse im übrigen "CabinetWClass" verwendet werden.
EDIT: Die Fenster werden doch nicht alphabetisch sortiert, sondern nach der letzten Aktivität. Daher dürfte das Script wohl in 99% der Fälle funktionieren, sofern keine längeren Pausen zwischen Fenster Erstellung und winlist eingebaut werden.
Um sicher die richtigen Fenster zu erwischen, muß man das Skript etwas erweitern. Hab es nicht getestet, aber sollte eigentlich klappen.
#include <Array.au3>
Opt("WinTitleMatchMode", 4)
Local $WinList = WinList("CLASSNAME=ExploreWClass")
Local $count = $WinList[0][0], $ListOld, $aHwnd[2], $j = 0
If $count Then $ListOld = $WinList
ShellExecute("explorer.exe")
ShellExecute("explorer.exe")
Do
$WinList = WinList("CLASSNAME=ExploreWClass")
Sleep(50)
Until $WinList[0][0] = $count +2
Opt("WinTitleMatchMode", 1) ; wichtig, sonst können die Window Funcs nicht mit dem Handle arbeiten!
If $count Then
For $i = 1 To $WinList[0][0]
_ArraySearch($ListOld, $WinList[$i][1], 0, 1, 0, 0, 1, 1)
If @error Then
$aHwnd[$j] = $WinList[$i][1]
$j = 1
EndIf
Next
Else
$aHwnd[0] = $WinList[1][1]
$aHwnd[1] = $WinList[2][1]
EndIf
WinMove($aHwnd[0],"",0,0,@DesktopWidth/2,@DesktopHeight-480-60) ; left
WinMove($aHwnd[1],"",@DesktopWidth/2,0,@DesktopWidth/2,@DesktopHeight-480-60) ; right
Juhu, es funktioniert !!!
Doch bitte bitte:
Warum funktioniert der Ansatz drüber über PID nicht? (aus einer PID ein Handle erzeugen).
Falls ihr müde geworden seid, kann ich dieses Problem auch mal unter autoitscript.com erfragen...
Bin jetzt gespannt, ob ich schaffe, die Explorer Adresse eines der 2 Fenster zu ändern 
Viele Grüße und einen schönen Abend!
Warum funktioniert der Ansatz drüber über PID nicht? (aus einer PID ein Handle erzeugen).
Hast du dir mal die PIDs angesehen? Es ist nur eine. Auch wenn "explorer.exe" mehrfach aufgerufen wird, existiert dazu nur ein Prozeß und somit nur eine PID. Also läßt sich daraus auch nicht auf die Handle schließen.
Nö ist nicht richtig. Unter Vista erhalte ich pro gestarteter explorer.exe auch eine eigene PID.
Ich kriege allerdings auch unter XP zwei verschiedene PIDs.
Das ist mal wieder typisch Windows. :wacko: Ich habe auch XP und bekomme nur eine Instanz der explorer.exe, egal wie oft ich die exe aufrufe.
Dieses Verhalten (nur ein Explorer-Prozess oder mehrere) kannst Du einstellen:
autoit.de/wcf/attachment/11943/
Ist der Haken gesetzt, wird für jedes Explorerfenster ein eigener Prozess gestartet.
Ist der Haken gesetzt, wird für jedes Explorerfenster ein eigener Prozess gestartet.
Wie sagte meine Oma so richtig: "Kannste alt werd'n, wie ne Kuh - lernste immer noch dazu."
Edit:
Kommando zurück - das ist eine Fehlinterpretation.
Habe es mal durchgetestet. Es gibt max. 2 Explorer-Instanzen zeitgleich. Völlig egal ob der Aufruf mit Run, ShellExecute oder aus der Eingabeaufforderung erfolgt. Einmal läuft sowieso und in der zweiten Instanz werden dann die Fenster geöffnet, sofern die Checkbox aktiviert ist. "Ordnerfenster in einem eigenem Prozeß anzeigen" sagt die Beschreibung, und nicht "jedes Ordnerfenster in einem eigenen Prozeß"
Oh! Dann habe ich das missverstanden. Beim testen hatte ich nur im Taskmanager nachgesehen und dort waren zwei Explorer-Prozesse. Deshalb bin ich davon ausgegangen, dass für jedes Explorerfenster ein neuer Prozess gestartet wird.
Ich hätte mal die PIDs testen sollen, sorry! 
Es ist trotzdem verwirrend.
Hier mal ein Testskript.
$PID1 = Run("explorer.exe")
; Unter dieser PID sind nachher alle Explorerfenster vereint, obwohl beim Start eine eigene PID vergeben wird.
; Aber Windows scheint diese zu verwerfen.
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $PID1 = ' & $PID1 & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
$PID2 = Run("explorer.exe")
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $PID2 = ' & $PID2 & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
$PID3 = Run("explorer.exe")
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $PID3 = ' & $PID3 & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
$PID4 = Run("explorer.exe")
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $PID4 = ' & $PID4 & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
$PID5 = Run("explorer.exe")
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $PID5 = ' & $PID5 & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
Opt("WinTitleMatchMode", 4)
Local $WinList
Do
$WinList = WinList("CLASSNAME=ExploreWClass")
Sleep(50)
Until $WinList[0][0] = 5
Opt("WinTitleMatchMode", 1)
ConsoleWrite('Hwnd / PID from Hwnd' & @CRLF)
For $i = 1 To $WinList[0][0]
ConsoleWrite('Hwnd / PID : ' & $WinList[$i][1] & ' / ' & WinGetProcess($WinList[$i][1]) & @CRLF & @CRLF)
Next
Local $ProcList = ProcessList('explorer.exe')
ConsoleWrite('PIDs from ProcessList' & @CRLF)
For $i = 1 To $ProcList[0][0]
ConsoleWrite($ProcList[$i][1] & @CRLF)
Next
Nach dem Starten dieser 5 Explorerfenster erhalte ich folgende Ausgabe:
@@ Debug(516) : $PID1 = 948
>Error code: 0
@@ Debug(518) : $PID2 = 3560
>Error code: 0
@@ Debug(520) : $PID3 = 2228
>Error code: 0
@@ Debug(522) : $PID4 = 2568
>Error code: 0
@@ Debug(524) : $PID5 = 3496
>Error code: 0
Hwnd / PID from Hwnd
Hwnd / PID : 0x0006069A / 948
Hwnd / PID : 0x000805C2 / 948
Hwnd / PID : 0x00030684 / 948
Hwnd / PID : 0x00180400 / 948
Hwnd / PID : 0x00120352 / 948
PIDs from ProcessList
1396
948Starte ich dann nochmals das Skript und lasse die 5 Fenster offen, erhalte ich folgende Ausgabe:
@@ Debug(516) : $PID1 = 3708
>Error code: 0
@@ Debug(518) : $PID2 = 4068
>Error code: 0
@@ Debug(520) : $PID3 = 904
>Error code: 0
@@ Debug(522) : $PID4 = 264
>Error code: 0
@@ Debug(524) : $PID5 = 4016
>Error code: 0
Hwnd / PID from Hwnd
Hwnd / PID : 0x0006069A / 948
Hwnd / PID : 0x000805C2 / 948
Hwnd / PID : 0x00030684 / 948
Hwnd / PID : 0x00180400 / 948
Hwnd / PID : 0x00120352 / 948
PIDs from ProcessList
1396
948
4068
904
264
4016D.h. die neuen Prozesse sind in der Prozesslist, werden aber im Taskmanager bei mir nur unter einer Instanz, PID 948 angezeigt und die Handle sind auch alle dieser PID zugeordnet.
Mir fehlen dazu die tieferen Windows-Kenntnisse, um das zu verstehen. :wacko: