Geschlossen: AutoIt-Kalender

jonk

Klar, wollte das Projekt ja auch nicht für unnötig erklären. Vielleicht kann ePIM ja ein paar Anregungen geben

**Gun-Food**

Und es macht Spaß!
Übersetzungen sind ohne große Umwege möglich....
Naja. das $gui_mnu_file hab ich ja auch aus peethebees script, weil er darin ja in seinem Menü die GUI für die Einstellungen auffruft.
Daher musste ich sie ja verwenden, um nicht peethebees "Link" ändern zu müssen.
Oder hab ich da was falsch verstanden.
Hab halt bisher nur Scripte für die Kommandozeile in AutoIt geschrieben.

**peethebee**

Hallo!

@Gun:
Wenn du bisher nur auf der Kommandozeile codest, hast du so einiges verpassat. GUIs sind top!
Also, meine Variable kann dir herzlich egal sein. Sie enthält die Control ID des Menüeintrages. Die brauche ich nur bei mir, um die Funktion aufzurufen, die ausgeführt werden soll, wenn man drauf klickt. Innerhalb der Funktion steht dann dein Skript. Daher solltest du deine GUI-ID in einer anderen Varibalen speichern, damit dann der Zugriff auf deine GUI auch gesichert ist. Außerdem werde ich versuchen, mal ein Child-Window aus deiner GUI zu machen.

Kennst du dich mit Subversion oder CSV aus, Gun-Food? Dann wäre die Arbeit evtl. viel leichter, leider kenne ich mich damit nicht aus. Habe gesehen, dass es jetzt bei SciTE4AutoIt ein PlugIn für die Versionverwaltung gibt, ob die allerdings online geht, weiß ich nicht.

Was mir noch nicht ganz klar ist, ist, wie du dir die Anzeige der Termine vorstellst. Das es ein Control gibt, das gleich ein ganzes Jahr darstellt wusste ich gar nicht.

peethebee

Edit: Neue Variante im Anhang.

**GtaSpider**

Hallo!

hab nochmal ne frage: mach ich das mit der Kategorie (neu erstellen) oder du?
Wenn ich es mache hätt ich nochmal ne frage: wer Outlook kennt, kennt das: eine ComboBox mit Färbenden kästchen links und rechts den Text(im anhang ein Bild) meine überlegung: (musst du nich lesen wenn du nich viel zeit hast..)

Spoiler anzeigen

ein ListView zu machen die erstmal nur einzeilig ist und da neben ein Button der ein "v" als text hat(das nach unten zeichen der Combo) und dann die Liste rausfahren würde und die List häte den Style $LVS_SMALLICONS und da bilder reinpacken mit verschiedenen farben... ist nich gut weil man daunter ordentlich platz brauch, und weil man wirklich bilder brauch und nich ein Label das kein text hat und als hintergrund irgendeine farbe oder eine Graphic mit hintergrund..

Also lange rede Kurzer sinn wie kann ich das mit einer ComboBox machen? also mit einer echten, so wie in outlook? weiß jmd rat?

Mfg Spider

**bernd670**

Hallo,

Zitat

Also lange rede Kurzer sinn wie kann ich das mit einer ComboBox machen? also mit einer echten, so wie in outlook? weiß jmd rat?

Mit einer normalen ComboBox geht das nicht dafür benötigt man die ComboBoxEx. Diese ist aber in AutoIt (noch?) nicht umgesetzt!

Im englischen Forum habe ich was gefunden. Habs aber nicht getestet ;-).

**GtaSpider**

Hallo

Also mit ComboBoxEx hab ich paar ocx dateien gefunden, funktioniert aber nicht mit autoit..

Wenn ich das vom Engl Forum ausprobiere versucht Microsoft office 03 etwas zu installieren..

aber danke für dein Rat werde nochmal das inet etwas durchforsten,,

Mfg Spider

**peethebee**

Hallo!

