copy & paste und Aufruf eines VB-Scriptes mit AutoIT möglich?

imebro

Hallo und guten Morgen,

ich bin seit heute neu hier und möchte zunächst mal Alle hier begrüßen

Auf Empfehlung habe ich mir AutoIT heruntergeladen und auch schon ein bisschen damit herum probiert.
Nun habe ich aber eine konkrete Frage zu einem Problem, welches ich so nicht lösen konnte.

Ich habe ein VBScript (Word 2000) geschrieben, welches einen in ein Dokument einkopierten Text auf Knopfdruck in ein bestimmtes Verzeichnis speichert und dabei auch nach einer Eingabe für einen Dateinamen fragt.
Diesen einkopierten Text muss man per markieren, copy & paste aus einem Programmfenster (Textfenster) heraus kopieren. Es handelt sich dabei um ein für uns speziell geschriebenes individuelles Programm.

Folgende Schritte möchte ich umsetzen:

- Text aus dem Textfenster des Programms komplett markieren und kopieren (Strg A, Strg C)
- dann Word (Word 2000) öffnen
- anschließend dann automatischer Start des weiter oben beschriebenen Word-VBScriptes

Wie kann ich das mit AutoIT umsetzen?

Danke und schöne Grüße,
imebro

**water**

Ich würde nicht die GUI Deines Programmes automatisieren (d.h. copy&paste etc verwenden), sondern die Funktionen von AutoIt einsetzen um das Control in eine Variable auszulesen.
Dann wäre noch zu prüfen, ob es nicht sinnvoller wäre, statt des VBScripts die Word UDF einzusetzen.

imebro

Hallo und danke für die schnelle Antwort.

Ich muss zugeben, dass ich Deine Antwort nicht so recht verstanden habe... bin kein Programmierer

Mit dem Word-VBScript funktioniert das alles recht gut.
Ich suche jetzt einfach nur eine Möglichkeit, den zu kopierenden Text zu markieren, zu kopieren, dann Word zu starten und dann das VB-Script von Word auszuführen.

Wie würde ich das mit AutoIT umsetzen können?
Kannst Du mir dabei helfen?

Danke und Gruss,
imebro

gmmg

Hallo imebro

wie water schon geschrieben hat am besten die Word Funktion dazu benutzen. Am besten mal in die Hilfe schauen.

Poste doch mal das VB Schript, da kann man dir sicher schenller helfen

Gruß gmmg

**water**

Schau Dir mal das AutoIt Window Info Tool an. Damit kannst Du die Control-ID eruieren und dann mit ControlGetText den Inhalt auslesen und einer Variablen zuweisen.
Das wäre mal Schritt 1.
Danach sehen wir weiter.

imebro

Hallo und danke "gmmg"...

naja, das Word starten und dann das Word-VB-Script ausführen, kann ich ja nicht mit einem Word-VB-Script machen... denke ich jedenfalls

Aber hier mal mein VB-Script:

Code

Sub memo()
'
' memo Makro
' Makro aufgezeichnet am 04.09.2015 von imebro
'
    Selection.Paste
    nummer = InputBox("Bitte Nummer eingeben:")
    fname = "S:\ARCHIV\Mittelvergabe\Memos\" & nummer & ".doc"
    ActiveDocument.SaveAs FileName:=fname, FileFormat:=wdFormatDocument, _
    LockComments:=False, Password:="", AddToRecentFiles:=True, WritePassword _
    :="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts:=False, _
    SaveNativePictureFormat:=False, SaveFormsData:=False, SaveAsAOCELetter:= _
    False
    Application.Quit
End Sub

Alles anzeigen

Dieses Script sollte ausgeführt werden, nachdem man den Text aus dem Textfeld des anderen Programms markiert und kopiert und dann Word gestartet hat.
Die 4 Schritte (markieren, kopieren, Word starten, VBScript starten) müßten dann über AutoIT ausgeführt werden.

LG
imebro

imebro

Hallo,

habe gerade das "AutoInfo" gefunden und gestartet und dann das Icon in das Textfenster des Programms gezogen.
Dadurch wurde das "AutoInfo" mit Daten gefüllt... allerdings in mehreren Reitern (Window, Controll.... etc.).
Welchen Inhalt muss ich denn jetzt hier posten... und wie mache ich das?

