Datum / Ostersonntag.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Ja mir ist klar, es gibt diese Gauß Formel, leider komme ich mit so auf die schnelle nicht klar. Gibt es irgendetwas "fertiges" zur Berechnung des Osterfestes? Von Bugfix habe ich ein ziemlich langes (Gaus) Scribt zu dem Thema gefunden Ewiger Kalender - Feiertage. Da müßte ich aber den Gaus erst extrahieren, da ich das Gui nicht brauche. Führt der weg tatsächlich nur über Gaus, oder gibt es eine (fertige) Funktion für das Osterfest ?
Ich gebs zu - ich such ne faule Lösung - sorry !!! Ich arbeite bis heute immer mit Feiertagslisten für den Osterfeiertag, das ging bis heute schneller als das "ausrechnen einbauen" möchte aber weg davon.

Danke
Peter

PS: Ja schon klar faule Lösungen sind nicht gerne gesehen......

**BugFix**

Hier die Osterformel alleine:

AutoIt

;===============================================================================
; Description:     returns the date of easter in specified year between 1583 and 2999
; Parameter(s):    $year
; Return Value(s): On Success - easterdate (sunday)
;                  On Failure - -1
; Author(s):       BugFix (bugfix@autoit.de)
;===============================================================================
Func _Easter($year)
	;Determination Easter with formula by C. F. Gauss
	If $year > 1582 And $year < 3000 Then
		$a = Mod($year, 19)
		$b = Mod($year, 4)
		$c = Mod($year, 7)
		$H1 = Int($year / 100)
		$H2 = Int($year / 400)
		$N = 4 + $H1 - $H2
		$M = 15 + $H1 - $H2 - Floor(Int((8 * $H1 + 13) / 25))
		$d = Mod((19 * $a + $M), 30)
		$e = Mod((2 * $b + 4 * $c + 6 * $d + $N), 7)
		If $d + $e = 35 Then
			$Easter = 50
		Else
			If $d = 28 And $e = 6 And $a > 10 Then
				$Easter = 49
			Else
				$Easter = 22 + $d + $e
			EndIf
		EndIf
		If $Easter < 32 Then
			$EasterDay = $Easter
			$EasterMonth = "03"
		Else
			$EasterDay = $Easter - 31
			$EasterMonth = "04"
		EndIf
		If $EasterDay < 10 Then
			$EasterDay = "0" & $EasterDay
		EndIf
		; $EasterDate = $year & "/" & $EasterMonth & "/" & $EasterDay ; english notation
		$EasterDate = $EasterDay & "." & $EasterMonth & "." & $year ; german notation
	Else
		$EasterDate = -1; input year is out of range
	EndIf
	Return $EasterDate
EndFunc   ;==>_easter

Alles anzeigen

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

@ BugFix
Vielen Dank für die schnelle Reaktion. Du hast mir jede Menge Arbeit abgenommen. Schade, dass diese Funktion nicht in AutoIT enthallten ist. Es ist schließlich die Grundlage der beweglichen Feiertagsrechnung.

Nun kan ich endlich die ollen Listen entsorgen. Nochmals Danke

Gruß

Peter

**BugFix**

Die Funktion hatte ich 2007 geschrieben. Jetzt habe ich mal noch den Code etwas aufgeräumt und eine Syntaxanpassung an die aktuelle Version vorgenommen-

AutoIt

;===============================================================================
; Description:     returns the date of easter in specified year between 1583 and 2999
; Parameter(s):    $year
; Return Value(s): On Success - easterdate (sunday)
;                  On Failure - -1
; Author(s):       BugFix (bugfixautoit.de)
;===============================================================================
Func _Easter($year)
	;Determination Easter with formula by C. F. Gauss
	Local $a, $b, $c, $d, $e, $H1, $H2, $N, $M, $EasterDay, $EasterMonth
	If $year < 1583 Or $year > 2999 Then Return -1
	$a = Mod($year, 19)
	$b = Mod($year, 4)
	$c = Mod($year, 7)
	$H1 = Int($year/100)
	$H2 = Int($year/400)
	$N = 4 + $H1 - $H2
	$M = 15 + $H1 - $H2 - Floor(Int((8 * $H1 + 13)/25))
	$d = Mod((19 * $a + $M), 30)
	$e = Mod((2 * $b + 4 * $c + 6 * $d + $N), 7)
	$EasterDay = ($d + $e = 35) ? 50 : (($d = 28 And $e = 6 And $a > 10) ? 49 : (22 + $d + $e))
	$EasterMonth = '03'
	If $EasterDay > 31 Then
		$EasterDay -= 31
		$EasterMonth = '04'
	EndIf
	; $EasterDate = $year & "/" & $EasterMonth & "/" & $EasterDay ; english notation
	$EasterDate = StringRight('0' & $EasterDay, 2) & "." & $EasterMonth & "." & $year ; german notation
	Return $EasterDate
EndFunc   ;==>_Easter

Alles anzeigen

AutoMit

Was mache ich falsch?

Ich habe über Dein Script geschrieben:

#include <Date.au3> ; Datum und Zeit - brauche ich das?

$year = @YEAR
_Easter($year)
ConsoleWrite ($EasterDate)

Ergebnis:

ConsoleWrite ($EasterDate)
ConsoleWrite (^ ERROR

**BugFix**

Zitat von AutoMit

#include <Date.au3> ; Datum und Zeit - brauche ich das?

Schau in die UDF - ausschliesslich native Funktionen. Somit sind keinerlei Includes erforderlich.

Und du musst schon den Return der Funktion auffangen.

AutoIt

$EasterDate = _Easter(@YEAR)
ConsoleWrite($EasterDate & @CRLF)


; oder:
ConsoleWrite(_Easter(@YEAR) & @CRLF)

AutoMit

Vielen Dank - das funktioniert.

Laut gedacht:

Somit kann man scheinbar nicht den Rückgabewert einer Funktion direkt ausgeben, dachte nach folgender Zeile

Return $EasterDate

wäre das Ergebnis bereits in $EasterDate

Den Funktionsaufruf in der Form _Funktion(Wert) fand ich häufiger, scheinbar nicht überall so schreibbar:

_Easter(@YEAR)

Auf jeden Fall gehen obige Varianten - danke!

**Oscar**

Return $EasterDate
gibt den Wert von $EasterDate an das aufrufende Programm/Funktion zurück.
$EasterDate ist hierbei nur eine lokale Variable, wobei BugFix in seinem Script vergessen hat, diese als Lokal zu deklarieren.

BTW: Diese ganzen Fragen von Dir sind eigentlich Programmier-Grundlagen. Du solltest nicht versuchen zu laufen, wenn Du nichtmal stehen kannst. SCNR.