Nummernkreislauf generieren

Kloppstock

Hallo liebe Leute,

ich versuche folgendes Programm zu schreiben:

Es soll ein Kreislauf von Auftragsnummern erstellt werden. Sprich Ich drücke einen Button und es werden 20 Nummern ab 200 angezeigt die ich ausdrucken kann. Wenn der nächste auf dem Button drückt sollen 20 Nummern ab 221 angezeigt werden und so weiter. Wird die Zahl 500 erreicht, soll der der Zähler wieder auf 200 gesetzt werden und von vorne anfangen.
Wichtig ist auch, dass das Programm auch mit mehreren gleichzeitig aktiven Leuten klar kommt. Wäre doof, wenn das Programm dann abstürzt oder Nummern bei 2 Nutzern gleich anzeigt.

Habt ihr da eine Idee?

Gruß
Philip

x0r

Hi,

evtl kannst du da mit einer "ini" (oder txt geht auch) arbeiten, die eine darin enthaltene Zahl immer weiter hochzählt, sobald jemand auf seinen Button klickt und diese Zahl genauso vor der Ausgabe ausliest.

Ich würds jedenfalls so versuchen

Gruß,
x0r

Kloppstock

Ok. Meine Idee zum Programmablauf wäre dann :
Autoit erstellt eine ini nach dem Knopfdruck die 20 fortlaufende Nummern enthält, welche man dann ausdrucken kann . Außerdem setzt er noch in einer anderen ini Datei eine Variable +20. Wird der Knopf wieder betätigt, guckt er nach der ini Datei und liest die ggf aus. Sie enthält dann ja eine um 20 erhöhte Variable. Da rechnet er wieder 20 drauf gibt es aus und schreibt wieder +20 in die Quellini. Code enthält dann natürlich auch eine Prüfung, ob wert schon zu hoch ist und fängt ggf von vorne an. Würde das so funktionieren?

**Andy**

Hi,

Zitat von Kloppstock

erstellt eine ini nach dem Knopfdruck die 20 fortlaufende Nummern enthält

Du benötigst keine *.ini mit 20 fortlaufenden Nummern, du benötigst eigentlich nur eine Textdatei.
Btw. sollen diese "Nummern" auch ausgedruckt werden, soll dafür ein spezielles Format herhalten?
Wieso AutoIt?
Gibt es bei euch in der Firma ggf. Excel? Damit wäre sowohl der Nummernkreis als auch der Ausdruck mit einigen Zeilen VBA-Code erledigt! Und eine extra Datei gespeichert werden müsste auch nicht...

Kloppstock

Das klingt natürlich wesentlich einfacher. Wie erstellt man so ein vba Script

**Kanashius**

Hier mit Server/Client Prinzip. IpAdresse musst du dann jeweils ändern, oder den Nutzer eintragen lassen,...

Server:

AutoIt

#cs ----------------------------------------------------------------------------


 AutoIt Version: 3.3.13.10 (Beta)
 Author:         Kanashius


#ce ----------------------------------------------------------------------------


Global $arUsers[0],$IpAdress=@IPAddress1,$Port=65432,$aktAufNr=200,$maxAufNr=500,$giveAufNr=20


OnAutoItExitRegister("_closeF")


TCPStartup()
$listenSocket=TCPListen($IpAdress,$Port)
if @error then
	Switch @error
		case 1
			_sE("IPAdresse: "&$IpAdress&" is incorrect!")
		case 2
			_sE("Port: "&$Port&" is incorrect!")
		case else
			_sE("Unknown Error opening Server. See MSDN for more Information: "&@error)
	EndSwitch
	exit
endif


While sleep(10)
	$socket=TCPAccept($listenSocket)
	if NOT @error and $socket<>-1 then
		_newConnection($socket)
	endif
	for $i=0 to UBound($arUsers)-1 step 1
		if $arUsers[$i]<>-1 then
			$data=TCPRecv($arUsers[$i],9999)
			if @error and @error<>-1 then
				_closeConnetion($i)
			else
				if $data<>"" then
					_gotMessage($i,$data)
				endif
			endif
		endif
	next
