Timer mit Progressbar der läuft während ein Programm läuft

s0nny

Hallo,
bin gestern erst auf AutoIT gestoßen, als ich nach einer Möglichkeit gesucht habe, eine Dateisicherung für einen Nutzer so einfach und idiotensicher wie möglich zu machen.
Grund ist, dass diese Person vor kurzem von Ransomware befallen war. Eine Datensicherung war zwar vorhanden, aber die nützt in diesem Fall ja äußerst wenig, wenn die externe auf die gesichert wird, dauerhaft am System ist. Nun soll eine absolut idiotensichere Möglichkeit her, das ordentlich zu machen (heißt Festplatte soll auch immer schön getrennt werden und der Nutzer soll nicht viel mehr machen müssen als 1-2 mal OK zu drücken und die Festplatte an- und abzustöpseln).
Das ganze soll so nun so ablaufen:
Alle wichtigen Daten werden mit AOMEI Backupper als Image auf eine lokale Partition gesichert, wenn sich der Benutzer am System anmeldet (oder via Schedule, weiß ich noch nicht)
Diese Dateien sollen dann mittels SyncToy auf eine externe HDD gesynct werden.
Ich schreib also grad an einem kleinen Scrypt, welches über den Windows Task Scheduler regelmäßig ausgeführt wird, und als erstes mal über ein logfile prüft, wann die Backups zum letzten mal gesynct wurden. Ist eine gewisse Zeitschwelle überschritten, poppt ein Fenster auf, was dem Nutzer sagt wann das letzte mal gesynct wurde und dass es doch mal wieder an der Zeit wäre.
Er kann dann abbrechen oder ja sagen. Dann wird geprüft ob die externe angeschlossen ist und ggf. so oft darauf hingewiesen, dass diese angeschlossen werden soll, bis sie auch wirklich angeschlossen ist.
Dann ruf ich SyncToy über die CMD auf und starte den SyncVorgang.
Dabei würde ich gerne einen kleinen Timer laufen lassen, der anzeigt, wie lange die Synchronisierung schon dauert. Optimal wäre auch noch ein Fortschrittsbalken, der definitiv nicht genau sein muss! Würde da einfach eine anzunehmende Datenrate für verwenden und ob er dann schon bei 80% fertig ist, oder der Balken schon 100% zeigt und er noch nicht ganz fertig ist, ist nicht so wichtig. Das dient nur zur ungefähren Abschätzung und dass der Anwender nicht denkt da würde nichts mehr passieren und er könne den PC einfach ausschalten. Das (also der Timer+Fortschrittsbalken) ist eigentlich das einzige was mir noch fehlt.
Weiß nicht genau wie ich das bewerkstelligen soll, weil alles was ich so gefunden hab mir While-Schleifen Arbeitet, und das Programm somit an dieser stelle quasi "stecken bleibt".
Am Ende würde dann noch der Hinweis kommen, dass die externe jetzt bitte wieder abgestöpselt wird.

Gibt es da eine Möglichkeit? Oder ist mein Grundgedanke schon falsch?

Vielen Dank schonmal für euere Bemühungen

**autoBert**

Eine ProgressBar die schon 100% zeigt bevor das Backup fertig ist, wirkt nicht nur unschön sondern verleitet auch dazu schon abzustpüseln. Daher rate ich zur Marquee-Progressbar. Timer kannst du mit AdLibRegister machen.

AutoIt: OnEvent-Modus

#include <GUIConstantsE x.au3>
#include <SendMessage.au3>
#include <ProgressConstants.au3>


Opt("GUIOnEventMode", 1)


$Form1 = GUICreate("Form1", 545, 125, 5, 5);, $WS_POPUP, $WS_EX_TOOLWINDOW)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1Close")
$Button1 = GUICtrlCreateButton('&STOP Marquee', 5, 5)
GUICtrlSetOnEvent(-1, "StopResumeMarquee")
$Timer = GUICtrlCreateLabel('Zeit: ', 470, 5, 70)
$Progress1 = GUICtrlCreateProgress(0, 95, 545, 25, $PBS_MARQUEE)
$hProgress = GUICtrlGetHandle($Progress1) ;wichtig
_SendMessage($hProgress, $PBM_SETMARQUEE, True, 10) ;Handle verwenden
GUISetState(@SW_SHOW)
$dtStart = TimerInit()


