Problem mit _GUICtrlListView_SetItemSelected()

svart

Hallo,

ich habe folgendes Problem:

Ich möchte gerne eine ListView aktualisieren - das ausgewähle Item soll nach dem aktualisieren markiert bleiben.
- alle Werte in der ListView löschen und neu schreiben.

Wenn ich in der Funktion _GUICTRLListView_Setitemselected die Variable $selected eingebe funktioniert es nicht, wenn ich anstelle der Variable eine 1 eingebe funktioniert es.
Woran liegt das?

Hat jemand eine andere Lösung für mein Problem?

Vielen Dank für die Hilfe

Hier ein Beispiel:

C

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 376, 284, 192, 124)
$ListView1 = GUICtrlCreateListView("TEST - Name", 152, 50, 177, 217)
GUICtrlCreateListViewItem("Tester",$ListView1)
GUICtrlCreateListViewItem("Mustermann",$ListView1)
$Button1 = GUICtrlCreateButton("Button1", 24, 40, 113, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			$selected = _GUICtrlListView_GetSelectedIndices($ListView1)
			_GUICTRLListView_DeleteAllItems($ListView1)
			GUICtrlCreateListViewItem("Tester",$ListView1)
			GUICtrlCreateListViewItem("MusterFrau",$ListView1)
			_GUICTRLListView_Setitemselected($ListView1,$selected,True,True)


	EndSwitch
WEnd

Alles anzeigen

svart

Es funktioniert zwar mit _GUICtrlListView_ClickItem, doch dann wird die listview immer aktiviert...

**autoBert**

Das liegt daran das _GUICtrlListView_GetSelectedIndices einen String zurück gibt. Du musst also mit Int zu einem Integer wandeln.

Code

$selected = int(_GUICtrlListView_GetSelectedIndices($ListView1))

Dies funktioniert solange in der LV nur 1 Item selektiert werden kann.

**Oscar**

Ein Beispiel dafür, dass die ListView-UDF noch Probleme mit der Control-ID hat.
_GUICtrlListView_SetItemSelected funktioniert nur mit dem Handle des ListViews:

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 376, 284, 192, 124)
$ListView1 = GUICtrlCreateListView("TEST - Name", 152, 50, 177, 217)
GUICtrlCreateListViewItem("Tester", $ListView1)
GUICtrlCreateListViewItem("Mustermann", $ListView1)
$Button1 = GUICtrlCreateButton("Button1", 24, 40, 113, 33)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			$selected = _GUICtrlListView_GetSelectedIndices($ListView1)
			ConsoleWrite('$selected: ' & $selected & @CR)
			_GUICtrlListView_DeleteAllItems($ListView1)
			GUICtrlCreateListViewItem("Tester", $ListView1)
			GUICtrlCreateListViewItem("MusterFrau", $ListView1)
			$iRet = _GUICtrlListView_SetItemSelected(GUICtrlGetHandle($ListView1), $selected, True, True)
			ConsoleWrite($iRet & @CR)
	EndSwitch
WEnd

Alles anzeigen

Edit: Nanu!? AutoBert hat auch recht. Wenn man explizit in Int wandelt, funktioniert auch die Ctlr-ID. Was ist denn mit der automatischen Typwandlung von AutoIt los?

**autoBert**

Zitat von Oscar

Edit: Nanu!? AutoBert hat auch recht. Wenn man explizit in Int wandelt, funktioniert auch die Ctlr-ID. Was ist denn mit der automatischen Typwandlung von AutoIt los?

Typumwandlung funktioniert meines Wissens nur bei Berechnungen, so dass auch dies:

Code

$selected = _GUICtrlListView_GetSelectedIndices($ListView1)*1

funktioniert.

mfg autoBert

**Oscar**

Das hatte auch mal ohne Berechnung funktioniert. In irgendeiner AutoIt-Version muss das geändert worden sein.

**BugFix**

Ja, da fällt einem der "gut gemeinte" Datentyp Variant vor die Füße. Als ich mit AutoIt anfing, fand ich den Datentyp ganz praktisch. Aber je länger ich damit arbeite, desto weniger gefällt mir das. Z.B. wegen solcher Erlebnisse, die man dann durch mühseliges Error-Handling ausfindig macht.
Andere Skriptsprachen verwenden zwar auch Variant-Typen, aber da meckert der Interpreter wenigstens sofort, wenn trotzdem eine Umwandlung erforderlich ist.

**Oscar**

Das ist das Problem! Wenn ein Variant-Datentyp benutzt wird, dann müssen auch die Funktionen damit arbeiten können.
Wenn ich jetzt bei jeder Funktion erst checken muss, ob der Datentyp passt, dann ist es einfacher gleich die Variablen entsprechend zu deklarieren.
Für mich handelt es sich dabei um einen Bug.

svart

Vielen Dank,

es funktioniert nun.