WEnd


Func _gotMessage($nr,$msg)
	if $msg="CLOSE" then
		_closeConnetion($nr)
	elseif $msg="GETNR" then
		$string=""
		for $i=0 to $giveAufNr-1 step 1
			if $string<>"" then
				$string&="|"
			endif
			$string&=$aktAufNr
			$aktAufNr+=1
			if $aktAufNr>$maxAufNr then
				$aktAufNr=0
			endif
		next
		TCPSend($arUsers[$nr],"NR:"&$string)
	endif
EndFunc


Func _closeConnetion($nr)
	TCPSend($arUsers[$nr],"CLOSE")
	TCPCloseSocket($arUsers[$nr])
	$arUsers[$nr]=-1
EndFunc


Func _newConnection($socket)
	for $i=0 to UBound($arUsers)-1 step 1
		if $arUsers[$i]=-1 then
			$arUsers[$i]=$socket
			return 0
		endif
	next
	ReDim $arUsers[UBound($arUsers)+1]
	$arUsers[UBound($arUsers)-1]=$socket
EndFunc


Func _sE($msg);showError
	MsgBox(16,"Error",$msg)
EndFunc


Func _closeF()
	for $i=0 to UBound($arUsers)-1 step 1


	next
	TCPShutdown()
EndFunc

Alles anzeigen

Client:

AutoIt

#cs ----------------------------------------------------------------------------


 AutoIt Version: 3.3.13.10 (Beta)
 Author:         Kanashius


#ce ----------------------------------------------------------------------------
#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <WindowsConstants.au3>


local $width=400,$height=200,$IpAdress=@IPAddress1,$Port=65432,$socket
OnAutoItExitRegister("_closeF")


TCPStartup()
$socket=TCPConnect($IpAdress,$Port)
if @error then
	Switch @error
		case 1
			_sE("IPAdresse: "&$IpAdress&" is incorrect!")
		case 2
			_sE("Port: "&$Port&" is incorrect!")
		case else
			_sE("Unknown Error opening Server. See MSDN for more Information: "&@error)
	EndSwitch
	exit
endif


$Gui=GUICreate("Auftragsnummer",$width,$height)
$button=GUICtrlCreateButton("Hole Auftragsnummern",5,5,$width-10,25)
$list=GUICtrlCreateList("",5,35,$width-10,$height-35,BitOR($WS_BORDER,$WS_VSCROLL))
GUISetState(@SW_SHOW)


While 1
	$msg=GUIGetMsg()
	Switch $msg
		case $button
			GUICtrlSetState($button,$GUI_DISABLE)
			TCPSend($socket,"GETNR")
		case -3
			exit
	EndSwitch
	$data=TCPRecv($socket,9999)
	if @error and @error<>-1 then
		_sE("Verbindung zum Server verloren!")
		exit
	endif
	if $data<>"" then
		if $data="CLOSE" then
			_sE("Server hat die Verbindung geschlossen!")
			exit
		elseif StringInStr($data,"NR:")=1 then
			_GUICtrlListBox_ResetContent($list)
			$string=StringMid($data,4)
			$ar=StringSplit($string,"|",1+2)
			for $i=0 to UBound($ar)-1 step 1
				GUICtrlSetData($list,$ar[$i])
			next
			GUICtrlSetState($button,$GUI_ENABLE)
		endif
	endif
WEnd


Func _closeF()


EndFunc


Func _sE($msg);showError
	MsgBox(16,"Error",$msg)
EndFunc

Alles anzeigen

Hoffe, das geht in die Richtung von dem, was du haben möchtest. Kannst es ja dementsprechend anpassen.

Kloppstock

Wow echt sehr ausführlich. Werde ich morgen mal testen. Kann ich statt IP auch einen Computernamen verwenden.

Kloppstock

AutoIt Errro
Line 4098 (File...\client.au3)
Error:Error in expression.

Was muss ich tun?
Der Server scheint erstmal ohne Fehlermeldung zu laufen

**Kanashius**