AdlibRegister('Timer', 1000)


While 1
	Sleep(100)
WEnd


Func Timer()
	Local $Time = TimerDiff($dtStart) / 1000
	Local $HOUR = Int($Time / 3600)
	Local $MIN = Int(($Time - $HOUR * 3600) / 60)
	Local $SEC = $Time - $HOUR * 3600 - $MIN * 60
	GUICtrlSetData($Timer, StringFormat("%02i:%02i:%02i", $HOUR, $MIN, $SEC))
EndFunc   ;==>Timer


Func StopResumeMarquee()
	If GUICtrlRead($Button1) = '&STOP Marquee' Then
		_SendMessage($hProgress, $PBM_SETMARQUEE, False, 10)
		GUICtrlSetData($Button1, '&Resume Marquee')
	Else
		_SendMessage($hProgress, $PBM_SETMARQUEE, True, 10)
		GUICtrlSetData($Button1, '&STOP Marquee')
	EndIf
EndFunc   ;==>StopResumeMarquee


Func Form1Close()
	Exit
EndFunc   ;==>Form1Close

Alles anzeigen

AutoIt: MsgLoop-Modus

#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <ProgressConstants.au3>




$Form1 = GUICreate("Form1", 545, 125, 5, 5);, $WS_POPUP, $WS_EX_TOOLWINDOW)
$Button1 = GUICtrlCreateButton('&STOP Marquee', 5, 5, 200)
$Timer = GUICtrlCreateLabel('Zeit: ', 470, 5, 70)
$Progress1 = GUICtrlCreateProgress(0, 95, 545, 25, $PBS_MARQUEE)
$hProgress = GUICtrlGetHandle($Progress1)
_SendMessage($hProgress, $PBM_SETMARQUEE, True, 10)
GUISetState(@SW_SHOW)
$dtStart = TimerInit()




AdlibRegister('Timer', 1000)


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $Button1
			If GUICtrlRead($Button1) = '&STOP Marquee' Then
				_SendMessage($hProgress, $PBM_SETMARQUEE, False, 10)
				GUICtrlSetData($Button1, '&Resume Marquee')
			Else
				_SendMessage($hProgress, $PBM_SETMARQUEE, True, 10)
				GUICtrlSetData($Button1, '&STOP Marquee')
			EndIf
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd


Func Timer()
	Local $Time = TimerDiff($dtStart) / 1000
	Local $HOUR = Int($Time / 3600)
	Local $MIN = Int(($Time - $HOUR * 3600) / 60)
	Local $SEC = $Time - $HOUR * 3600 - $MIN * 60
	GUICtrlSetData($Timer, StringFormat("%02i:%02i:%02i", $HOUR, $MIN, $SEC))
EndFunc   ;==>Timer

Alles anzeigen

**Kanashius**

Da ich schon länger ein BackUp Programm schreiben wollte hab ich das jetzt mal gemacht.
Ist allerdings in Java, damit ich Threads benutzen kann, um die Sache etwas zu beschleunigen. (Bei mir den gesamten PC mit 2 Festplatten nach geänderten Dateien zu durchsuchen hat ~8min. gedauert (~1,7TB))
Man kann das Programm auch mit Parametern starten, was für dich interessant wäre, damit du die Pfade, Ausnahmen und den Datumszeitraum festlegen kannst. Eventuell pack ich noch nen silentmode rein, damit alles ohne gui läuft, und die Ausgaben in die Konsole geschrieben werden

Code

Parameterlist: 
	-SearchFolder
		AbsolutePath
		 The Folder must exists!
	-BackupFolder
		AbsolutePath
		 The Folder must exists!
	-startDate
		Date in Format dd.MM.yyyy for Example:09.03.2016
		 StartDate is the older Date
	-endDate
		Date  in Format dd.MM.yyyy for Example:09.03.2016
		 EndDate is the newer Date
	-exceptions
		List of Exceptionpaths. Last parameter in the List.
		 All Parameters behind this must be Paths to Exceptions.
		 Throws a Warning, if a Path does not exists.
	-nocopy
		Do not copy files. Just show the List.
	-details
		Shows the ParameterDetails

Alles anzeigen

Bei den Exceptions empfiehlt es sich übrigens, den AppDataOrdner hinzuzufügen... Die ganzen Dateien von Firefox, die der cached sind nicht unbedingt nett zu kopieren :D. Ebenso viele andere Dateien, die von Programmen genutzt werden