Was sicher auch cool wäre, wären die neuen ListViews, die man jetzt Eintrasweise färben kann soiviel ich weiß...

peethebee

**GtaSpider**

Hallo!

Ja das klappt perfekt! Das könnte man natürlcih auch machen
z.b. so:
Brauch BETA 3.1.1.126 oder höher

Code

#include <GUIConstants.au3>
### Koda GUI section start ###
$Form1 = GUICreate("AForm1", 269, 176, 193, 126)
$ListView1 = GUICtrlCreateListView("test01|test02", 8, 8, 250, 150)
$ListView1_0 = GUICtrlCreateListViewItem("Test|ttteeesssttt", $ListView1)
GUICtrlSetBkColor(-1,0xff0000)
$ListView1_1 = GUICtrlCreateListViewItem("etst|testtest", $ListView1)
GUICtrlSetBkColor(-1,0x00bb00)
GUISetState(@SW_SHOW)
### Koda GUI section end   ###
While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd

Alles anzeigen

Mfg Spider

**peethebee**

Ich finde das schon nahe am Optimum. Farbe ist deutlich zu erkennen. Man muss evtl noch darüber nachdenken, ob man die Textfarbe dann auf die Komplementärfarbe setzt, daber das ist erst mal egal, denke ich.

peethebee

**Gun-Food**

So und jetzt ich.
Ich lad gerade alles ins Repository (subversion) hoch.
Anleitung folgt.
Für alle die sich auskennen:

Code

svn://subversion@autoit.aufwaerts.de

Viel Spaß. *gg*

**peethebee**

Super, Gun-Food, aber ich brauche wirklich eine Anleitung - oder zumindest einen Link irgendwohin, wo es so was gibt

Ich les mal das: http://www.autoitscript.com/autoit3/scite/cvsWrapper.php

peethebee

**GtaSpider**

Hallo

Hab jetzt mal erstmal die rohe Alpha GUI erstellt, freue mich auf anrehgungen und lob =)

aso und noch ne frage: wie kann man das Date controll editieren?

Spoiler anzeigen

C

;======================================================================
; =========================================================================================================
; =========================================   G a l e n d a  ==============================================
; =========================================================================================================
; =========================================================================================================
;                                 eine Kalenderapplikation in AutoIt
; =========================================================================================================
; Contributors: peethebee (Idee, MainGUI, Rahmenfunktionen, TextEffects UDF)
;               GtaSpider (Eintrag hinzufügen?)
;               Schwester (Logo)
;               Gun-Food (Einstellungsmenü)


; ===========================
; AutoIt options
; ===========================
Opt("GUIOnEventMode", 1) ; wichtig! Bitte beachten! Macht Dinge bei einem so großen Skript wesentlich einfacher


; ===========================
; includes
; ===========================
#include <GUIConstants.au3>
#Include <GuiStatusBar.au3>
#Include <text_effects.au3> ; by peethebee


; ===========================
; HotKey definitions
; ===========================




; ===========================
; Constants
; ===========================
Const $program_name = "Galenda"
Const $program_version = "0.0"


; ===========================
; Global vars & Config vars
; ===========================
Global $open_cal_path = ""
Global $gui_width = 1024
Global $gui_height = 740
Global $splash_width = 500
Global $splash_height = 400
Global $view_type = ""
Global $help_file_path = @ScriptDir & "\Dokumentation.txt"
Global $GUI_BK_COLOR = 0x66aaff
Global $newTaskopened = 0




; ===========================
; Main program
; ===========================


; Startup
SplashImageOn("", @ScriptDir & "\logo.jpg", $splash_width, $splash_height, Default, Default, 19)
; hier evlt. kleine Aufgaben erledigen, da das BIld agezeigt werden muss, sonst Sleep
; Debug-Log-File löschen
$file_log = FileOpen(@ScriptDir & "\log.txt", 2)
FileClose($file_log)
;~ Sleep(3000)


