TCP-Verbindung überprüfen ohne Unterbrechung

Homer J. S.

Hallo Zusammen,
ich habe mal wieder ein Problem, wofür ich eure Hilfe benötige. Ich habe eine App welches über TCP mit meinem Skript kommuniziert. Allerdings habe ich keine Kontrolle darüber, ob die TCP-Verbindung von der App unerbrochen worden ist (z.B. beim schließen der APP), um eine neue Connection zu starten. Eine
fiktive If-Abfrage zum verlassen der Schleife, um einen neue Connection zu starten, habe ich schon eingebunden.

Hier mein Test Skript:

Spoiler anzeigen

Code

;Init
OnAutoItExitRegister("OnAutoItExit")
TCPStartup()


;Init Variablen
$IP='192.168.10.50'
$PORT=54321
$LISTEN=TCPListen($IP, $PORT)
$ACCEPT=0


;Mainloop
While 1
	While 1
		$ACCEPT=TCPAccept($LISTEN)
		If ($ACCEPT>0) Then ExitLoop
		Sleep(10)
	WEnd
	ConsoleWrite('Verbunden'&@CRLF)
	While 1
		While 1
			$RECEIVE=TCPRecv($ACCEPT, 1024)
			If Not @error Then ExitLoop
		        Sleep(10)
		WEnd
		While 1
			$RECEIVE&=TCPRecv($ACCEPT, 1024)
			If (@error) Then ExitLoop
		WEnd
		TCPSend($ACCEPT ,@LF) ;Linefeed -> Acknowledged
		ConsoleWrite($RECEIVE & @CRLF)
		;If Verbindung der App==Unterbrochen Then ExitLoop ;-> Bei Disconnect der App Schleife verlassen
		Sleep(10)
	WEnd
WEnd


;Funktionen
Func OnAutoItExit()
	TCPCloseSocket($ACCEPT)
	TCPShutdown()
EndFunc

Alles anzeigen

Wenn bei jedem Schleifendurchgang ein "TCPAccept($LISTEN)" ausgeführt wird, dann wird die Verbindung zur App kurz getrennt. Was für eine Möglichkeit besteht, die Verbindung zu prüfen ohne eine Unterbrechung zur App hervorzurufen?

Vielen Dank für eure Hilfe!

Gruß
Homer J. S.

**alpines**

Prüfe mal dein TCPSend ob dessen Return 0 ist, wenn das der Fall ist, lass dir @error ausgeben.
Die Fehlerliste findest du hier https://www.autoitscript.com/autoit3/docs/functions/TCPSend.htm / https://msdn.microsoft.com/en-us/library/ms740668.aspx
Sollte ein Unterschied bestehen zwischen Connection noch am Leben und Client hat die Connection abgebrochen, dann kannst du das verwenden.

////// Alternativ könntest du auch einen Heartbeat einbauen der jede Sekunde z.B. gesendet wird. Sollte der nicht ankommen -> Client gedroppt.

Homer J. S.

@alpines: Das war der Tip den ich gebraucht habe - Vielen Dank! Da hätte ich ja auch selber drauf kommen können ;). Zudem war die fiktive If-Abfrage an der falschen stelle.

Hier das geänderte Test Skript:

Spoiler anzeigen

Code

;Init
OnAutoItExitRegister("OnAutoItExit")
TCPStartup()


;Init Variablen
$IP='192.168.10.50'
$PORT=54321
$LISTEN=TCPListen($IP, $PORT)
$ACCEPT=0


;Mainloop
While 1
	While 1
		$ACCEPT=TCPAccept($LISTEN)
		If ($ACCEPT>0) Then ExitLoop
		Sleep(10)
	WEnd
	ConsoleWrite('Connect' & @CRLF)
	While 1
		$TIMEOUT=TimerInit()
		While 1
			$RECEIVE=TCPRecv($ACCEPT, 1024)
			If Not @error Then ExitLoop
			If (TimerDiff($TIMEOUT)>250) Then
				$TIMEOUT=TimerInit()
				If (TCPSend($ACCEPT , ' ')==0) Then ExitLoop 2
			EndIf
			Sleep(10)
		WEnd
		While 1
			$RECEIVE&=TCPRecv($ACCEPT, 1024)
			If (@error) Then ExitLoop
		WEnd
		TCPSend($ACCEPT ,@LF) ;Linefeed -> Acknowledged
		ConsoleWrite($RECEIVE & @CRLF)
	WEnd
	ConsoleWrite('Disconnect' & @CRLF)
WEnd


;Funktionen
Func OnAutoItExit()
	TCPCloseSocket($ACCEPT)
	TCPShutdown()
EndFunc

Alles anzeigen

Gruß
Homer J. S.