So, da mir im chat keiner antwortet 
schreibe ich jetzt hier nen Thema!
ich habe 2 fragen(vielleicht werdens ja noch mehr ;))
1.) Wie kann man es machen, dass wenn ich in ein input-Feld klicke der Text sofort markiert wird?
2.) Wie kann man einen Text (==> in anführungszeichen), der nur aus Zahlen besteht in eine Zahl konvertieren? (wie in Visual Basic "Cint()")
Danke
DFPWare
Zu 2.
[autoit]$sString = "22384"
$iNumber = Number($sString)
okay dann hab ich da jetzt nochmal ne frage:
wie bekomme ich das hin, dass das ausgerechnet wird?
ja ich weiß, dass "12+3" nicht nur aus Zahlen besteht, das ist mein Problem 
GUICreate("",100,100)
$button = GUICtrlCreateButton("Rechnen",10,10)
$input = GUICtrlCreateInput("12+3",10,50)
GUISetState()
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $button
_rechnen()
EndSwitch
WEnd
Func _rechnen()
$read = GUICtrlRead($input)
$output = Number($read)
MsgBox(0,"",$output)
EndFunc
Dafür gibt es Execute:
#include <GUIConstantsEx.au3>
GUICreate("", 100, 100)
$button = GUICtrlCreateButton("Rechnen", 10, 10)
$input = GUICtrlCreateInput("12+3", 10, 50)
GUISetState()
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $button
_rechnen()
EndSwitch
WEnd
Func _rechnen()
$read = Execute(GUICtrlRead($input))
;~ $output = Number($read)
MsgBox(0, "", $read)
EndFunc ;==>_rechnen
Allerdings solltest du dann den String überprüfen z.B. mit StringRegExp.
Ansonsten könnte man auch MsgBox o.Ä. eingeben und es würde ausgeführt werden ;).
$sTerm = InputBox("Calculate", "Term:")
$sTerm = StringRegExpReplace($sTerm, '[^\d\+\-/\*\(\)\^]', "")
MsgBox(64, "Result", Execute($sTerm))
okay
habt ihr vielleicht auch noch eine antwort auf
1.) Wie kann man es machen, dass wenn ich in ein input-Feld klicke der Text sofort markiert wird?
So würde es gehen...
#include <WindowsConstants.au3>
#include <GUIConstants.au3>
#include <GUIEdit.au3>
$hWnd = GUICreate("Test", 200, 60)
$cInput = GUICtrlCreateInput("AutoIt", 5, 5, 190, 20)
$cButton = GUICtrlCreateButton("Test", 5, 30, 190, 25)
GUISetState()
GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")
$bFocus = False
While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
If $bFocus Then
ControlFocus($hWnd, "", $cInput)
_GUICtrlEdit_SetSel($cInput, 0, -1)
$bFocus = False
EndIf
WEnd
Func _WM_COMMAND($hWndGUI, $MsgID, $WParam, $LParam)
If $WParam = 0x01000003 And $LParam = ControlGetHandle($hWnd, "", $cInput) Then $bFocus = True
EndFunc
Wobei ich nicht weiß, warum ein direktes aufrufen von SetSel innerhalb von _WM_COMMAND nicht funktioniert. 
Geht auch mit WM_COMMAND. Du musst nur den Focus wieder auf das Input-Control setzen:
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
GUICreate("", 200, 100)
$button = GUICtrlCreateButton("Rechnen", 10, 10)
$input = GUICtrlCreateInput("12+3", 10, 50, 100, 20)
GUISetState()
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $button
_rechnen()
EndSwitch
WEnd
Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
Local $nNotifyCode, $nID
$nNotifyCode = BitShift($wParam, 16)
$nID = BitAND($wParam, 0x0000FFFF)
Switch $nID
Case $input
Switch $nNotifyCode
Case $EN_SETFOCUS
GUICtrlSendMsg($input, $EM_SETSEL, 0, -1)
GUICtrlSetState($input, $GUI_FOCUS)
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>WM_COMMAND
Func _rechnen()
$read = Execute(GUICtrlRead($input))
MsgBox(0, "", $read)
EndFunc ;==>_rechnen
(Arcus)Sinus, (Arcus)Kosinus, (Arcus)Tangens, Quadratwurzel, Konstanten wie Pi oder eulersche Zahl.
Hmm Modulo vielleicht noch. Ansonsten wären das die wichtigsten Funktionen. Alles andere mache ich entweder auf dem Papier oder mit einem Script.