Welche AutoIt-Version nutzt du? Die, die bei den Scripten oben steht (3.3.13.10 oder höher)?

Ansonsten gib mal die genaue Fehlermeldung. Wenn möglich nachdem du die Datei mit F5 in SciTe ausführst. Dann steht dort auch gleich die Zeile ohne Includes.

MfG Kanashius

**Kanashius**

Hab Computernamen hinzugefügt. Wenn du die Variable $Hostname am Anfang leer lässt wird die $Ipadress genommen, sonst der Hostname (Fehlermeldung, wenn der nicht gefunden wird).

Kloppstock

Ah jetzt klappt es super soweit. Gute Arbeit Kanashius!
Zwei Probleme habe ich aber noch:
- Wenn ich das Server-Script beende speichert er nicht die letzte Nummer. Also wenn ich den Servercomputer neustarten muss, fängt er wieder von vorne an. Kann man das beheben?
- Er zeigt die Nummern schön an, aber ich brauche noch einen Button zum drucken. Ist das möglich?

Ein letzter Punkt fällt mir auch noch ein. Ist es möglich $giveAufNr als Eingabefeld in den Client zu intigrieren, dass jeder Client selbst entscheidet, wieviel er braucht?

**Kanashius**

Klar! Kannst den Aktuellen Wert beim Beenden SPeichern und beim Starten laden. SIehe: IniWrite, IniRead (oder einfach normales fileread/filewrite).
Für die Anzahl: Nen Input dazupacken, wo ne Zahl reinkommt, diese Zahl an den Server senden, dort dann Abfragen und passend reagieren.

Heut (späten)abend kann ich das machen. Grad nur noch 4% Akku aufm Laptop

**Kanashius**

Habs umgesetzt.

Kloppstock

Fehlt nur noch ein Button zur Ausgabe in einer Doc oder zum direkten drucken

Edit:
~~Oh mir fällt gerade auf, dass er bei 0 anfängt, wenn die 500 erreicht sind, sollte aber eigentlich wieder bei 200 starten~~
Edit2: Ah ok. Ich versuche nebenbei ja auch etwas zu lernen und das Script, zu verstehen. Da habe ich $aktAufNr=0 gesehen, geändert und es funktioniert.

Du hast echt viel Ahnung von Autoit. Da kann ich noch viel lernen!

**Kanashius**

Zum drucken speicher ich immer als HTML. Da kann man dann designtechnisch auch einfach viel machen. Und im Browser ausdrucken. (Kann man ja automatisch öffnen).

Danke

Kloppstock

Leider übersteigt dass meine Fähigkeiten, wie speicher ich denn die msg ausgabe als html, dass man sie direkt drucken kann?

**Kanashius**

Hab Drucken hinzugefügt. Das Design kannst du in Zeile 12 ändern bei $html, sowie in Zeile 91: $str&="<li>"&$ar[$i]&"</li>". Wenn nichts gedruckt wird erhöhe $TimeToPrint (in 1000 Schritten). Solange wartet er (in ms), wenn das Druckenfenster verschwunden ist, darauf, dass der IE den Druckauftrag gibt... Hab bisher keine bessere Methode gefunden, dass er drucken kann, bevor _IEQuit kommt.

Habs jetzt so hinbekommen, dass er das garnicht speichern muss

Server wurde nicht geändert.

Kloppstock

Genau so habe ich mir das vorgestellt!
Echt super.
Ein letzer Wunsch fällt mir noch ein.
Kann man eine Begrenzung rein machen, dass ein bestimmter Computername oder IP nur 50 Nummern am Tag erstellen darf?
Will verhindern, dass ein Troll 10000 Nummern erstellt.

Nachid

Wenn das nicht 100% sein muss füg einfach am Schluss der Funktion für den Generieren Knopf folgendes ein

AutoIt

Sleep(1000 * 60) ;Sind 1000 mal 60 millisekunden (1minute)

Das wird es für einen Troll echt unattraktiv machen

Kloppstock

Aber wenn ich ein sleep reinmache, kann ich ja einfach das Programm schließen und wieder öffnen?!