Progressbar in Update Funktion einbauen

    Hallo AutoIt´ler,

    ich wende mich an euch mit einer Frage die für die meisten von euch
    sicherlich einfach zu beantworten ist, aber für mich leider noch nicht.

    Um was für ein Programm handelt es sich fragt ihr euch?
    Wir haben ein schon vorhandenes Projekt zur weiterführung übernommen, da der Erfinder aus Zeitlichen und privaten Gründen nicht weiter machen kann und es daher an uns abgetreten hat! Der Quellcode zu dem Programm ist kommplett in Autoit geschrieben und umfasst insgesammt 27283 Zeilen!
    Es handelt sich hier um ein art Datenbank Programm, was den Usern kostenlos von uns zur Verfügung gestellt wird!
    In diesem Programm sammeln wir (Das Team rund um das Programm) alles was es in dem Spiel so gibt und (von Quests über Schiffen bis hin zu Kleidung usw.) speichern das in .Data Datein ab. Diese rufen wir dann über den Quellcode auf!

    Nun ist es zwar so, das wir einen AutoIt Programmierer in unserem Team haben, aber dieser leider momentan aus privaten und technischen Gründen nicht zur Verfügung steht!
    Viele User beschweren sich (schon vor übernahme durch uns) das wenn ein Update geladen wird keine Anzeige vorhanden ist die ihnen Aufschluss darüber gibt wie lange dieses noch zum herunterladen braucht! Nun dachte ich mir das man doch so eine schöne Progressbar einbauen könnte um eben dieses Problem zu beheben, aber leider blicke ich (trotz Video´s und Beispielen) nicht so recht durch wo, wie und was nun hin muss! Ich hatte vor sehr langer Zeit zwar mal was mit AutoIt zu tun, was mir aber im moment nichts nützt.

    Ich stelle euch mal die Updatefunktion in eine Code Box und hoffe das Ihr mir da weiterhelfen könnt!
    Code:

    [autoit]

    Func UPDATECHECK()
    DATENBANKENPRUEFEN()
    If $M <> 700 Then
    $TEMP[1] = GUICtrlCreateLabel(TRANSLATION("Es wird geprüft, ob neue Updates vorliegen. Bitte warten..."), 180, 320, 520, 25, $SS_CENTER)
    GUICtrlSetFont(-1, 14, 400)
    EndIf
    FileSetAttrib("*.*", "-r", 1)
    $VAR = 1
    If $VAR Then
    If IniRead($SCRIPTPATH & "data\config.ini", "TestUpdate", "Server", $ALTERNATIVEUPDATESERVER) = "http://www.test-test.eu" Then
    IniWrite($SCRIPTPATH & "data\config.ini", "TestUpdate", "Server", $ALTERNATIVEUPDATESERVER)
    EndIf
    $TZ = LOADFILE(IniRead($SCRIPTPATH & "data\config.ini", "TestUpdate", "Server", $ALTERNATIVEUPDATESERVER) & "/Updateinfo.data", $SCRIPTPATH & "data\Updateinfo.data")
    If $TZ = 1 Then
    $UNR = Number(IniRead($SCRIPTPATH & "data\Updateinfo.data", "Serverversion", "Versionnr", ""))
    $UPFAD = IniRead($SCRIPTPATH & "data\Updateinfo.data", "Serverversion", "Versionname", "")
    $FMIN = IniRead($SCRIPTPATH & "data\Updateinfo.data", "Serverversion", "Fullversionnr", "")
    $UMINPFAD = IniRead($SCRIPTPATH & "data\Updateinfo.data", "Serverversion", "Fullversionname", "")
    If $M <> 700 Then GUICtrlDelete($TEMP[1])
    If $LUPDATE = 0 Then
    If $UNR = 0 Then
    MsgBox(16, TRANSLATION("Updatecheck Fehler"), TRANSLATION("Die Updatedatei wurde vom Server fehlerhaft geladen!"), 0)
    ElseIf $UNR > $VNR Then
    If $VNR > $FMIN Then
    $JANEIN = MsgBox(68, "Update Information", TRANSLATION("Neues Update") & " '" & $UPFAD & "' " & TRANSLATION("verfügbar. Laden?"), 0)
    If $JANEIN = 6 Then
    If $M <> 700 Then
    $TEMP[1] = GUICtrlCreateLabel(TRANSLATION("Neues Update wird geladen. Bitte warten..."), 180, 320, 520, 25, $SS_CENTER)
    GUICtrlSetFont(-1, 14, 400)
    EndIf
    $FILE = IniRead($SCRIPTPATH & "data\config.ini", "TestUpdate", "Server", $ALTERNATIVEUPDATESERVER) & "/" & $UPFAD & ".exe"
    FileDelete($SCRIPTPATH & "Updates\Test Test Update*.*")
    LOADFILE($FILE, $SCRIPTPATH & "Updates\" & $UPFAD & ".exe")
    GUICtrlDelete($TEMP[1])
    MsgBox(64, "Update Information", TRANSLATION("Update wurde geladen und wird nun installiert. Der Test wird dazu geschlossen."), 0)
    If WinExists("Test-Counter") Then
    WinKill("Test-Counter")
    EndIf
    If WinExists("Test-Tray") Then
    WinKill("Test-Tray")
    EndIf
    Run($SCRIPTPATH & "Updates\" & $UPFAD & ".exe")
    Exit
    EndIf
    Else

    [/autoit]

    Schön wäre es wenn ihr mir beim einsetzen in den Code vielleicht kurz was dazu schreiben könntet warum gerade das und warum es dort hin kommt,
    damit ich es nachvollziehen und dadurch verstehen und lernen kann!

    Ich hoffe das mir nun jemand dabei helfen kann, mir antwortet und sage schonmal vielen Dank!

    Mfg Ghostleader

    Einmal editiert, zuletzt von Ghostleader (12. Februar 2011 um 19:38)

    Da ich im Moment leider nicht genug Zeit hab mich in den Code reinzuversetzen, versuch ich dir die Progressbar mit einem einfachen Beispiel zu erklären.

    [autoit]

    Global $Data = 0
    Global $AnzahlDerDateien = 37
    $hGui = GUICreate("Progress Bar Test GUI", 100, 20)
    $hProgress = GUICtrlCreateProgress(0, 0, 100, 20)

    [/autoit][autoit][/autoit][autoit]

    GUISetState()

    [/autoit][autoit][/autoit][autoit]

    For $i = 1 To $AnzahlDerDateien
    $Data += 100 / $AnzahlDerDateien
    Sleep(1000) ;Simuliert das Updaten
    GUICtrlSetData($hProgress, $Data)
    Next

    [/autoit][autoit][/autoit][autoit]

    ;~ Jede Progress Bar hat ANFANGS den Höchstwert 100 (änderbar)
    ;~ Du guckst wie viele Sachen du Updaten möchtest, z.B. 37
    ;~ Pro neue Datei gehst du einen Schritt vorwärts, so das du am Ende der 37 Datei bei 100 bist
    ;~ In dem Fall wäre es 100/37, damit bekommst du jeden Schritt raus.

    [/autoit]

    Wenn ich es falsch verstanden hab tut es mir sehr Leid.
    PS: Das Projekt hört sich sehr interessant an.

    Hallo BadBunny,

    danke erstmal für deine sehr schnelle Antwort und die Erklährung der Progressbar anhand deines Beispieles. Nun stellt sich mir noch die Frage ob es einen bestimmten Punkt gibt wo ich diese einbauen muss, oder ob das egal ist! Desweiteren wird wenn man das Programm startet eine Update abfrage gemacht und wenn ein Update vorhanden ist dieses per MsgBox angezeigt und gefragt ob man es downloaden will oder nicht über --> Update starten ja/nein Auswahl, die dann ja auch da bedacht werden muss.

    Mfg Ghostleader

    Spoiler anzeigen
    [autoit]

    Func UPDATECHECK()
    DATENBANKENPRUEFEN()
    If $M <> 700 Then
    $TEMP[1] = GUICtrlCreateLabel(TRANSLATION("Es wird geprüft, ob neue Updates vorliegen. Bitte warten..."), 180, 320, 520, 25, $SS_CENTER)
    GUICtrlSetFont(-1, 14, 400)
    EndIf
    FileSetAttrib("*.*", "-r", 1)
    $VAR = 1
    If $VAR Then
    If IniRead($SCRIPTPATH & "data\config.ini", "TestUpdate", "Server", $ALTERNATIVEUPDATESERVER) = "http://www.test-test.eu" Then
    IniWrite($SCRIPTPATH & "data\config.ini", "TestUpdate", "Server", $ALTERNATIVEUPDATESERVER)
    EndIf
    $TZ = LOADFILE(IniRead($SCRIPTPATH & "data\config.ini", "TestUpdate", "Server", $ALTERNATIVEUPDATESERVER) & "/Updateinfo.data", $SCRIPTPATH & "data\Updateinfo.data")
    If $TZ = 1 Then
    $UNR = Number(IniRead($SCRIPTPATH & "data\Updateinfo.data", "Serverversion", "Versionnr", ""))
    $UPFAD = IniRead($SCRIPTPATH & "data\Updateinfo.data", "Serverversion", "Versionname", "")
    $FMIN = IniRead($SCRIPTPATH & "data\Updateinfo.data", "Serverversion", "Fullversionnr", "")
    $UMINPFAD = IniRead($SCRIPTPATH & "data\Updateinfo.data", "Serverversion", "Fullversionname", "")
    If $M <> 700 Then GUICtrlDelete($TEMP[1])
    If $LUPDATE = 0 Then
    If $UNR = 0 Then
    MsgBox(16, TRANSLATION("Updatecheck Fehler"), TRANSLATION("Die Updatedatei wurde vom Server fehlerhaft geladen!"), 0)
    ElseIf $UNR > $VNR Then
    If $VNR > $FMIN Then
    $JANEIN = MsgBox(68, "Update Information", TRANSLATION("Neues Update") & " '" & $UPFAD & "' " & TRANSLATION("verfügbar. Laden?"), 0)
    If $JANEIN = 6 Then
    If $M <> 700 Then
    $TEMP[1] = GUICtrlCreateLabel(TRANSLATION("Neues Update wird geladen. Bitte warten..."), 180, 320, 520, 25, $SS_CENTER)
    GUICtrlSetFont(-1, 14, 400)
    $Progress = GUICtrlCreateProgress(;X,Y,Width,Heigh)
    $Data = 0
    EndIf
    ;Sagen wir 3 Teile, 1:Ini Lesen,2:DateiLöschen,3:DateiLaden, also 100/3, 0.33333333333**** Andere Möglichkeit: 100/6 anfangs 100/6tel dazu setzen und nach einem Schritt wieder.

    [/autoit] [autoit][/autoit] [autoit]

    $FILE = IniRead($SCRIPTPATH & "data\config.ini", "TestUpdate", "Server", $ALTERNATIVEUPDATESERVER) & "/" & $UPFAD & ".exe")
    $Data += 100 / 3;1. Schritt
    GUICtrlSetData($Progress, $Data);Warte setzen
    FileDelete($SCRIPTPATH & "Updates\Test Test Update*.*")
    $Data += 100 / 3;2. Schritt
    GUICtrlSetData($Progress, $Data)
    LOADFILE($FILE, $SCRIPTPATH & "Updates\" & $UPFAD & ".exe")
    $Data += 100 / 3;3. Schritt
    GUICtrlSetData($Progress, $Data)
    GUICtrlDelete($TEMP[1])
    Guictrldelete ($Progress)

    ;;>>ES KANN GUT SEIN DAS DIE CONTROLS GELÖSCHT WERDEN BEVOR DIE PROGRESSBAR 100 ERRICHT HAT, DAS LIEGT AM LADEN.
    ;;>>

    MsgBox(64, "Update Information", TRANSLATION("Update wurde geladen und wird nun installiert. Der Test wird dazu geschlossen."), 0)
    If WinExists("Test-Counter") Then
    WinKill("Test-Counter")
    EndIf
    If WinExists("Test-Tray") Then
    WinKill("Test-Tray")
    EndIf
    Run($SCRIPTPATH & "Updates\" & $UPFAD & ".exe")
    Exit
    EndIf
    Else

    [/autoit] [autoit][/autoit] [autoit][/autoit]

    So müsste es gehen. Wie ich kommentiert hab kann es sein das die 100 % nicht erreischt werden da die progress dann schon gelöscht ist. In dem Fall einfach das Laden vor das ausführen der Schritte setzen, oder die andere Möglichkeit mit 100/6 nutzen.

    Deine Lösung hilft denke ich kaum BadBunny. Dadurch sieht man zwar, dass das Update noch läuft, aber das wars auch schon. Einen Verlauf sieht man nicht wirklich, denn das ini lesen dürfte in nem sekundenbruchteil gehen, das bedeutet er springt sofort auf 66% und die 100% bekommt man auch nicht mehr zusehen, weil das ganze sofort gelöscht wird sobald er fertig ist.

    Um einen brauchbaren Verlauf zu realisieren müsste der Threadersteller mal die Funktion LOADFILE hier posten.

    Hallo BadBunny,

    die Progressbar ist eingebaut und nun vorhanden, dafür erstmal danke. Leider ist es nun tatsächlich so wie misterspeed schon beschreibt das es keinerlei bewegung der Progressbar gibt sondern immer nur (jenachdem wie ich es einstelle) eine bestimmte anzeige kommt und bleibt ohne sich zu bewegen.

    misterspeed

    Leider weiss ich nun nicht so recht welchen Teil du dafür brauchst! Ich habe aber noch etwas gefunden. Siehe Code Box:

    Spoiler anzeigen
    [autoit]

    Func LOADFILE($INETADRESS, $LOCALFILE)
    Local $HDOWNLOAD = InetGet($INETADRESS, $LOCALFILE, 17, 1)
    Do
    Sleep(250)
    Until INETGETINFO($HDOWNLOAD, 2)
    Local $ADATA = INETGETINFO($HDOWNLOAD)
    INETCLOSE($HDOWNLOAD)
    If $ADATA[3] = True Then
    Return 1
    Else
    Return 0
    EndIf

    [/autoit]

    Ich hoffe das ich gleich das richtige gefunden habe und du damit was anfangen kannst!

    Mfg Ghostleader

    Hallo Ghostleader,

    herzlich willkommen im Forum und viel Spass mit AutoIt.

    Hier kannst du dir die deutsche Hilfe herunterladen.
    Hier gibt es ein AutoIt-Tutorial: http://wiki.autoit.de/wiki/index.php/TutorialSehr hilfreich ist auch das Buch von peethebee

    und jetzt zu deinem Problem: Ich bin der gleichen Meinung wie misterspeed. Für mich sieht es so aus als ob nur eine einzige Datei heruntergeladen wird und das in einer Routine, die du nicht gepostet hast. Des weiteren ist nicht zu erkennen ob bereits eine GUI existiert.
    Hier ein Downloadbeispiel (lädt die dt. Hilfe herunter) und zeigt den Fortschritt als Tray-Tipp:

    Spoiler anzeigen
    [autoit]

    #region ;**** Directives created by AutoIt3Wrapper_GUI ****
    #AutoIt3Wrapper_UseUpx=n
    #endregion ;**** Directives created by AutoIt3Wrapper_GUI ****
    #include <Date.au3>
    #include <array.au3>

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    HttpSetUserAgent("Mozilla/5.0 (Windows; U; Windows NT 5.1; de; rv:1.9.2.7) Gecko/20100713 Firefox/3.6.7") ; User-Agent (Header) von AutoIt3 ändern, da beim Webhoster dieser gesperrt ist

    [/autoit] [autoit][/autoit] [autoit]

    Global $tDiff, $iToDo, $iRTime, $sMSG, $nKBPerSec
    $sUrl = "http://translation.autoit.de/autoitinfo/hilfedateien/AutoIt-Hilfe-Deutsch-3.3.6.1-Stand-07_09_10.zip"
    ;url eventell gegen einen anderen größeren Download tauschen, dann aber bitte auch $sPath ändern
    $sPath = @ScriptDir & "\AutoIt-Hilfe-Deutsch-3.3.6.1-Stand-07_09_10.zip"
    Global $iSize = InetGetSize($sUrl) ;siehe Hilfe zu InetgetSize
    Global $tStart = TimerInit()
    $hDownLoad = InetGet($sUrl, $sPath, 1, 1)
    Dim $aData[3]

    [/autoit] [autoit][/autoit] [autoit]

    Do
    Sleep(250)
    If $aData[0] > 0 Then
    _CalcPerformance($aData[0], $aData[2])
    TrayTip("downloading", $sMSG, 10, 16)
    EndIf
    $aData = InetGetInfo($hDownLoad, -1)
    Until $aData[2]
    $aData = InetGetInfo($hDownLoad, -1)
    _CalcPerformance($aData[0], $aData[2])

    [/autoit] [autoit][/autoit] [autoit]

    InetClose($hDownLoad) ; Handle schließen um die Resourcen freizugeben.
    MsgBox(0, "", "Bytes gelesen: " & $aData[0] & @CRLF & _
    "Größe: " & $aData[1] & @CRLF & _
    "beendet?: " & $aData[2] & @CRLF & _
    "Erfolgreich?: " & $aData[3] & @CRLF & _
    "@error: " & $aData[4] & @CRLF & _
    "@extended: " & $aData[5] & @CRLF & @CRLF & _
    "KiloBytes/sec: " & $nKBPerSec & @CRLF & _
    "benötigte Teit: " & Round($tDiff / 1000, 0) & " Sekunden")
    ConsoleWrite("Bytes gelesen: " & $aData[0] & @CRLF & _
    "Größe: " & $aData[1] & @CRLF & _
    "beendet?: " & $aData[2] & @CRLF & _
    "Erfolgreich?: " & $aData[3] & @CRLF & _
    "@error: " & $aData[4] & @CRLF & _
    "@extended: " & $aData[5] & @CRLF & @CRLF & _
    "KiloBytes/sec: " & $nKBPerSec & @CRLF & _
    "benötigte Teit: " & Round($tDiff / 1000, 0) & " Sekunden")

    [/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

    ;FileDelete(@ScriptDir & "\Testdownload.htm")

    [/autoit] [autoit][/autoit] [autoit]

    Func _CalcPerformance($iRead, $bDone)

    [/autoit] [autoit][/autoit] [autoit]

    $tDiff = TimerDiff($tStart)
    $iToDo = Round(($iSize - $iRead) / 1024, 2)
    $nKBPerSec = Round($iRead / $tDiff * 1000 / 1024, 2)
    $iPercent = Round($iRead / $iSize * 100, 2)
    if ($iSize = 0) And Not $bDone Then
    $iRTime = "unbekannt"
    Else
    $iRTime = Round($iToDo / $nKBPerSec, 0)
    EndIf
    $sMSG = Round($iRead / 1024, 0) & "/" & Round($iSize / 1024, 0) & " KB " & " = " & $iPercent & "%" & @CRLF
    $sMSG &= "durchschnittlich KB/s = " & $nKBPerSec & @CRLF ;& "aktuell: KB/s " & $nKBAct & @CRLF
    If Not $bDone Then
    $sMSG = $sMSG & "vermutlich zu Ende:" & StringLeft(StringRight(_DateAdd('s', $iRTime, _NowCalc()), 8), 5)
    ;ConsoleWrite($sMSG & @CRLF)
    Else
    $sMSG = $sMSG & "benötigte Zeit = " & Round($tDiff / 1000, 0)
    EndIf
    ;if $iSize > 0 Then $sMSG = $sMSG & " sec"
    EndFunc ;==>_CalcPerformance

    [/autoit]

    wenn wie du sagst der Zustand mit der fehlenden Info schon länger existiert das Programm aber ansonsten läuft würde ich dir raten es so zu lassen wie es ist und abwarten bis der zuständige Programmierer erreichbar ist

    mfg autoBert

    Hallo autoBert,

    es ist in der Tat so, das es sich immer um nur eine Datei handelt (sorry das ich das nicht erwähnt habe) die gedownloadet wird. Es ist aber auch so das die User schon beim damaligen Hersteller des Programms dies bemängelten und wir das eben gerne mit ändern wollten!

    Ich hoffe trotzdem das es möglich ist mir zu helfen ich suche mal ob ich das was du gerne haben magst/brauchst zu finden!

    Mfg Ghostleader

    Hi ja das schaut sehr gut aus und sollte sich auch eignen um hier einen Verlauf einzubauen. Hier mal eine modifizierte Variante, allerdings ungetestet und der einfachheit halber mal mit progressON anstelle einer progressbar die sich in der Hauptgui befindet:

    Spoiler anzeigen
    [autoit]

    Func LOADFILE($INETADRESS, $LOCALFILE)
    Local $HDOWNLOAD = InetGet($INETADRESS, $LOCALFILE, 17, 1)
    ProgressOn ( "Download-Verlauf: " & $LOCALFILE, "" , "" , -1 , -1 , 18 )
    $SIZE = InetGetInfo($HDOWNLOAD,1) ; Gesamt Größe der Datei, achtung evtl nicht auslesbar siehe hilfe

    Do
    Sleep(250)
    $curSIZE = InetGetInfo($HDOWNLOAD,0) ; Bytes die bereits heruntergeladen wurden
    ProgressSet(($curSIZE/$SIZE)*100)
    Until INETGETINFO($HDOWNLOAD, 2)

    Local $ADATA = INETGETINFO($HDOWNLOAD)
    INETCLOSE($HDOWNLOAD)
    ProgressOff()
    If $ADATA[3] = True Then
    Return 1
    Else
    Return 0
    EndIf
    EndFunc

    [/autoit]

    Hallo misterspeed,

    danke für die wieder schnelle Antwort.

    Also das downloadfenster wird angezeigt, jedoch ist auch hier leider keine Bewegung zu sehen sondern der Balken bleibt leer!

    Ich weiss ja leider nicht was direkt noch von nöten währe um das Problem zu erleichtern!

    Kann man nicht etwas verwenden ähnlich diesem hier?

    Spoiler anzeigen
    [autoit]

    $Quelle = @SystemDir & '\taskmgr.exe'
    $Ziel = "C:\taskmgr.exe"

    [/autoit] [autoit][/autoit] [autoit]

    If _ProgressCopy($Quelle, $Ziel) Then MsgBox(0,"", "Kopiervorgang erfolgreich!")

    [/autoit] [autoit][/autoit] [autoit]

    Func _ProgressCopy($SourceFile, $DestinationFile)
    If Not FileExists($SourceFile) Then Return SetError(1,1,0)
    If $SourceFile == $DestinationFile Then Return SetError(2,2,0)

    #region------------------------------------Declare Variables-------------------------------
    Local $ByteBlock, $Counter
    Local Const $BlockSize = Int(FileGetSize($SourceFile) / 99)
    Local Const $Opt = Opt("GUIOnEventMode", 0)
    Local $OpenHandle = FileOpen($SourceFile, 16)
    Local $WriteHandle = FileOpen($DestinationFile, 26)
    #endregion---------------------------------------------------------------------------------

    If $OpenHandle = -1 Or $WriteHandle = -1 Then Return SetError(3,3,0)

    #region------------------------------------GUI create--------------------------------------
    Local $GUI = GUICreate('', 400, 105, Default, Default, 0x80880000)
    Local $Label1 = GUICtrlCreateLabel($SourceFile, 8, 10)
    Local $Label2 = GUICtrlCreateLabel($DestinationFile, 8, 30)
    Local $Label3 = GUICtrlCreateLabel("0%", 360, 25, 30, 20, 0x2)
    Local $Button = GUICtrlCreateButton("Abbrechen", 160, 75, 80)
    Local $PBar = GUICtrlCreateProgress(8, 50, 384, 20)
    GUISetState()
    #endregion---------------------------------------------------------------------------------

    #region----------------------------------Copy File-----------------------------------------
    Do
    $ByteBlock = FileRead($OpenHandle, $BlockSize)
    If @error Then ExitLoop
    FileWrite($WriteHandle, $ByteBlock)
    $Counter += 1
    GUICtrlSetData($PBar, $Counter)
    GUICtrlSetData($Label3, $Counter & ' %')

    If GUIGetMsg() = $Button Then
    Opt("GUIOnEventMode", $Opt)
    FileClose($OpenHandle)
    FileClose($WriteHandle)
    GUIDelete($GUI)
    FileDelete($DestinationFile)
    Return SetError(4,4,0)
    EndIf

    Sleep(20) ;Bremse - Auskommentieren für maximale Geschwindigkeit
    Until 0
    #endregion---------------------------------------------------------------------------------


    Opt("GUIOnEventMode", $Opt)
    FileClose($OpenHandle)
    FileClose($WriteHandle)
    GUIDelete($GUI)
    Return 1
    EndFunc

    [/autoit]

    Mfg Ghostleader

    Versuch das mal:

    [autoit]


    $SIZE = InetGetInfo($HDOWNLOAD,1) ; Gesamt Größe der Datei, achtung evtl nicht auslesbar siehe hilfe
    msgbox(0,"Debug-Info SIZE", "Wert von size: " & $SIZE & " Errorcode: " & @error) ; sollte der Wert ein leerer String sein klappt das auslesen der Größe nicht, evtl sollte vor der Größen Ermittlung noch ein sleep eingebaut werden...

    [/autoit]

    Muss ich irgendwo noch etwas eintragen oder eher nicht, denn jetzt kommt immer eine msgbox und
    sagt --> Debug-Info SIZE Wert von size: 0 Errorcode: 0

    Auch in dem Balken passiert nichts!

    Mfg Ghostleader

    Ps. Wieviele Zeichen darf man hier im Forum Posten?

    Also laut Hilfe liest er die Größe zwar angeblich ohne Fehler aus, aber er geht davon aus, dass die Datei 0 Byte groß ist. Dadurch ergibt sich in der Prozentberechnung natürlich immer ein fehlerhafter Wert, da durch 0 nicht geteilt werden kann. Resultat davon ist dann natürlich eine Progressbar die leer bleibt. Versuch mal ein sehr großzügiges sleep(5000) vor der Zeile "$SIZE=...." sollte dann immernoch eine 0 als Wert in der msgbox erscheinen musst du dir etwas anderes einfallen lassen. Dazu wäre interessant wie groß die Update Datei in der Regel ist. Ist die Größe immer etwa gleich oder wächst diese permanent deutlich an? Wenn diese immer etwa gleich groß ist könntest du zur Not auch einen festen Wert ins Script schreiben, also einfach ein "$SIZE=xxxx" in Byte. Dadurch wäre der Verlauf zwar nicht exakt, aber wenigstens ungefähr stimmig. Sollte die Größe der Datei sehr schwankend sein wird es etwas schwerer bis ziemlich unmöglich. Du könntest aber einfach auf gut Glück alle x Sekunden den Progress um 5% oder andere Werte die hinkommen könnten fortschreiten lassen. Da das aber wohl sehr von Internetanbindung des Benutzers abhängt und auch von der Performance des Servers wäre das nicht sehr genau und der Balken könnte längere Zeit bei 100% stehen bleiben.

    Hallo Ghostleader,

    ich habe hier einmal die func loadfile veränderte und meine (leicht verädnerte calcPerformance hinten angehängt:

    Spoiler anzeigen
    [autoit]

    #Include <Date.au3> ;am Anfang des Skriptes einbauen

    [/autoit] [autoit][/autoit] [autoit]

    Func LOADFILE($INETADRESS, $LOCALFILE) ;vorhandene func austauschen
    Local $iSize = InetGetSize($INETADRESS)
    Local $tStart = TimerInit(), $tDiff
    Dim $aData[3]
    Local $HDOWNLOAD = InetGet($INETADRESS, $LOCALFILE, 17, 1)
    Do
    $tDiff = TimerDiff($tStart)
    If $aData[0] > 0 Then
    _CalcPerformance($iSize, $aData[0], $aData[2], $tDiff)
    EndIf
    $aData = InetGetInfo($HDOWNLOAD, -1)
    Sleep(250)
    Until $aData[2]
    Local $aData = InetGetInfo($HDOWNLOAD)
    InetClose($HDOWNLOAD)
    If $aData[3] = True Then
    Return 1
    Else
    Return 0
    EndIf
    EndFunc ;==>LOADFILE

    [/autoit] [autoit][/autoit] [autoit]

    Func _CalcPerformance($iSize, $iRead, $bDone, $tDiff) ;zusätzliche neue func hinter LoadFile einfügen
    Local $sMSG
    $iToDo = Round(($iSize - $iRead) / 1024, 2)
    $nKBPerSec = Round($iRead / $tDiff * 1000 / 1024, 2)
    $iPercent = Round($iRead / $iSize * 100, 2)
    if ($iSize = 0) And Not $bDone Then
    $iRTime = "unbekannt"
    Else
    $iRTime = Round($iToDo / $nKBPerSec, 0)
    EndIf
    $sMSG = Round($iRead / 1024, 0) & "/" & Round($iSize / 1024, 0) & " KB " & " = " & $iPercent & "%" & @CRLF
    $sMSG &= "durchschnittlich KB/s = " & $nKBPerSec & @CRLF ;& "aktuell: KB/s " & $nKBAct & @CRLF
    If Not $bDone Then
    $sMSG = $sMSG & "vermutlich zu Ende:" & StringLeft(StringRight(_DateAdd('s', $iRTime, _NowCalc()), 8), 5)
    ;ConsoleWrite($sMSG & @CRLF)
    Else
    $sMSG = $sMSG & "benötigte Zeit = " & Round($tDiff / 1000, 0)
    EndIf
    TrayTip("downloading", $sMSG, 10, 16)
    EndFunc ;==>_CalcPerformance

    [/autoit]

    wenn du dieses Skriptteil einbaust habt ihr zumindest einen Traytipp, aber bitte nicht im Original sondern als neue Version speichern. Den Einbau in eure GUI solltest du eurem Programmierer überlassen, da ich ja nicht denke das du bereit bist den kompletten Source hier oder per PN an jemanden fremden zu geben,

    misterspeed,

    Zitat

    1 - Die Größe des Downloads (ist nicht immer vorhanden).


    mfg autoBert

    Hallo zusammen,

    ersteinmal ein Herzliches Dankeschön an alle die mir hier geholfen haben! Auch ein großes Danke dafür das das hier alles so super schnell und vorallem Kompetent ohne irgendwelche Sprüche von statten geht! SUPER Forum SUPER Community!

    misterspeed
    Ein besonderes Danke auch an dich für die viele Mühe die du dir gemacht hast um die verschiedenen Möglichkeiten auf zu zeigen und zu erklähren!

    autoBert
    Ich habe das mal so eingebaut und muss sagen als Übergangslösung ist das eine echt tolle Sache! Ich würde gerne mal etwas mit dir über PN oder falls du hast über Scype besprechen! Falls das ok für dich ist melde dich doch bitte und sage mir bescheid!

    Mfg an alle Ghostleader

    Einmal editiert, zuletzt von Ghostleader (13. Februar 2011 um 15:35)