Transparente InputBox?

elektronenpeter

Hallo,

ist es irgendwie möglich, den Hintergrund einer InputBox transparent zu setzen?
Ich versuche eine komplett transparente GUI zu erstellen, man soll also nur den eingegbenen Text der InputBox sehen, ohne irgendeinen Rahmen oder Hintergrund.
Ich habe bereits diese Möglichkeit probiert, das scheint mit InputBoxen aber nicht zu funktionieren:

AutoIt

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WINAPI.au3>
$gui = GUICreate("trans", 300, 400, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
GUISetBkColor(0xABCDEF)
$layButt = GUICtrlCreateButton("Button", 10, 40, 40)
$label = GUICtrlCreateLabel ("Label", 10, 80, 100, 30)
$Input1 = GUICtrlCreateInput("nicht transparent", 0, 0, 417, 24, -1, 0)
_WinAPI_SetLayeredWindowAttributes($gui, 0xABCDEF, 255)
GUISetState()
While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case -3
            Exit
    EndSwitch
    Sleep(50)
WEnd

Alles anzeigen

Gibt es vielleicht noch eine andere Möglichkeit?
Bitte um Hilfe

Grüße, Elektronenpeter

**autoBert**

Welche Windowsversion benutzt du?

**Schnuffel**

einfach mal suchen

https://autoit.de/index.php/Thre…8563#post128563

elektronenpeter

@autoBert

ich nutze win10 und autoit 3.3.12

@Schnuffel

Danke, das würde erstmal gehen, mir wäre es aber eigentlich lieber wenn man den Text auch markieren könnte und einen Cursor sehen würde.
Wäre das auch noch irgendwie machbar?

Ich bin dankbar für alle Bemühungen

Edit: Mein Script bis jetzt:

AutoIt

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WINAPI.au3>
#include <_TransInput.au3>


$gui = GUICreate("trans", 300, 400, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
GUISetBkColor(0xABCDEF)
$input = GUICtrlCreateInput("Ich bin ein Input", 0, 0, 300, 24)
$layButt = GUICtrlCreateButton("Exit", 10, 40, 40)
$label = GUICtrlCreateLabel ("Transparentes Label", 10, 80, 100, 30)
_WinAPI_SetLayeredWindowAttributes($gui, 0xABCDEF, 255)
_TransInput_Create($input,12)
GUISetState()


While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case -3
            Exit
		Case $layButt
            Exit
    EndSwitch
    Sleep(50)
WEnd

Alles anzeigen

**autoBert**

Ist vielleicht nicht genau was du suchst kommt ihm aber sehr nahe:

C

;found https://www.autoitscript.com/forum/topic/87619-trans-gui/
^#cs ----------------------------------------------------------------------------
	AutoIt Version: 3.3.0.0
	Author:         HAL9000
	Script Function:
	Template AutoIt script.
#ce ----------------------------------------------------------------------------
; Script Start - Add your code below here
#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <ProgressConstants.au3>
#include <Constants.au3>
#include <StaticConstants.au3>
#NoTrayIcon
Opt("TrayMenuMode", 1)
HotKeySet("{F6}", "hide")
$1 = GUICreate("TRANS GUI", 700, 550, -1, -1, $WS_POPUP, $WS_EX_CLIENTEDGE)
$pic = GUICtrlCreatePic("bin\bg" & Random(1, 8, 1) & ".jpg", 0, 0, 700, 550) ;change bgX.jpg with your jpeg
GUICtrlSetState(-1, $GUI_DISABLE)
WinSetOnTop("TRANS", "", 1)
GUISetState(@SW_SHOW, $1)
$2 = GUICreate("GUI", 700, 550, -1, -1, $WS_POPUP, $WS_EX_MDICHILD, $1)
WinSetTrans("GUI", "", 0)
WinSetOnTop("GUI", "", 1)
GUISetState(@SW_SHOW, $2)
$progressbar1 = GUICtrlCreateProgress(0, 540, 700, 10, $PBS_SMOOTH)
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle(-1), "wstr", 0, "wstr", 0)
$close = GUICtrlCreateIcon("bin\close.ico", -1, 700 - 16, 0, 16, 16)
$w = GUICtrlCreateLabel("0", 300, 250, 150, 60)
GUICtrlSetFont(-1, 20, 800)
$idInput=GUICtrlCreateInput('My Input',20,300,600)	;eingefügt autoBert
GUICtrlSetFont(-1,13,1500)
;------------------------MENU FILE
$filemenu = GUICtrlCreateLabel("File", 3, 0, 25, 15)
GUICtrlSetFont(-1, 10, 800)
$filesDummy = GUICtrlCreateDummy()
$fileContext = GUICtrlCreateContextMenu($filesDummy)
$fileopen = GUICtrlCreateMenuItem("Background", $fileContext)
GUICtrlCreateMenuItem("", $fileContext)
$OptionsExit = GUICtrlCreateMenuItem("Exit", $fileContext)
;--------------------Menu EDIT
$editmenu = GUICtrlCreateLabel("Edit", 33, 0, 30, 15)
GUICtrlSetFont(-1, 10, 800)
$editDummy = GUICtrlCreateDummy()
$editContext = GUICtrlCreateContextMenu($editDummy)
$editcopy = GUICtrlCreateMenuItem("Copy", $editDummy)
$editpaste = GUICtrlCreateMenuItem("Past", $editDummy)
;---------------------MENU HELP
$helpmenu = GUICtrlCreateLabel("Help", 63, 0, 35, 15)
GUICtrlSetFont(-1, 10, 800)
$HelpDummy = GUICtrlCreateDummy()
$HelpContext = GUICtrlCreateContextMenu($HelpDummy)
$HelpWWW = GUICtrlCreateMenuItem("Website", $HelpContext)
GUICtrlCreateMenuItem("", $HelpContext)
$HelpAbout = GUICtrlCreateMenuItem("Help", $HelpContext)
$helpregister = GUICtrlCreateMenuItem("License", $HelpContext)
;-------------------LINE
$line = GUICtrlCreateGraphic(0, 16, 700, 2)
GUICtrlSetGraphic($line, $GUI_GR_LINE, 0, 0)
GUICtrlSetColor(-1, 0)
;-----------------ICONS
GUICtrlCreateIcon("shell32.dll", -100, 0, 25, 32, 32, $SS_SUNKEN)
GUICtrlCreateIcon("shell32.dll", -4, 32, 25, 32, 32, $SS_SUNKEN)
GUICtrlCreateIcon("shell32.dll", -7, 64, 25, 32, 32, $SS_SUNKEN)
For $a = 0 To 100 Step 2
	Sleep(1)
	WinSetTrans("GUI", "", $a * 1.5)
	GUICtrlSetData($progressbar1, $a)
	GUICtrlSetData($w, $a & " %")
Next
GUICtrlDelete($w)
While 1
	Sleep(1)
	$msg = GUIGetMsg()
	If $msg = $GUI_EVENT_CLOSE Or $msg = $OptionsExit Then ExitLoop
	If $msg = $close Then ExitLoop
	If $msg = $filemenu Then ShowMenu($2, $msg, $fileContext)
	If $msg = $helpregister Then InputBox("License", "Type your license key", "", " ", Default, Default, Default, Default, Default, $2)
	If $msg = $helpmenu Then ShowMenu($2, $msg, $HelpContext)
	If $msg = $editmenu Then ShowMenu($2, $msg, $editContext)
	If $msg = $fileopen Then
		$var = FileOpenDialog("Select a file", @ScriptDir & "\bin", "Images (*.jpg)", 1, "", $2)
		GUICtrlSetImage($pic, $var)
	EndIf
	;FileSelectFolder("Select","",6,"",$2)
	If $msg = $HelpAbout Then MsgBox(64, "Help", "F6 Hide/Show Gui" & @CRLF & "File/Background to change background", Default, $2)
WEnd
;  -------------- func
Func hide()
	GUISetState(@SW_HIDE, $1)
	GUISetState(@SW_HIDE, $2)
	HotKeySet("{F6}", "show")
EndFunc   ;==>hide
Func show()
	GUISetState(@SW_SHOW, $1)
	GUISetState(@SW_SHOW, $2)
	HotKeySet("{F6}", "hide")
EndFunc   ;==>show
; Show a menu in a given GUI window which belongs to a given GUI ctrl
Func ShowMenu($hWnd, $CtrlID, $nContextID)
	Local $arPos, $x, $y
	Local $hMenu = GUICtrlGetHandle($nContextID)
	$arPos = ControlGetPos($hWnd, "", $CtrlID)
	$x = $arPos[0]
	$y = $arPos[1] + $arPos[3]
	ClientToScreen($hWnd, $x, $y)
	TrackPopupMenu($hWnd, $hMenu, $x, $y)
EndFunc   ;==>ShowMenu
; Convert the client (GUI) coordinates to screen (desktop) coordinates
Func ClientToScreen($hWnd, ByRef $x, ByRef $y)
	Local $stPoint = DllStructCreate("int;int")
	DllStructSetData($stPoint, 1, $x)
	DllStructSetData($stPoint, 2, $y)
	DllCall("user32.dll", "int", "ClientToScreen", "hwnd", $hWnd, "ptr", DllStructGetPtr($stPoint))
	$x = DllStructGetData($stPoint, 1)
	$y = DllStructGetData($stPoint, 2)
	; release Struct not really needed as it is a local
	$stPoint = 0
EndFunc   ;==>ClientToScreen
; Show at the given coordinates (x, y) the popup menu (hMenu) which belongs to a given GUI window (hWnd)
Func TrackPopupMenu($hWnd, $hMenu, $x, $y)
	DllCall("user32.dll", "int", "TrackPopupMenuEx", "hwnd", $hMenu, "int", 0, "int", $x, "int", $y, "hwnd", $hWnd, "ptr", 0)
EndFunc   ;==>TrackPopupMenu
; ----------------------------------------

Alles anzeigen

die Technik funktioniert über eine (Teil)-transparente Childgui die mit Hilfe von WinSetTrans eingestellt wird.

Edit: du solltest dir das Original RAR herunterladen zwecks den HG-Bildern, kannst aber auch ein eigenes verwenden.

Das ganze so aus:1_VollBild.jpg

elektronenpeter

Erstmal vielen Dank,
aber das hilft mir leider nicht wirklich weiter, da der eingegebene Text ja auch transparent wird.
es gibt wohl wirklich keine Möglichkeit nur den Hintergrund des Inputs transparent zu setzen...