2D Arrays vergleichen und nur Übereinstimmung in neuem Array auflisten...

horphi

Hallo,

ich bekomme es leider nicht hin.
Ich versuche 2 Arrays zu vergleichen und bei Übereinstimmung die Werte beider Arrays in einem neuen Array zusammenzufügen.

Hier ist mein Ansatz:

Spoiler anzeigen

AutoIt

#include <Array.au3>
#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>




Global $aarray1 = [["Banane", "16,95"], ["Apfel", "20,5"], ["Birne", "20,5"]]
Global $aarray2 = [["Banane", "16.11", '2 / 3'], ["Apfel", "20.11", '2 / 5'], ['Kirsche', '23.11', '4 / 9']]




$aresultcomp = _ArrayCompare($aarray1, $aarray2)
_ArrayDisplay($aresultcomp)


Func _ArrayCompare($aarray1, $aarray2)


	Local $aArray3[][] = [[0, 0]], $iNeu, $i


	For $i = 0 To UBound($aarray1) - 1
		If _callcomparison($aarray2, $aarray1[$i][0]) Then
			MsgBox(0, '', $aarray1[$i][0])
			$iNeu = UBound($aArray3) + $i
			ReDim $aarray1[$iNeu][0]
			$avArray3 = $aarray1
		EndIf


	Next
	_ArrayDisplay($avArray3)


EndFunc   ;==>_ArrayCompare


Func _callcomparison($aAr1, $aAr2)
	Local $i
	For $i = 0 To UBound($aAr1) - 1
		If $aAr1[$i][0] = $aAr2 Then Return True
;~ 		MsgBox(0, '', 'RICHTIG ' & $aAr1[$i][0] & " test " & $aAr2)
;~ 	Else
;~ 		If $aAr1[$i][0] <> $aAr2 Then MsgBox(0, '', 'Falsch ' & $aAr1[$i][0] & " test " & $aAr2)
;~ 	EndIf
	Next
;~ 	Return True


EndFunc   ;==>_callcomparison

Alles anzeigen

Könnt Ihr mir helfen?

VG

horphi

**water**

Wie sollte das Ergebnis aufbauend auf Deinem obigen Beispiel aussehen?

**water**

Beispiel - ich gehe davon aus, dass jede Frucht in Tabelle 2 nur 1x vorkommt.

Code

#include <Array.au3>
Global $aArrayIn1 = [["Banane", "16,95"], ["Apfel", "20,5"], ["Birne", "20,5"]]
Global $iRecords = UBound($aArrayIn1, 1)
Global $aArrayIn2 = [["Banane", "16.11", '2 / 3'], ["Apfel", "20.11", '2 / 5'], ['Kirsche', '23.11', '4 / 9']]
ReDim $aArrayIn1[UBound($aArrayIn1, 1) + UBound($aArrayIn1, 1)][UBound($aArrayIn1, 2) + UBound($aArrayIn2, 2) - 1] ; Zielarray auf maximale Größe setzen
For $iIndex2 = 0 To UBound($aArrayIn2, 1) - 1 ; Jede Zeile des zweiten Index verarbeiten
	For $iIndex1 = 0 To UBound($aArrayIn1, 1) - 1 ; Mit jeder Zeile des ersten Index vergleichen
		If $aArrayIn1[$iIndex1][0] = $aArrayIn2[$iIndex2][0] Then ; Bestehenden Eintrag gefunden. Werte dazuhängen
			For $i = 1 To UBound($aArrayIn2, 1) - 1
				$aArrayIn1[$iIndex1][$i + 1] = $aArrayIn2[$iIndex2][$i]
			Next
			ExitLoop
		ElseIf $aArrayIn1[$iIndex1][0] = "" Then ; Kein Eintrag gefunden. Am Ende der Tabelle anhängen
			For $i = 0 To UBound($aArrayIn2, 1) - 1
				$aArrayIn1[$iIndex1][$i] = $aArrayIn2[$iIndex2][$i]
			Next
			$iRecords = $iRecords + 1
			ExitLoop
		EndIf
	Next
Next
ReDim $aArrayIn1[$iRecords][UBound($aArrayIn1, 2)] ; Zielarray nicht verwendete zeilen entfernen
_ArrayDisplay($aArrayIn1)

Alles anzeigen

**Oscar**

Hmm...vielleicht so:

AutoIt

#include <Array.au3>


Global $aarray1 = [["Banane", "16,95"], ["Apfel", "20,5"], ["Birne", "20,5"]]
Global $aarray2 = [["Banane", "16.11", '2 / 3'], ["Apfel", "20.11", '2 / 5'], ['Kirsche', '23.11', '4 / 9']]
Global $oDictionary = ObjCreate('Scripting.Dictionary')
For $i = 0 To UBound($aarray1) - 1
	If Not $oDictionary.Exists($aarray1[$i][0]) Then $oDictionary.Add($aarray1[$i][0], $aarray1[$i][1])
Next
Global $iNewCol = UBound($aarray2, 2) + 1, $iNewRow = 1
Global $aNew[$iNewRow][$iNewCol]
_ArrayDisplay($aarray2)
For $i = 0 To UBound($aarray2) - 1
	If $oDictionary.Exists($aarray2[$i][0]) Then
		For $j = 0 To $iNewCol - 2
			$aNew[$iNewRow - 1][$j] = $aarray2[$i][$j]
		Next
		$aNew[$iNewRow - 1][$iNewCol - 1] = $oDictionary.Item($aarray2[$i][0])
		$iNewRow += 1
		ReDim $aNew[$iNewRow][$iNewCol]
	EndIf