Beispielaufruf:

Run('javaw -jar BackUp.jar -startDate "08.03.2016"',@ScriptDir)

Viel Spaß damit. Ich denke ich werd das Tool auch fleißig nutzen
(wird sich demnächst auch auf meiner Webside finden)

MfG Kanashius

Habs als zip hochgeladen, musst noch entpacken.

bazii

Hallo sOnny,

erst mal willkommen hier

Zitat von s0nny

Oder ist mein Grundgedanke schon falsch?

Der Grundgedanke ist jedem Programmierer sein höchstes Gut. Daher halte an Deiner Idee im Grundgedanke fest.

Die Vorgehensweise mit dem AOMEI Backupper als Image auf eine lokale Partition würde ich jedoch überdenken. Ich rate driekt zu einem AOMEI Backupper Image (oder Acronis macht das auch super) auf eine externe Festplatten-Lösung.

Wenn Du den Benutzer vor Ransomware schützen möchtest, sollte auf jeden Fall immer ein abgeschlossenes Image sehr dienlich sein.

Zitat von s0nny

Das (also der Timer+Fortschrittsbalken) ist eigentlich das einzige was mir noch fehlt.
Weiß nicht genau wie ich das bewerkstelligen soll, weil alles was ich so gefunden hab mir While-Schleifen Arbeitet, und das Programm somit an dieser stelle quasi "stecken bleibt".

Schau Dir dazu bitte mal die einmaligen Beispiele von UEZ seinem Beitrag unter GDI-Animated-Loading-Waiting-Screens-mit-32-Beispielen an. Mir haben es diese Animationen angetan und sind einfach schöner für den Benutzer, (ist natürlich Geschmacksache) als nur einfache Fortschrittsbalken.

UEZ hat mir bei diesem Thema beim Einsatz der o. g. Beispiele klasse weitergeholfen. Vielleicht hilft es Dir ja auch für Dein Vorhaben.

s0nny

Hallo,
vielen Dank für Eure Antworten.
Bin leider erst am Wochenende dazu gekommen, am Script weiter zu arbeiten.

Zitat von autoBert

Eine ProgressBar die schon 100% zeigt bevor das Backup fertig ist, wirkt nicht nur unschön sondern verleitet auch dazu schon abzustpüseln. Daher rate ich zur Marquee-Progressbar. Timer kannst du mit AdLibRegister machen.

Der Marquee-Progressbar ist dafür natürlich einiges besser geeignet, hab ich nun auch so umgesetzt

Zitat von bazii

Die Vorgehensweise mit dem AOMEI Backupper als Image auf eine lokale Partition würde ich jedoch überdenken. Ich rate driekt zu einem AOMEI Backupper Image (oder Acronis macht das auch super) auf eine externe Festplatten-Lösung.
Wenn Du den Benutzer vor Ransomware schützen möchtest, sollte auf jeden Fall immer ein abgeschlossenes Image sehr dienlich sein.

Genau das tue ich ja. Ich mache von den Benutzerdaten regelmäßig ein Backup als Image und speichere dieses auf einer lokalen Partition. Das hat den Vorteil, dass das Backup jederzeit im Hintergrund laufen kann, ohne dass der Benutzer etwas tun muss.
Dann kommt das Script zum Einsatz. Dieses pack ich in den Windowsscheduler und lass es regelmäßig ausführen. Das Script sagt dem Nutzer dann "Hey, hast schon seit 3 Tagen dein Backup nicht mehr gesichert, mach mal wieder!" (ob nun 3 Tage, ein Tag oder vll nur wöchentlich nötig ist muss iletztendlich der Nutzer entscheiden)
Der Nutzer kann dann sagen OK, dann wird er aufgefordert die externe anzuschließen und OK zu drücken und die Backups werden auf die externe gesichert. Wenn das Backup fertig ist nerv ich den Nutzer noch damit, dass er die externe wieder entfernen muss.
Damit nehm ich den Nutzer denk ich recht gut an die Hand, und "zwinge" ihn wirklich zu beherzigen, dass das Backupmedium nicht dauerhaft am PC angeschlossen ist.
Wenn ich das Backup direkt auf die externe machen würde, müsste der Nutzer die externe entweder immer angeschlossen haben (schlecht) oder das Backup selbst starten wenn er die Festplatte angeschlossen hat (schlecht).
Das einzige was mit meiner Methode halt passieren könnte ist, dass das Backup immer schön auf der lokalen Platte gesichert wird, der Nutzer aber immer die Aufforderung, das Backup auf der externen sichern zu lassen, wegklickt. Aber ab einem gewissen Punkt ist der Nutzer meiner Meinung nach auch selbst in der Pflicht. Und wenn es ihm nicht zuzumuten ist, die externe aller paar Tage anzuschließen wenn der PC ihm den Hinweis schon gibt und einmal OK zu drücken, dann hat er halt einfach pech