; GUI aufbauen
$gui_main = GUICreate($program_name & " " & $program_version & " - Hauptfenster", $gui_width, $gui_height, 0, 0, $WS_SIZEBOX)
GUISetBkColor($GUI_BK_COLOR, $gui_main)
GUISetOnEvent($GUI_EVENT_RESIZED, "_stbResize")
GUISetOnEvent($GUI_EVENT_CLOSE, "_close")
; Mainmenü
;  Datei
;   Kalender-Aufgaben
$gui_mnu_file = GUICtrlCreateMenu("&Datei")
$gui_mnu_file_new = GUICtrlCreateMenuitem("&Neuer Kalender", $gui_mnu_file)
GUICtrlSetOnEvent(-1, "_cal_new")
$gui_mnu_file_open = GUICtrlCreateMenuitem("Kalender ö&ffnen", $gui_mnu_file)
GUICtrlSetOnEvent(-1, "_cal_open")
$gui_mnu_file_backup = GUICtrlCreateMenuitem("Kalender-&Backup speichern", $gui_mnu_file)
GUICtrlSetOnEvent(-1, "_cal_backup")
$gui_mnu_file_backup = GUICtrlCreateMenuitem("", $gui_mnu_file)
;   Einstellungen
$gui_mnu_file_settings = GUICtrlCreateMenuitem("&Programmeinstellungen", $gui_mnu_file)
GUICtrlSetOnEvent(-1, "_change_settings")
GUICtrlCreateMenuitem("", $gui_mnu_file)
;   Beenden
$gui_mnu_file_close = GUICtrlCreateMenuitem($program_name & " been&den", $gui_mnu_file)
GUICtrlSetOnEvent(-1, "_close")
;  Ansicht
$gui_mnu_view = GUICtrlCreateMenu("&Ansicht")
;   Tag
$gui_mnu_view_day = GUICtrlCreateMenuitem("&Tagesansicht", $gui_mnu_view, -1, 1)
GUICtrlSetOnEvent(-1, "_change_view_day")
;   Woche
$gui_mnu_view_week = GUICtrlCreateMenuitem("&Wochenansicht", $gui_mnu_view, -1, 1)
GUICtrlSetOnEvent(-1, "_change_view_week")
;   Monat
$gui_mnu_view_month = GUICtrlCreateMenuitem("&Monatsansicht", $gui_mnu_view, -1, 1)
GUICtrlSetOnEvent(-1, "_change_view_month")
; Neuer Termin
$gui_mnu_task = GUICtrlCreateMenu("&Termin")
;   neuer Termin
$gui_mnu_task_new = GUICtrlCreateMenuitem("&Neuen Termin anlegen", $gui_mnu_task)
GUICtrlSetOnEvent(-1, "_newTask")
; Hilfe
$gui_mnu_help = GUICtrlCreateMenu("&Hilfe")
;   Info
$gui_mnu_help_info = GUICtrlCreateMenuitem("&Info", $gui_mnu_help)
GUICtrlSetOnEvent(-1, "_help_info")
;   Dokumentation
$gui_mnu_help_documentation = GUICtrlCreateMenuitem("&Dokumentation", $gui_mnu_help)
GUICtrlSetOnEvent(-1, "_help_docu")
GUICtrlCreateMenuitem("", $gui_mnu_help)
;   Credits
$gui_mnu_help_info = GUICtrlCreateMenuitem("&Info", $gui_mnu_help)
GUICtrlSetOnEvent(-1, "_help_credits")


