rekusive Dateiliste plus Dateigrösse ermitteln und im Array anzeiegn

ugt100

Hallo zusammen,

habe da mal wieder ein Problem.
Und zwar muss ich auf verschiedenen Maschinen ein Dir /s *.* laufen lassen - also ab einem Enstiegspunkt die FileListe ermitteln.
Das gelingt mir auch schon unter Nutzung der (BugFix'schen) GetFilesFolderRekursiv UDF.
Das Ergebnis ist ein Array (angezeigt mit _ArrayDisplay) ...
Soweit - sogut.

Jetzt kommt aber mein Problem - denn ich benötige neben den Fileanmen auch noch die jeweilige Größe der gefundenen Datei.
Die Größe kann ich - so denke ich zumindest - ermitteln, wenn mittels UBOUND die einzelnen Elemente des Array 'lese' und mit
FileGetSize ermittle.

Doch wie schaffe ich es das (Gesamt)Ergebnis in ein 2 dim Array zu schreiben ?

Beispiel

d:\test
1.txt
2.txt
3.xls
4.doc

mit Hilfe von GetFilesFolderRekursiv bekomme ich folgendes Ergebnis

_ArrayDisplay
4
1.txt
2.txt
3.xls
4.doc

Jetzt Schleife + Ubound + FileGetSize
soll ergeben

_ArrayDisplay
4
1.txt 2,0 mb
2.txt 1,5 mb
3.xls 1,0 mb
4.doc 9,5 mb

Danke schon einmal im voraus

mfg
ugt100

**Schnitzel**

Am einfachsten gehts über ein neues Array

[autoit]

#include <Array.au3>
#include <File.au3>

[/autoit][autoit][/autoit][autoit]

$a = _FileListToArray(@Desktopdir)

[/autoit][autoit][/autoit][autoit]

_ArrayDisplay($a)
Local $a2[Ubound($a)][2] = [[$a[0], '']]
For $i = 1 To $a[0]
$a2[$i][0] = $a[$i]
$a2[$i][1] = Round(FileGetSize($a[$i])/1048576) & " MB"
Next
$a = ''
_ArrayDisplay($a2)

[/autoit]

ugt100

Hallo Schnitzel,

danke für die schnelle Antwort.
Das sieht soweit gut aus - leider werden die Filegrössen nicht richtig angezeigt bzw. der Wert ist immer 0 ....
Sieht so aus als ob das FileGetSize nicht zieht

Danke
Gruss
ugt100

**Schnitzel**

Hast du denn Dateien auf dem Desktop die größer als 500 KB sind?
Mein Beispiel arbeitet jetzt auch nicht rekursiv sondern zur Veranschaulichung nur mit den Dateien auf dem Desktop

ugt100

ja habe ich ich habe einfach folgendes ausprobiert

$cdeDir = "J:\installAIT"

$a = _FileListToArray($cdeDir)
.....

Warum 500 KB

**Schnitzel**

Weil ich die Round funktion verwendet habe. Und ab 500 KB auf 1 MB aufgerundet wird

Dann gilt die Frage für das installAIT Verzeichnis^^

ugt100

ja da gibt es Dateien von 28 KB bis 5 MB Größe

**Schnitzel**

Und die Dateien liegen direkt im Ordner "J:\installAIT"?

Bekommst du mit folgenden Code Dateien angezeigt die bei FileGetSize einen @error liefern?

[autoit]

#include <Array.au3>
#include <File.au3>

[/autoit][autoit][/autoit][autoit]

$cdeDir = "J:\installAIT"
$a = _FileListToArray($cdeDir)

[/autoit][autoit][/autoit][autoit]

Local $a2[Ubound($a)][2] = [[$a[0], '']]
For $i = 1 To $a[0]
$a2[$i][0] = $a[$i]
$iSize = FileGetSize($a[$i])/1048576
If @error Then ConsoleWrite("Fehler bei Datei: " & $a[$i] & @LF)
$a2[$i][1] = Round($iSize) & " MB"
Next
$a = ''
_ArrayDisplay($a2)

[/autoit]

ugt100

Hi Schnitzel,

also offensichtlich wird die DateiListe eingelesen und dann bei der Ermittlung der FileGröße läuft das Script auf einen Fehler - und zwar bei allen gefundenen Dateien.
Anders ausgedrückt die Grösse wird nicht zurückgegeben.

ugt100

So sieht das Verzeichnis aus

DIR = $PLUGINSDIR
DIR = $PROFILE
DIR = ADAT
DIR = AD_Func
DIR = api
Au3Check.dat
Au3Check.exe
Au3Info.exe
Au3Info_x64.exe
DIR = Aut2Exe
AutoIt v3 Website.url
AutoIt.chm
AutoIt.chw
AutoIt3.chm
AutoIt3.chw
AutoIt3.exe
AutoIt3Help.exe
AutoIt3Wrapper
AutoIt3_x64.exe
DIR = AutoItX
DIR = CodeWizard
DIR = cSnippet
DIR = Defs
DIR = Examples
DIR = Extras
findstr.au3
findstr.exe
DIR = Icons
DIR = Include
DIR = Koda
DIR = lua
MS_SystemErrorCodes.txt
DIR = Obfuscator
DIR = OL_Func
DIR = Properties
SciLexer.dll
DIR = SciTe
SciTE.exe
SciTE4AutoIt3.chm
DIR = SciTEConfig
SciTEGlobal.properties
DIR = SciTEJump
DIR = Tidy
UDFs3.chm
UDFs3.chw
DIR = _Snips

**Andy**

Hi,
man sollte an filegetsize() den gesamten Pfad übergeben und nicht nur den Dateinamen.

Spoiler anzeigen

[autoit]

#include <Array.au3>
#include <File.au3>

[/autoit] [autoit][/autoit] [autoit]

$pfad = "c:\windows\system32"
$a = _GetFilesFolder_Rekursiv($pfad, '*', 0)
;_ArrayDisplay($a)

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

Local $a2[Ubound($a)][2] = [[$a[0], '']]
For $i = 1 To $a[0]
$a2[$i][0] = $a[$i]
$iSize = FileGetSize($a[$i])/1028
If @error Then ConsoleWrite("Fehler bei Datei: " & $a[$i] & @LF)
$a2[$i][1] = Round($iSize) & " kB"
Next
$a = ''
_ArrayDisplay($a2)

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

;==================================================================================================
; Function Name: _GetFilesFolder_Rekursiv($sPath [, $sExt='*' [, $iDir=-1 [, $iRetType=0 ,[$sDelim='0']]]])
; Description: Rekursive Auflistung von Dateien und/oder Ordnern
; Parameter(s): $sPath der Basispfad für die Auflistung ('.' -aktueller Pfad, '..' -Parentpfad)
; $sExt Erweiterung für Dateiauswahl '*' oder -1 für alle (Standard)
; $iDir -1 Dateien+Ordner(Standard), 0 nur Dateien, 1 nur Ordner
; optional: $iRetType 0 gibt Array, 1 gibt String zurück
; optional: $sDelim legt Trennzeichen für Stringrückgabe fest
; 0 -@CRLF (Standard) 1 -@CR 2 -@LF 3 -';' 4 -'|'
; Return Value(s): Array (Standard) od. String mit den gefundenen Pfaden der Dateien und/oder Ordner
; Array[0] enthält die Anzahl der gefundenen Dateien/Ordner
; Author(s): BugFix ([email='bugfix@autoit.de'][/email])
;==================================================================================================
Func _GetFilesFolder_Rekursiv($sPath, $sExt='*', $iDir=-1, $iRetType=0, $sDelim='0')
Global $oFSO = ObjCreate('Scripting.FileSystemObject')
Global $strFiles = ''
Switch $sDelim
Case '1'
$sDelim = @CR
Case '2'
$sDelim = @LF
Case '3'
$sDelim = ';'
Case '4'
$sDelim = '|'
Case Else
$sDelim = @CRLF
EndSwitch
If ($iRetType < 0) Or ($iRetType > 1) Then $iRetType = 0
If $sExt = -1 Then $sExt = '*'
If ($iDir < -1) Or ($iDir > 1) Then $iDir = -1
_ShowSubFolders($oFSO.GetFolder($sPath),$sExt,$iDir,$sDelim)
If $iRetType = 0 Then
Local $aOut
$aOut = StringSplit(StringTrimRight($strFiles, StringLen($sDelim)), $sDelim, 1)
If $aOut[1] = '' Then
ReDim $aOut[1]
$aOut[0] = 0
EndIf
Return $aOut
Else
Return StringTrimRight($strFiles, StringLen($sDelim))
EndIf
EndFunc

[/autoit] [autoit][/autoit] [autoit]

Func _ShowSubFolders($Folder, $Ext='*', $Dir=-1, $Delim=@CRLF)
If Not IsDeclared("strFiles") Then Global $strFiles = ''
If ($Dir = -1) Or ($Dir = 0) Then
For $file In $Folder.Files
If $Ext <> '*' Then
If StringRight($file.Name, StringLen($Ext)) = $Ext Then _
$strFiles &= $file.Path & $Delim
Else
$strFiles &= $file.Path & $Delim
EndIf
Next
EndIf
For $Subfolder In $Folder.SubFolders
If ($Dir = -1) Or ($Dir = 1) Then $strFiles &= $Subfolder.Path & '\' & $Delim
_ShowSubFolders($Subfolder, $Ext, $Dir, $Delim)
Next
EndFunc

[/autoit]

ugt100

Hi Andy,

genau dieser Gedanke ist mir eben auch eaufgekommen .... gleich mal testen DANKE

**Schnitzel**

Jup flüchtigkeitsfehler. Mit GetFilesFolderRekursiv hätts funktioniert

ugt100

Super jetzt funktioniert es ....

DANKE Schnitzel / DANKE Andy

wie immer einfach Supi das Forum

Gruss
ugt100