Bin wie gesagt soweit durch, hänge nun noch vor einem kleinen "Problem".
Ich speichere Daten wie den Pfad wo die Backups sind und den Zielpfad in einer .ini-Datei.
Dafür habe ich noch ein kleines extra Script gemacht, mit dem man diese Config erstellen kann. Das Gui sieht erstmal ungefähr so aus:

AutoIt

$Form1 	= GUICreate("Configuration erstellen", 400, 280,   324,228)
$Label1 = GUICtrlCreateLabel("Lokaler Pfad: ", 	8,	16, 	64, 17)
$Label2 = GUICtrlCreateLabel("Externer Pfad: ", 8, 	40, 	68, 17)
$Label3 = GUICtrlCreateLabel("SyncToy-Pfad: ", 	8, 	64, 	71, 17)
$Label4 = GUICtrlCreateLabel("SyncToy-Name: ", 	8, 	88, 	77, 17)
$Label5 = GUICtrlCreateLabel("ID File: ", 	8, 	112, 	34, 17)
$Label6 = GUICtrlCreateLabel("Logfile: ", 	8, 	136, 	35, 17)
$Label7 = GUICtrlCreateLabel("Warnschwelle: ", 	8, 	160, 	71, 17)
$Label8 = GUICtrlCreateLabel("Datenrate: ", 	8, 	184,	51, 17)


$Input1 = GUICtrlCreateInput($aReturn[1][1], 104, 	12, 	281, 21)
$Input2	= GUICtrlCreateInput($aReturn[2][1], 104, 	36, 	281, 21)
$Input3	= GUICtrlCreateInput($aReturn[3][1], 104, 	60, 	281, 21)
$Input4	= GUICtrlCreateInput($aReturn[4][1], 104, 	84, 	281, 21)
$Input5	= GUICtrlCreateInput($aReturn[5][1], 104, 	108, 	281, 21)
$Input6	= GUICtrlCreateInput($aReturn[6][1], 104, 	132, 	281, 21)
$Input7	= GUICtrlCreateInput($aReturn[7][1], 104, 	156, 	281, 21)
$Input8	= GUICtrlCreateInput($aReturn[8][1], 104, 	180, 	281, 21)
$Button1 = GUICtrlCreateButton("Config erstellen",0,	216, 	200, 64)
$Button2 = GUICtrlCreateButton("Abbrechen",	 200,	216, 	200, 64)

Alles anzeigen

Wie krieg ich es denn hin, dass ich in die Input-Zeile reinklicken kann, und sich dann ein FileSelectFolder-Fenster öffnet? Und wenn ich den Pfad ausgewählt habe, soll der Pfad im Input-Feld stehen.
Oder alternativ könnt ich mir auch vorstellen rechts neben der Input-Zeile einen kleinen Button mit 3 Punkten zu haben [...], der das FileSelectFolder-Fenster öffnet (soweit erstmal kein Problem, das würd ich noch hinkriegen) und dann widerum den ausgewählten Pfad in das Input-Feld einträgt.
Oder ist das so nicht möglich?

bazii

Hallo

Zitat von s0nny

Oder alternativ könnt ich mir auch vorstellen rechts neben der Input-Zeile einen kleinen Button mit 3 Punkten zu haben [...], der das FileSelectFolder-Fenster öffnet (soweit erstmal kein Problem, das würd ich noch hinkriegen) und dann widerum den ausgewählten Pfad in das Input-Feld einträgt.
Oder ist das so nicht möglich?

Schau Dir mal das Beispiel von mir an.

Code

#Region
#AutoIt3Wrapper_Outfile=_.exe
#AutoIt3Wrapper_UseUpx=y
#AutoIt3Wrapper_Res_Comment=Beispiel.
#AutoIt3Wrapper_Res_Description=Beispiel
#AutoIt3Wrapper_Res_Fileversion=Beispiel
#AutoIt3Wrapper_Res_LegalCopyright=-Beispiel
#AutoIt3Wrapper_Res_Language=1031
#EndRegion


; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +


;;;;;;;;;;;;;;;;;;;;;;;;
;;       Beispiel     ;;
;;;;;;;;;;;;;;;;;;;;;;;;




#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>


; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +


Opt('GUIOnEventMode', 1)
Opt('MustDeclareVars', 1)


; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +


AutoItSetOption("TrayMenuMode", 11)


; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +


Global $g_hGUI, $Inputbox1, $Ordnerwahl, $Text1, $makeindextxt


; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +


$g_hGUI = GUICreate("Beispiel", 758, 250, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_THICKFRAME))
	GUISetBkColor(0xD7E4F2)
	GUICtrlSetFont(-1, 8, 400, 4, "Arial")
	$Inputbox1 = GUICtrlCreateInput("Pfadauswahl nur über Icon Ordner wählbar!", 230, 63, 500, 23, $ES_READONLY)
	GUICtrlSetTip(-1, "Dieses Feld füllt sich automatisch" & @CRLF & "über den Button -Ordner wählen-!")
	$Ordnerwahl = GUICtrlCreateButton("Ordner wählen", 36, 63, 177, 25, $BS_ICON)
	GUICtrlSetTip(-1, "Zielordner wählen")
	GUICtrlSetColor(-1, 0x000000)
	GUICtrlSetOnEvent($Ordnerwahl, __idButton_Ordnerwahl__)
	GUISetState(@SW_SHOW)


; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +


HotKeySet("{ESC}","Quit") ;Press ESC key to quit


; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +


While Sleep(200)
WEnd ;==>__Schleife zur Vermeidung von Prozessorlast__


; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +


Func __idButton_Ordnerwahl__()
	Local $Ordnerwahl = FileSelectFolder("Ordner wählen", "::{20D04FE0-3AEA-1069-A2D8-08002B30309D}", Default, "", $g_hGUI)
	If @error Then Return ;--Return um nicht das Programm zu beenden, sondern um zur GUI zurückzukehren
	GUICtrlSetData($Inputbox1, $Ordnerwahl)
EndFunc   ;==>__idButton_Ordnerwahl__




; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +


Func Quit()
    Exit
EndFunc


; ++++++++++ +++++++++ ++++++++ +++++++ ++++++ +++++ ++++ +++ ++ +

Alles anzeigen

Eventuell bringt es Dich etwas weiter.

s0nny

Hallo,
hilft!
Hab allerdings noch ein Problem dabei. Ich kann Ordner auswählen, das funktioniert.
Wenn ich allerdings Dateien auswählen will, funktioniert das nicht. Ich verwende dann statt der FileSelectFolder() Funktion die FileOpenDialog()-Funktion. Die Datei wird auch wie gewünscht im Inputfeld angezeigt. Wenn ich dann allerdings die config erstellen will, passiert nichts.
Mach ich das ganze nur für ORdner, funktioniert alles tadellos.
Auch wenn ich statt des FileOpenDialog-Buttons einfach selbst was reinschreibe erstellt er die Config.
Es wird also wirklich nur dann keine Config gebaut, wenn ich eine Datei(!) über die FileOpenDialog()-Funktion auswähle.

AutoIt

$configFile = ".\config.ini"
$section = "config"


If FileExists( $configFile ) == 0 Then
  Dim $aReturn[4][2]
  $aReturn[0][0] = 3
  $aReturn[0][1] = ""
  $aReturn[1][0] = "backupPathLocal"
  $aReturn[1][1] = ""
  $aReturn[2][0] = "backupPathExternal"
  $aReturn[2][1] = ""
  $aReturn[3][0] = "ID-File"
  $aReturn[3][1] = ""
Else
  $aReturn = IniReadSection($configFile, $section)
EndIf






$Form1 	= GUICreate("Configuration erstellen", 	400, 260,  324,	228)


$Label1 = GUICtrlCreateLabel("Lokaler Pfad: ", 	8,16, 77, 21)
$Input1 = GUICtrlCreateInput($aReturn[1][1], 95, 12, 260,21)
$Button1= GUICtrlCreateButton("...", 360, 12, 35, 21)