; Groupboxes
;  Termine
$gui_gru_tasks = GUICtrlCreateGroup("Termine", 10, 10, 720, 600)
GUICtrlSetFont(-1, 12, 800)
GUICtrlSetResizing(-1, $GUI_DOCKLEFT + $GUI_DOCKTOP) ; left und top
;~ $gui_xxx_1 = GUICTRLCREATE?? - das wird das Control, um die Termine anzuzeigen, entweder Labels, IE-ActiveX oder Graphic
;  Details
$gui_gru_details = GUICtrlCreateGroup("Details", 740, 10, 270, 600)
GUICtrlSetFont(-1, 12, 800)
GUICtrlSetResizing(-1, $GUI_DOCKRIGHT + $GUI_DOCKTOP) ; left und top
$gui_details_lbl_title = GUICtrlCreateLabel("[Titel]", 750, 40, 250)
GUICtrlSetFont(-1, 14, 800)
$gui_details_lbl_description = GUICtrlCreateLabel("[Beschreibung, die auch mal länger sein und sich über mehrere Zeilen erstrecken kann. Länger als diese hier sollte sie aber nicht sein...]", 750, 70, 250, 80)
GUICtrlSetFont(-1, 11, 400, 2)
$gui_details_lbl_date = GUICtrlCreateLabel("[Montag, 12.06.2006 (bis Dienstag, 13.06.2006)]", 750, 160, 250, 80)
GUICtrlSetFont(-1, 12, 600)
$gui_details_lbl_time = GUICtrlCreateLabel("[10:00 Uhr bis 12:00 Uhr]", 750, 210, 250, 80)
GUICtrlSetFont(-1, 12, 600)
$gui_details_lbl_category = GUICtrlCreateLabel("Kategorie: [Fußball-WM 2006]", 750, 260, 210, 80)
GUICtrlSetFont(-1, 12, 300)
$gui_details_lbl_category_color = GUICtrlCreateLabel("", 980, 260, 20, 20)
GUICtrlSetBkColor(-1, 0x00ffe3)




; Dummy (v.a. für AboutBox)
$gui_dmy_1 = GUICtrlCreateDummy()
; statusbar
$gui_stb_1 = _GuiCtrlStatusBarCreate($gui_main, -1, "")
_GuiCtrlStatusBarSetSimple($gui_stb_1)
_SetStatus("Main GUI aufgebaut")
$MonthCal1 = GUICtrlCreateMonthCal("2006/06/09", 30, 50, 671, 442)
_SetStatus("Main GUI angezeigt")


#region By GtaSpider


$from_Time = @HOUR ;Hier wird die für den User eine Kompfortable Zeit ermittelt
$to_Time = @HOUR + 1
If @MIN > 30 Then
	$from_Time &= ":30:00"
	$to_Time &= ":30:00"
Else
	$from_Time &= ":00:00"
	$to_Time &= ":00:00"
EndIf


$newTask = GUICreate("Galenda - Neuer Termin", 746, 555, 188, 137)
GUISetBkColor($GUI_BK_COLOR, $newTask)




$data_menu = GUICtrlCreateMenu("&Datei")
$data_menu_Open = GUICtrlCreateMenuitem("&Öffnen", $data_menu)
$data_menu_Save = GUICtrlCreateMenuitem("&Speichern", $data_menu)
$data_menu_Save_As = GUICtrlCreateMenuitem("Speichern &Unter...", $data_menu)


$art_of_date = GUICtrlCreateButton("Art des Termines", 640, 72, 91, 21)
GUICtrlCreateLabel("Name des Termines:", 10, 9, 101, 15, $WS_GROUP)
$name_of_date = GUICtrlCreateInput("", 10, 24, 721, 21)
GUICtrlCreateLabel("Ort:", 10, 56, 101, 15)
$place_of_date = GUICtrlCreateInput("", 10, 72, 625, 21)
$info_of_date = GUICtrlCreateEdit("", 10, 176, 729, 361)
$from_Date = GUICtrlCreateDate("", 10, 112, 82, 21, $DTS_SHORTDATEFORMAT)
GUICtrlCreateLabel("Von:", 10, 96, 26, 15)
$till_Date = GUICtrlCreateDate("", 96, 112, 82, 21, $DTS_SHORTDATEFORMAT)
GUICtrlCreateLabel("Bis:", 96, 96, 26, 15)
$from_Time = GUICtrlCreateDate($from_Time, 10, 136, 82, 21, $DTS_TIMEFORMAT)
$till_Time = GUICtrlCreateDate($to_Time, 96, 136, 82, 21, $DTS_TIMEFORMAT)
$remember = GUICtrlCreateCheckbox("Erinnern:", 192, 112, 65, 17)
$time_d_h_m = GUICtrlCreateInput("0", 264, 112, 48, 21)
GUICtrlCreateUpdown(-1)
$d_h_m_combo = GUICtrlCreateCombo("", 312, 112, 81, 21)
GUICtrlSetData(-1, "Tag(e)|Stunde(n)|Minute(n)", "Minute(n)")
GUICtrlCreateLabel("Voher", 400, 115)
$bell = GUICtrlCreateButton("", 192, 132, 32, 32, $BS_ICON)
GUICtrlSetImage(-1, "bell.ico")