Hier mal die Hauptinhalte aus dem "AutoInfo"-Fenster:

Basic Window Info:
Title: Stiftungsanträge / Einzelfallhilfen (Vers.6.7) - [Anträge]
Class: TMainForm

Basic Control Info:
Class: TwwDBRichEdit
Instance: 1

Control-ID: 394352

LG
imebro

gmmg

Ich würde das in etwas so machen ...

In Autoit eine GUI Basteln, mit einem Editfeld (für den Text), einem Textfeld (für die Nummer des DOC) und einem Save Button.

Beispiel ...

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>


$AutoIT = GUICreate("", 500, 500)
$Edit = GUICtrlCreateEdit("First line" & @CRLF, 10, 10, 300, 300, 0x0080 + 0x0040)
;$Filename = GUICtrlCreateInput("", 40, 350, 180, 25)
$Save = GUICtrlCreateButton("Save", 40, 380, 100, 25)


GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Save
            $txt = GUICtrlRead($Edit)
            _Save_to_Word()
    EndSwitch
WEnd


Func _Save_to_Word()


    Local $oWord = _Word_Create()


    If @error <> 0 Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_Create Example", _
            "Error creating a new Word application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    If @extended = 1 Then
        ;MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_Create Example", "MS Word was not running when _Word_Create was called.")
    Else
        ;MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_Create Example", "MS Word was already running when _Word_Create was called.")
    EndIf


    _Word_DocAdd($oWord)
    $oWord.Selection.TypeText ($txt)
    ;speicher word dokument
    ;beende Word


EndFunc

Alles anzeigen

Gruß gmmg

imebro

Vielen Dank "gmmg" für Deine Mühe.

Muss ich diesen Code jetzt einfach in den Script-Editor kopieren und das dann speichern (ggf. als EXE-Datei)?
Und... was meinst Du mit "Editfeld für den Text"?

Wenn ich nun zunächst den Text aus dem Textfeld des Programms selbst markieren und kopieren... und diesen dann in das Editfeld einfügen muss, dann habe ich natürlich nichts gewonnen, denn das mache ich jetzt ja auch so, wo ich NUR das Word-Script nutze. Ich markiere und kopiere (Strg. A + Strg. C) den Text aus dem Textfeld und dann starte ich das Makro in Word über einen entsprechenden Button. Dieser fügt den Text aus der Zwischenablage ein, fragt nach eingabe der Nummer und speichert dann im gewünschten Verzeichnis ab.

Sehe ich das richtig, dass bei dieser Lösung das VB-Script von Word gar nicht benötigt wird?

Danke und Gruss,
imebro

gmmg

Der Code ist ja nur ein Grundgerüst als Beispiel, den musst du natürlich noch anpassen

Ja, kannst du einfach in den Script Editor kopieren und über F5 starten, ohne da jedesmal eine Exe zu erstellen.
Richtig, damit brauchst du kein vbs makro in Word.

Dein GUI (Class: TwwDBRichEdit) auszulesen und einzubauen sollte nicht so schwer sein ...

Du öffnest diese, aktivierst das entsprechende Fenster, markierst deinen Text und sendest ihn an Word .. dazu brauchst du den Zwischenschritt mit dem $Edit in meinem Beispiel natürlich nicht.

Schau dir dazu auch "WinExists", "WinActivate", "ClipPut - Zwischenablage", "Send Key List" bzw. "Send", eventuell noch Mousclick in der Hilfe an...

Gruß gmmg

imebro

Danke Dir nochmals "gmmg".

Glaube das ist doch ein bisschen zu hoch für mich als Jemand ohne Programmierkenntnisse.
Bekomme das so nicht hin.

Aber mein Word-VB-Script macht ja schon so einiges.
Da muss ich ja nur das Script über einen Button in der Symbolleiste starten und dann wird der Text aus der Zwischenablage eingefügt, nach Eingabe der Nummer gefragt und das Dokument im vorbelegten Verzeichnis gespeichert.
Ist ja schon eine Erleichterung für die Kolleg-/innen
Dann müssen sie eben lediglich mit Strg A + Strg C den Text aus dem Textfeld kopieren, Word starten und dann den Button dort anklicken...