$Label2 = GUICtrlCreateLabel("Externer Pfad: ", 8, 40, 77, 21)
$Input2	= GUICtrlCreateInput($aReturn[2][1], 95, 36, 260, 21)
$Button2= GUICtrlCreateButton("...", 360, 36, 35, 21)


$Label3 = GUICtrlCreateLabel("ID-File: ", 8, 64, 77, 21)
$Input3	= GUICtrlCreateInput($aReturn[3][1], 95, 60, 260, 21)
$Button3= GUICtrlCreateButton("...", 360, 60, 35, 21)


$create = GUICtrlCreateButton("Config erstellen",-2,200, 204, 64)
$abort 	= GUICtrlCreateButton("Abbrechen",200,200, 204, 64)
GUISetState(@SW_SHOW)




While 1
  $nMsg = GUIGetMsg()
  Switch $nMsg
    Case $GUI_EVENT_CLOSE, $abort
      Exit

    Case $Button1
      $path1 = FileSelectFolder("Wähle den lokalen Pfad, an dem die Backups liegen.", "", "All files (*.*)")
      If @error Then
        ContinueLoop
      EndIf
      GUICtrlSetData($Input1, $path1)


    Case $Button2
      $path2 = FileSelectFolder("Wähle den externen Pfad, an dem die Backups liegen.", "", "All files (*.*)")
      If @error Then
        ContinueLoop
      EndIf
      GUICtrlSetData($Input2, $path2)


    Case $Button3
      $path3 = FileOpenDialog("Wähle das ID-File aus.", "", "All files (*.*)")
      If @error Then
        ContinueLoop
      EndIf
      GUICtrlSetData($Input3, $path3)


    Case $create
        Dim $Input[4][2]
	$Input[0][0] = 3
	$Input[0][1] = ""
	$Input[1][0] = "backupPathLocal"
	$Input[1][1] = GUICtrlRead($Input1)
	$Input[2][0] = "backupPathExternal"
	$Input[2][1] = GUICtrlRead($Input2)
	$Input[3][0] = "ID-File"
	$Input[3][1] = GUICtrlRead($Input3)


	IniWriteSection( $configFile, $section, $Input, 1)
	ConsoleWrite(@ERROR&@LF)
	Exit
  EndSwitch
WEnd

Alles anzeigen

bazii

Hallo sOnny,

es ist doch alles gut. Du musst nur ein #include <GUIConstantsEx.au3> in Dein Script einfügen und schon gehts.

Ich empfehle Dir Organize-Includes

s0nny

Hallo,
das ist bereits includiert, hatte ich jetzt nur nicht mitgepostet weil da noch einiges sinnloses mit drin ist. Muss das wenn ich fertig bin erst noch etwas bereinigen. Bzw. ich werd mir dann mal den Inludeorganizer genauer angucken, das klingt äußerst interessant!

Aber egal was ich mache, sobald ich eine Datei über FileOpenDialog() öffne, schreibt er nichts in die Config.
Schreib ich was per Hand in das Feld, tut ers.
Und auch wenn ich die FileOpenDialog() Sachen weglasse und nur die beiden FileSelectFolder() nehme funktioniert es.

bazii

Du sOnny,

mach einen Test.

Öffne die Schaltfläche bei ID-File
*Wähle eine Datei aus
Drücke Config erstellen
*Verfolge den Pfad im Explorer zurück

Und da liegt Deine fertig geschriebene config.ini

Wenn Du die config.ini wo anders haben möchtest, .... weißt schon.

**Oscar**

Zitat aus der Hilfe zu FileOpenDialog:

Zitat von FileOpenDialog

@WorkingDir is changed on successful return.

Und da Du einen relativen Pfad bei IniWriteSection verwendest, wird die Ini im "falschen" (WorkingDir) Verzeichnis erstellt.

bazii

... by the Way ist bei IniWriteSection event. noch folgender Satz aus der Hilfe hilfreich.

Zitat von AutoIt

If you want to use an ini file with unicode encoding, first create an .ini file
by using the FileOpen() function with the mode
parameter set to "Unicode UTF16 Little Endian".

s0nny

Oh Mann, Vielen Dank für Eure Hilfe!
Hab $configFile von ".\config.ini" auf "@ScriptDir & "\config.ini" geändert und für den Fall, dass noch keine config.ini existiert, erstell ich eine bevor ich drin rumschreiben will. Jetzt funktioniert alles wie gewollt