GUISetOnEvent($data_menu_Open, "_Open")
GUISetOnEvent($data_menu_Save_As, "_Save")
GUISetOnEvent($GUI_EVENT_CLOSE, "_newtaskclose")
_SetStatus("NewTask GUI aufgebaut")


#endregion By GtaSpider


; Splash weg und GUI her:
SplashOff()
GUISetState(@SW_SHOW, $gui_main)


While 1
	Sleep(15)
WEnd






; ===========================
; Functions
; ===========================


; Diese Funktion setzt den Statusbar-Text wie gewünscht und schreibt den Text gleichzeitig in ein Log-File. Bitte nach jeder größeren Aktion aufrufen!
; by peethebee
Func _SetStatus($_setStatus_text)
	; Statusbar-Text setzen
	_GuiCtrlStatusBarSetText($gui_stb_1, "simple mode", 0)
	; Log-File erweitern
	$file_setStatus = FileOpen(@ScriptDir & "\log.txt", 1)
	FileWriteLine($file_setStatus, $_setStatus_text)
	FileClose($file_setStatus)
EndFunc   ;==>_SetStatus


Func _stbResize()
	_GuiCtrlStatusBarResize($gui_stb_1)
EndFunc   ;==>_stbResize


Func _close()
	TrayTip("", "", 3)
	If $newTaskopened = 1 Then
		$msgbox = MsgBox(67, $program_name, "Wollen Sie vor dem Schließen Speichern?")
		If $msgbox = 7 Then
			$newTaskopened = 0
			GUISetState(@SW_HIDE, $newTask)
			_SetStatus("Main GUI Versteckt")
			Return
		EndIf
		If $msgbox = 6 Then _Save("", 1)
	Else
		If MsgBox(4 + 32 + 256 + 8192, $program_name & " beenden", "Soll " & $program_name & " wirklich beendet werden?") = 6 Then
			_SetStatus($program_name & " beendet")
			Exit
		EndIf
	EndIf
EndFunc   ;==>_close


Func _newtaskclose()
	If $newTaskopened = 1 Then
		$msgbox = MsgBox(67, $program_name, "Wollen Sie vor dem Schließen Speichern?")
		If $msgbox = 7 Then
			$newTaskopened = 0
			GUISetState(@SW_HIDE, $newTask)
			_SetStatus("Main GUI Versteckt")
			Return
		EndIf
		If $msgbox = 6 Then _Save("", 1)
	EndIf
EndFunc   ;==>_newtaskclose


Func _cal_new()
	; neuen Kalender erzeugen (im Wesentlichen Datei anlegen und Einstellungen vorbelegen)
EndFunc   ;==>_cal_new


Func _cal_open()
	; vorhandenen Kalender öffnen. wichtig: alte Sachen löschen und Funktionen aufrufen, um neue zu zeichnen
EndFunc   ;==>_cal_open


Func _cal_backup()
	; Kalenderdatei an anderen Ort kopieren

EndFunc   ;==>_cal_backup