Next
ReDim $aNew[$iNewRow - 1][$iNewCol]


_ArrayDisplay($aNew)

Alles anzeigen

horphi

...wie macht ihr das....ich sitze seit 2 Tagen davor und kriege es nicht hin.

Dann poste ich hier einmal meinen Ansatz und ihr haut 10 min später die Lösung raus...
Oscars Lösung ist PERFEKT!

@ Water: auf dein Frage zurückzukommen, ja es gibt die Früchte mehrmals in der 2. Tabelle...Ich habe 2x Äpfel mit unterschiedlichen Halbarkeitsdaten...

AutoIt

Global $aarray1 = [["Banane", "16,95"], ["Apfel", "20,5"], ["Birne", "20,5"]]
Global $aarray2 = [["Banane", "16.11", '2 / 3'], ["Apfel", "20.11", '2 / 5'], ["Apfel", "19.11", '2 / 6'],['Kirsche', '23.11', '4 / 9']]

VIELEN DANK!!!!!

**water**

Da Oscars Lösung auch diesen Spezialfall abdeckt, müsste man meine Lösung noch etwas nacharbeiten.
Aber Dictionary sieht auch irgendwie eleganter aus

**Oscar**

Zitat von horphi

wie macht ihr das....ich sitze seit 2 Tagen davor und kriege es nicht hin.

Das sind im Prinzip auch Programmier-Grundlagen, die man mit der Zeit lernt.
Solche Vergleiche benötigt man öfter mal und wenn man ein Array mit mehreren Werten (2. Array) vergleichen will, dann ist das Dictionary.Object sehr schnell (im Vergleich zu zwei verschachtelten Schleifen).

horphi

Hallo Oscar,

die Funktionsweise des Dictionary.Object muss ich erst mal verstehen.

Bin ja absoluter Anfänger....

https://msdn.microsoft.com/en-us/library/…4(v=vs.84).aspx

VG
horphi

horphi

Ich verstehe aus dem Dictionary.Object.Add --> das ich nur ein Item hinzufügen kann richtig?

RICHTIG object.Add (key, item)

FALSCH object.Add (key, item1,Item2)

VG

**Oscar**

Genau! Es gibt dabei immer nur einen KEY und nur ein ITEM.
Brauchst Du mehrere Werte musst Du "tricksen" (mit einem Trennzeichen als String zusammenfügen).
Das bietet sich aber nur für das Item an. Den Key braucht man ja für den Vergleich.

**AspirinJunkie**

Man kann als Value auch ein Array übergeben.

**Oscar**

Oh, stimmt! Das funktioniert ja wirklich!
Danke, für den Hinweis! Wieder was gelernt.

Dann braucht man gar nicht mit dem String und Trennzeichen zu "tricksen".

horphi

Danke für die Hinweise.

Hab es jetzt mit einer Array Schleife gelöst.

Ich wiederhole die Übergabe und verändere die zuzufügende Reihe.

VG
horphi

horphi

Hallo Oscar,

könnte man deine Funktion nicht in die Standard-Bibliothek der Arrays mitaufnehmen?

Ich finde die genial.

VG
horphi

**Kanashius**

Naja, es wird zumindest in den UDFs recht viel aufgenommen, aber es kann nicht alles in die Standartbibliothek aufgenommen werden. Gerade so etwas, das ja doch nicht soo oft gebraucht wird. Genau dafür gibt es ja UDFs. Damit man sich Funktionen je nach gebrauch zusammensuchen kann. Ansonsten wird es irgendwann viel zu unübersichtlich

**autoBert**

Diese kleine Optimierung von @Oscar's Skript:

AutoIt

#include <Array.au3>


Global $aarray1 = [["Banane", "16,95"], ["Apfel", "20,5"], ["Birne", "20,5"]]
Global $aarray2 = [["Banane", "16.11", '2 / 3'], ["Apfel", "20.11", '2 / 5'], ['Kirsche', '23.11', '4 / 9']]
Global $oDictionary = ObjCreate('Scripting.Dictionary')
For $i = 0 To UBound($aarray1) - 1
	If Not $oDictionary.Exists($aarray1[$i][0]) Then $oDictionary.Add($aarray1[$i][0], $aarray1[$i][1])
Next
Global $iNewCol = UBound($aarray2, $UBOUND_COLUMNS ) + 1, $iNewRow = 1, $iRows=UBound($aarray2)+1
Global $aNew[$iRows][$iNewCol]
_ArrayDisplay($aarray2,'Array 2')
For $i = 0 To UBound($aarray2) - 1
	If $oDictionary.Exists($aarray2[$i][0]) Then
		For $j = 0 To $iNewCol - 2
			$aNew[$iNewRow - 1][$j] = $aarray2[$i][$j]
		Next
		$aNew[$iNewRow - 1][$iNewCol - 1] = $oDictionary.Item($aarray2[$i][0])
		$iNewRow += 1
	EndIf
Next
ReDim $aNew[$iNewRow - 1][$iNewCol]


_ArrayDisplay($aNew,'Array New')

Alles anzeigen

sollte zumindest bei großem 2. Array einige Zeit sparen da nur noch 1 ReDim ausgeführt werden muss.