In einem Text nach FQDN Server Namen suchen

Donsen64

Hallo,
ich habe mal wieder ein Problem, dass ich in einem Text nach etwas suchen möchte. Es geht um Fully Qualified Domain Name (FQDN).
Ich habe zum Beispiel den folgenden Text:

Code

$sText = "server.domaene.com ist mein Server die URL ist aber http://server5.domaene.de/de-de/ es kann aber auch der Server server2.temp.Domaene3.FR sein"

Im Text sind einige Server Namen versteckt die ich herausfiltern möchte. Ich weiß, dass es mit StringRegExp möglich ist. Nur leider bin ich zu blöd das entsprechende Pattern dazu zu erstellen.

Als Ergebnis würde ich gern die folgende Liste von Server Namen haben wollen:
server.domaene.com
server5.domaene.de
server2.temp.Domaene3.FR

Würde mich freuen wenn mir jemand bei dem Pattern helfen könnte.

Gruß Ingo

**Andy**

Zitat von Donsen64

Nur leider bin ich zu blöd das entsprechende Pattern dazu zu erstellen.

Über deine Blödheit erlaube ich mir kein Urteil, über deine Faulheit schon!

Ist das so schwer? <-klick mich, ich bin ein Link

Donsen64

Hallo Andy,
ich hatte schon im Internet gesucht und etwas zusammen gebaut. Aber leider hatte ich in meiner Funktion die Return Zeile vergessen. Daher habe ich immer eine 0 zurück bekommen, was mich zum verzweifeln gebracht hat. Aber manchmal helfen auch 1 Stunde Pause um ein Problem zu lösen.

Für alle die auch FQDN Namen in einem Text suchen wollen/müssen hier die fertige Funktion.

Gruß Ingo

AutoIt

#include <Array.au3>


Local $sText
Local $aFQDNs


$sText = "server.domaene.com ist mein Server die URL ist aber http://server5.domaene.de/de-de/ es kann aber auch der Server server2.temp.Domaene3.FR sein"


$aFQDNs = _StringSearchFQDN($sText)


If IsArray($aFQDNs) = 1 Then
   _ArrayDisplay($aFQDNs)
Else
   MsgBox(1, "Error", "Nichts gefunden")
EndIf


Func _StringSearchFQDN($sText)
	Local $aResult[1]
	Local $aTEMP
	Local $aTEMP2
	Local $sPattern = "(?x)\b((?=[a-zA-Z0-9-]{1,63}\.)(xn--)?[a-zA-Z0-9]+(-[a-zA-Z0-9]+)*\.)+[a-zA-Z]{2,63}\b "


	;im Text nach FQDNs suchen
	$aTEMP = StringRegExp($sText, $sPattern, 4) 


	;Ergebnis verarbeiten
	If IsArray($aTEMP) = 1 Then
	   $aResult[0] = 0
		For $i=0 To UBound($aTEMP)-1
		    $aTEMP2 = $aTEMP[$i]
			_ArrayAdd($aResult, $aTEMP2[0])
			$aResult[0] = $aResult[0]+1
		Next
		Return($aResult)
	Else
		Return 0 ;Nix gefunden
	EndIf
EndFunc

Alles anzeigen

Donsen64

Hallo,
leider funktioniert es noch nicht richtig. Denn wenn ich den Folgenden Text an die Funktion übergebe:

Code

$sText = "server.domaene.com ist mein Server die URL ist aber http://server5.domaene.de/de-de/ es kann aber auch der Server server2.temp.Domaene3.FR sein der Text ist aus test.txt kopiert"

Erkennt er auch test.txt als Server. Ein echter FQDN Server Name muss aber mindestens zwei Punkte enthalten.

Wie kann ich das noch mit einbauen?

Gruß Ingo

n00b-it

Du könntest deine Funktion so umbauen:

AutoIt

Func _StringSearchFQDN($sText)
	Local $aResult[1]
	Local $aTEMP
	Local $aTEMP2
	Local $aTEMP3
	Local $sPattern = "(?x)\b((?=[a-zA-Z0-9-]{1,63}\.)(xn--)?[a-zA-Z0-9]+(-[a-zA-Z0-9]+)*\.)+[a-zA-Z]{2,63}\b "


	;im Text nach FQDNs suchen
	$aTEMP = StringRegExp($sText, $sPattern, 4)


	;Ergebnis verarbeiten
	If IsArray($aTEMP) = 1 Then
	   $aResult[0] = 0
	   For $i=0 To UBound($aTEMP)-1
		    $aTEMP2 = $aTEMP[$i]
			$var = StringSplit($aTEMP2[0], ".")
			If $var[0] >= "3" Then _ArrayAdd($aResult, $aTEMP2[0])
			$aResult[0] = $aResult[0]+1
		Next
		Return($aResult)
	Else
		Return 0 ;Nix gefunden
	EndIf
EndFunc

Alles anzeigen

Das geht bestimmt auch noch eleganter, aber ich habe keine Ahnung wie

Donsen64

Hallo,
ist vielleicht nicht schön aber eine Lösung. Vielen Dank dafür. Ich habe das mal eingebaut und noch zusätzlich die Suche auf die klassischen Top Domänen (.com, .de, .fr ...) eingegrenzt. Die neuen langen Namen (.berlin ...) sind für nicht nicht so relevant.

Gruß Ingo

AutoIt

#include <Array.au3>


Local $sText
Local $aFQDNs


$sText = "server.domaene.com ist mein Server die URL ist aber http://server5.domaene.de/de-de/ es kann aber auch der Server server2.temp.Domaene3.FR sein der Text ist aus test.txt kopiert. Erweiterter Test server2.temp.Domaene3.Morgen ist Freitag."


$aFQDNs = _StringSearchFQDN($sText)


If IsArray($aFQDNs) = 1 Then
   _ArrayDisplay($aFQDNs)
Else
   MsgBox(1, "Error", "Nichts gefunden")
EndIf


Func _StringSearchFQDN($sText)
	Local $aResult[1]
	Local $aTEMP
	Local $aTEMP2
	Local $sPattern = "(?x)\b((?=[a-zA-Z0-9-]{1,63}\.)(xn--)?[a-zA-Z0-9]+(-[a-zA-Z0-9]+)*\.)+[a-zA-Z]{2,3}\b "


	;im Text nach FQDNs suchen
	$aTEMP = StringRegExp($sText, $sPattern, 4)


	;Ergebnis verarbeiten
	If IsArray($aTEMP) = 1 Then
	   $aResult[0] = 0
		For $i=0 To UBound($aTEMP)-1
		    $aTEMP2 = $aTEMP[$i]
			;nur um in @extended die Anzahl der Punkte zu bekommen erfolgt der Aufruf von StringReplace
			StringReplace($aTEMP2[0], ".", "-")
			If @extended >= 2 Then
			   _ArrayAdd($aResult, $aTEMP2[0])
			   $aResult[0] = $aResult[0]+1
			EndIf
		Next
		Return($aResult)
	Else
		Return 0 ;Nix gefunden
	EndIf
 EndFunc

Alles anzeigen