; by Gun-Food
Func _change_settings()
	$gui_settings = GUICreate("Einstellungen", 622, 441, 314, 412, -1, -1, $gui_main)
	$individual = GUICtrlCreateGroup("Individuelle Einstellungen", 216, 8, 185, 369)
	GUICtrlCreateGroup("", -99, -99, 1, 1)
	$security = GUICtrlCreateGroup("Sicherheitseinstellungen", 424, 8, 185, 369)
	GUICtrlCreateGroup("", -99, -99, 1, 1)
	$general = GUICtrlCreateGroup("Generelle Einstellungen", 8, 8, 185, 369)
	GUICtrlCreateGroup("", -99, -99, 1, 1)
	GUICtrlCreateLabel("Automatisch mit Windows laden", 24, 32, 154, 17)
	$yes_start = GUICtrlCreateRadio("Ja", 24, 48, 41, 17)
	$no_start = GUICtrlCreateRadio("Nein", 96, 48, 65, 17)
	GUICtrlSetState(-1, $GUI_CHECKED)
	GUICtrlCreateGroup("", -99, -99, 1, 1)
	GUICtrlCreateLabel("Übersichtsseite:", 24, 112, 79, 17)
	$view_day = GUICtrlCreateRadio("Tagesansicht", 24, 136, 113, 17)
	GUICtrlSetState(-1, $GUI_CHECKED)
	$view_week = GUICtrlCreateRadio("Wochenansicht", 24, 160, 113, 17)
	$view_month = GUICtrlCreateRadio("Monatsansicht", 24, 184, 113, 17)
	$view_year = GUICtrlCreateRadio("Jahresansicht", 24, 208, 113, 17)
	GUICtrlCreateGroup("", -99, -99, 1, 1)
	GUICtrlCreateLabel("Fragen vor Schließen", 24, 72, 105, 17)
	$yes_close = GUICtrlCreateRadio("Ja", 24, 88, 49, 17)
	GUICtrlSetState(-1, $GUI_CHECKED)
	$no_close = GUICtrlCreateRadio("Nein", 96, 88, 57, 17)
	GUICtrlCreateGroup("", -99, -99, 1, 1)
	$button_save = GUICtrlCreateButton("Speichern", 528, 400, 75, 25)
	$button_cancel = GUICtrlCreateButton("Abbrechen", 432, 400, 75, 25)
	GUISetState(@SW_SHOW, $gui_settings)
EndFunc   ;==>_change_settings


Func _change_view_day()
	GUICtrlSetState($gui_mnu_view_day, $GUI_CHECKED)
	$view_type = "day"
	_showTasks($view_type)
EndFunc   ;==>_change_view_day


Func _change_view_week()
	GUICtrlSetState($gui_mnu_view_week, $GUI_CHECKED)
	$view_type = "week"
	_showTasks($view_type)
EndFunc   ;==>_change_view_week


Func _change_view_month()
	GUICtrlSetState($gui_mnu_view_month, $GUI_CHECKED)
	$view_type = "month"
	_showTasks($view_type)
EndFunc   ;==>_change_view_month


Func _showTasks($_showTasks_type, $_showTasks_start_date = "today", $_showTasks_end_date = "today", $_showTasks_exclude_kategories = "none")

EndFunc   ;==>_showTasks




Func _help_info()
	MsgBox(0 + 64, "Informationen", "Sie nutzen " & @CRLF & @CRLF & $program_name & @CRLF & $program_version & @CRLF & @CRLF & "Dieses Programm ist Freeware. Es darf verbreitet und kopiert werden, solange damit in keiner Art Gewinn erzielt wird (z.B. erhöhter Verkauf von Zeitschriften). Dafür ist eine Genehmigung bei peethebee@gmx.de einzuholen!" & @CRLF & @CRLF & "Vielen Dank, dass Sie " & $program_name & " nutzen!" & @CRLF & @CRLF & "Die Autoren")
EndFunc   ;==>_help_info


Func _help_docu()
	Run(@ComSpec & " /c Start " & FileGetShortName($help_file_path), @ScriptDir, @SW_HIDE)