Danke und Gruss,
imebro

gmmg

Ach Quatsch, das ist ganz easy

Hast du mein Beispiel mal getestet?
Einfach mal im Scripteditor mit F5 starten, einen Text reinkopieren und speichern drücken ...

Das Word wird automatisch geöffnet, ein leeres Dokument erzeugt und der Text eingefügt.

Hier nochmal mein beispiel mit Speichern unf schließen ...

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>


$AutoIT = GUICreate("", 500, 500)
$Edit = GUICtrlCreateEdit("First line" & @CRLF, 10, 10, 480, 300, 0x0080 + 0x0040)
$Filename = GUICtrlCreateInput("filename ohne endung", 40, 350, 150, 25)
$Save = GUICtrlCreateButton("Save", 40, 380, 100, 25)


GUISetState(@SW_SHOW)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Save
			$txt_Edit = GUICtrlRead($Edit)
			$txt_Filename = GUICtrlRead($Filename)
			_Save_to_Word()
	EndSwitch
WEnd


Func _Save_to_Word()


	$oWord = _Word_Create(1)
	$oDoc = _Word_DocAdd($oWord)
	$oWord.Selection.TypeText ($txt_Edit)
	;_Word_DocSaveAs($oDoc, "d:\"& $txt_Filename,12) ; save as docx")
	_Word_DocSaveAs($oDoc, "d:\"& $txt_Filename) ; save as doc")
	_Word_Quit($oWord)


EndFunc

Alles anzeigen

dir wird hier sicher auch noch geholfen
kannst du mal von deinem Fenster, wo du die Daten raus kopierst, einen Screenshot anhängen? die Daten darin, kannst du ja unkenntlich machen.

mit dem Befehl Send() kannst du das Markieren, Kopieren, Einfügen automatisieren.

Send("^a"); alles markieren
Send("^c"); kopieren
Send("^v"); einfügen

Gruß gmmg

imebro

Danke Dir...

wie kann ich denn über AutoIT ein VBS-Script, welches ich als "memo.vbs" auf dem Desktop abgespeichert habe, starten?

Der Rest funktioniert per AutoIT... also Text markieren, kopieren, Word starten mit einem neuen Dokument.
Wenn ich jetzt über AutoIT dieses VBS-Script starten könnte (memo.vbs), dann würde das den Rest ausführen.

LG
imebro

gmmg

so startet es bei mir.

Beispiel
ShellExecute("C:\VBS_Scripte\DateToInteger8.vbs")

gruß gmmg

imebro

Wenn ich das so im AutoIT Code ergänze, erscheint bei mir eine Fehlermeldung:

---------------------------
Windows Script Host
---------------------------
Skript: C:\Users\imebro\Desktop\memo.vbs
Zeile: 13
Zeichen: 36
Fehler: Anweisung erwartet
Code: 800A0400
Quelle: Kompilierungsfehler in Microsoft VBScript

LG
imebro

gmmg

startet denn dein Script über Start-> ausführen bzw. in der cmd?

das scheint mir kein fehler vom autoit zu sein.
stell uns doch mal den quelltext vom vbs zur verfügung.

kannst ja auch nochmal folgendes probieren

#include <Process.au3>
_RunDos("C:\VBS_Scripte\test_.vbs")

obwohl ich denke, das Autoit das VBS Script startet

gruß gmmg

imebro

...habe eben mal getestet.
Wenn ich das "memo.vbs" manuell (per Doppelklick) vom Desktop aus starte, erscheint auch diese Fehlermeldung

Hier mal der Code:

Code

Attribute VB_Name = "memo"


Sub memo()
Attribute memo.VB_Description = "Makro aufgezeichnet am 04.09.2015 von imebro"
Attribute memo.VB_ProcData.VB_Invoke_Func = "Normal.NewMacros.memo2"
'
' memo Makro
' Makro aufgezeichnet am 04.09.2015 von imebro
'
    nummer = InputBox("Bitte Nummer + Name eingeben:")
    fname = "S:\ARCHIV\Mittelvergabe\Memos\" & nummer & ".doc"
    ActiveDocument.SaveAs FileName:=fname, FileFormat:=wdFormatDocument, _
    LockComments:=False, Password:="", AddToRecentFiles:=True, WritePassword _
    :="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts:=False, _
    SaveNativePictureFormat:=False, SaveFormsData:=False, SaveAsAOCELetter:= _
    False
    Application.Quit