EndFunc   ;==>_help_docu


Func _help_credits()
	Local $about[18], $times[1]
	$about[0] = "=== Idee ==="
	$about[1] = "peethebee"
	$about[2] = ""
	$about[3] = "=== Programmierer ==="
	$about[4] = "peethebee, GtaSpider, Gun-Food"
	$about[5] = ""
	$about[6] = "=== Design ==="
	$about[7] = "Programmierer & Schwester"
	$about[8] = ""
	$about[9] = "=== Forum ==="
	$about[10] = "http://www.autoit.de"
	$about[11] = ""
	$about[12] = "Feedback ist immer willkommen!"
	$about[13] = "peethebee@gmx.de"
	$about[14] = ""
	$about[15] = "=== Greetz ==="
	$about[16] = "Jonathan Bennett && Team"

	$times[0] = 2500

	_txt_eff__about_messages ($gui_main, $gui_dmy_1, $about, 15, $times, 1, "modern")
EndFunc   ;==>_help_credits


; Diese Funktion zeigt den Drucken-Dialog für eine bestimmte HTML-Seite an.
; By GtaSpider, not approved
Func _print()
	RunWait('rundll32.exe ' & @SystemDir & '\mshtml.dll,PrintHTML C:\Downloads\javacooksrc2\index.html', @SystemDir)
EndFunc   ;==>_print


#region By GtaSpider


;Zeigt die "newTask" GUI an!
Func _newTask()
	_SetStatus("NewTask GUI angezeigt")
	$newTaskopened = 1
	GUISetState(@SW_SHOW, $newTask)
EndFunc   ;==>_newTask


Func _Save($save_file = "", $exit = 0)
	If $save_file = "" Then $save_file = FileSaveDialog("", "", "Galenda Dateien(*.gld)|Alle Dateien(*.*)", 16)
	If @error Then Return

	FileWriteLine($save_file, "#Galenda Termin - Version " & FileGetVersion(@ScriptFullPath))
	IniWrite($save_file, "Name", "Name", GUICtrlRead($name_of_date))
	IniWrite($save_file, "Name", "Ort", GUICtrlRead($place_of_date))
	IniWrite($save_file, "Zeit", "Von_Datum", GUICtrlRead($from_Date))
	IniWrite($save_file, "Zeit", "Von_Zeit", GUICtrlRead($from_Time))
	IniWrite($save_file, "Zeit", "Bis_Datum", GUICtrlRead($till_Date))
	IniWrite($save_file, "Zeit", "Bis_Zeit", GUICtrlRead($till_Time))
	IniWrite($save_file, "Optionen", "Erinnern", GUICtrlRead($remember))
	IniWrite($save_file, "Optionen", "Erinnern_Zeit", GUICtrlRead($time_d_h_m))
	IniWrite($save_file, "Optionen", "Erinnern_Formart", GUICtrlRead($d_h_m_combo))
	If $exit <> 0 Then
		$newTaskopened = 0
		GUISetState(@SW_HIDE, $newTask)
		_SetStatus("Main GUI Versteckt")
	EndIf
;~ 	IniWrite($save_file,"Optionen","Sound",GUICtrlRead($sound))
EndFunc   ;==>_Save


Func _Open($open_file = "")
	If $open_file = "" Then $open_file = FileOpenDialog("", "", "Galenda Dateien(*.gld)|Alle Dateien(*.*)")
	If @error Then Return

	FileWriteLine($open_file, "#Galenda Termin - Version " & FileGetVersion(@ScriptFullPath))
	GUICtrlSetData($name_of_date, IniRead($open_file, "Name", "Name", "Error"))
	GUICtrlSetData($place_of_date, IniRead($open_file, "Name", "Ort", GUICtrlRead($name_of_date)))
	GUICtrlSetData($from_Date, IniRead($open_file, "Zeit", "Von_Datum", GUICtrlRead($from_Date)))
	GUICtrlSetData($from_Time, IniRead($open_file, "Zeit", "Von_Zeit", GUICtrlRead($from_Time)))
	GUICtrlSetData($till_Date, IniRead($open_file, "Zeit", "Bis_Datum", GUICtrlRead($till_Date)))
	GUICtrlSetData($till_Time, IniRead($open_file, "Zeit", "Bis_Zeit", GUICtrlRead($till_Time)))
	GUICtrlSetState($remember, IniRead($open_file, "Optionen", "Erinnern", 1))
	GUICtrlSetData($time_d_h_m, IniRead($open_file, "Optionen", "Erinnern_Zeit", GUICtrlRead($time_d_h_m)))
	GUICtrlSetData($d_h_m_combo, IniRead($open_file, "Optionen", "Erinnern_Formart", GUICtrlRead($d_h_m_combo)))
;~ 	GuiCtrlSetData($sound ,IniRead($open_file,"Optionen","Sound",""))
EndFunc   ;==>_Open
#endregion By GtaSpider

Alles anzeigen

Edit: hab es in der Main intriegriert.. im anhang Bell.ico+Script+Text_effects.au3

Mfg Spider

**Gun-Food**

Sieht klasse aus. Hab meine Einstellungen auch umgebaut. Ist noch nicht so klasse, aber liegt zum schauen schonmal im SVN. Anleitung wird gerade erstellt. Sonst meine galenda_main.au3 erstmal noch anbei zusätzlich.

**peethebee**

Hallo!

Mal noch ein paar Punkte, so allgemein:

Wichtig wäre mir auch Backup-Funktionalität. Was einfach zu implementieren ist, ist das Speichern eines Backups nach KLick auf Datei -> Backup. Noch cooler wäre eine Funktion zum paralleln Speichern in zwei Dateien, quasi ein simuliertes "Software-RAID".

Und wie wir die Kalenderdaten speichern bin ich mir auch noch unschlüssig. Meine beste Idee bisher ist ein Unterverzeichnis pro Kalender. Darin die Date mit den Terminen und eine Settings.ini oder so. Dann kann man Einstellungen leichter speichern und auslesen.

peethebee

**Gun-Food**

Da GTA im Script ja schon damit angefangen hat, nehm ich auch ne "settings.gld" Datei für die Einstellungen. Passt das?
Gerade auch relevant für die Anzeige der Ansicht ob täglich, wöchentlich, moantlich oder jährlich beim öffnen von Galenda.
Die kann dann ja auch pro Galenda pro User erzeugt werden. Dann sind mehrere unabhängige Galenda möglich.

**peethebee**

Ja, so hatte ich das jetzt vor. Und evtl. noch eine Settingss.gld insgesamt (welcher Kalender Standard ist und so).

peethebee

**Gun-Food**

Wegen der Farbe. Kann man der Combo nicht sagen, sie soll ne andere Hintergrundfarbe pro EWintrag verwenden?
in HTML geht das doch auch.

**peethebee**

Bei einer Combo glaube ich nicht. Aber kann man ja mal versuchen.
HTML rockt ja auch

peethebee

**peethebee**

Hallo!

An die Devs:
Bitte benenne Varaiblen so, dass man erkennen kann, was drin ist. Alles, was IDs von Controls enthält, sollte auch entweder eine 3-buchstabige Controlbezeichnung (lbl, btn, lst, ...) oder wenigstens gui enthalten. Die GUIs heißen $gui_newTask, $gui_main und $gui_settings. So hat man wenigstens eine Chance, sich in den fremden Code einzulesen. Und jeder KOmmentra wird mit Handkuss entgegen genommen

Edit: GtaSpider hat ja sogar _SetSTatus aufgerufen - nice...

peethebee

**Gun-Food**

Werd heute mal ein wenig weniger für den Galenda machen können, die Natur ruft. *gg*
Hoffe es passt sonst mit den SVN und Gta kommt auch mit zurecht.