End Sub

Alles anzeigen

LG
imebro

Micha_he

Meiner Meinung nach, mach doch Dein VBS-Script nichts anderes wie:
- Fragen nach Nummer
- Dokument mit Pfad+Name+Nummer+Ext speichern.

Das kannst Du doch in gmmg's Script (Zeile 30/31) noch einbauen und dann das VBS ganz weglassen. Z.B. so:

AutoIt

$txt_Filename = "S:\ARCHIV\Mittelvergabe\Memos\" & InputBox("Eingabe","Nummer vergeben:") & ".doc"
_Word_DocSaveAs($oDoc, $txt_Filename) ; save as doc")

(Code ungetestet...)

Das GUI-Element '$Filename' wären dann natürlich nicht mehr notwendig, wenn Du den Filenamen fest vergibts und nur um die Nummer erweiterst.

gmmg

hier nochmal mit Inputbox und Fehlerabfragen ...

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <Word.au3>


$AutoIT = GUICreate("", 500, 500)
$Edit = GUICtrlCreateEdit("First line" & @CRLF, 10, 10, 480, 300, 0x0080 + 0x0040)
;$Filename = GUICtrlCreateInput("filename ohne endung", 40, 350, 150, 25)
$Save = GUICtrlCreateButton("Save", 40, 380, 100, 25)


GUISetState(@SW_SHOW)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Save
			$txt_Edit = GUICtrlRead($Edit)
			;$txt_Filename = GUICtrlRead($Filename)
			$nummer = ""


			While 1
				$nummer = InputBox("Info","Bitte Nummer + Name eingeben:", "")
				If @error = 1 Then
					MsgBox(0,"Achtung","speichern abgebrochen")
					ExitLoop
				Else
					If  $nummer <> "" Then
						_Save_to_Word()
						ExitLoop
					Else
						MsgBox(0,"Achtung","darf nicht leer sein")
					EndIf
				EndIf
			WEnd
	EndSwitch
WEnd


Func _Save_to_Word()

	$oWord = _Word_Create(1)
	$oDoc = _Word_DocAdd($oWord)
	$oWord.Selection.TypeText ($txt_Edit)
	;_Word_DocSaveAs($oDoc, "d:\"& $txt_Filename,12) ; save as docx")
	_Word_DocSaveAs($oDoc, "S:\ARCHIV\Mittelvergabe\Memos\" & $nummer) ; save as doc
	_Word_Quit($oWord)

EndFunc

Alles anzeigen

gruß gmmg

imebro

Vielen Dank nochmal...

Problematisch ist, dass ich in diese Fensterbox ja den kopierten Text zunächst eingeben muss.
Genau diesen Schritt wollte ich ja einsparen

Hier ein AutoIT-Script, welches funktioniert bis zu dem Punkt, wo die Nummer eingegeben werden muss:

Code

#NoTrayIcon
; activate part match mode of title
AutoItSetOption("WinTitleMatchMode",2)
; Titel of Window
$wintitle = "Stiftungsanträge / Einzelfallhilfen"
; activate window
WinActivate($wintitle)
; wait max 10 seconds for window to become active
if WinWaitActive($wintitle,"",5) = 0 then
	msgbox(16,"Timeout","Konnte Fenster nicht finden!")
	exit 1
EndIf
; retrieve text of control
$text = ControlGetText($wintitle,"","[CLASS:TwwDBRichEdit; INSTANCE:1]")


; Word starten
$objWord = ObjCreate("Word.Application")
; leeres Dokument hinzufügen
$doc = $objWord.Documents.Add()
; make word visible
$objWord.Visible = true
; insert text into document
$doc.Content.Text = $text

Alles anzeigen

Somit habe ich ein offenes neues Word-Dokument, in dem der aus dem Programm schon automatisch kopierte Text eingefügt ist.
Jetzt brauche ich nur noch diese Input-Box, womit die Nummer abgefragt wird und dann das speichern ins Verzeichnis "S:\ARCHIV\Mittelvergabe\Memos" als ".doc"

Wäre toll, wenn das noch klappt

LG
imebro