Checkboxnamen aus Array verwenden

mm4040

Hallo
ich möchte gern den Namen (Variabel) aus einem Array verwenden um eine Checkbox anzusprechen.
Wenn ich den Namen direkt verwende wird die Checkbox aktiviert, wenn ich den Namen der Checkbox aus dem Array verwenden möchte, geht es nicht.
Hmmm.
Kann mit jemand helfen?

Code

#include <Array.au3>
#include<GUIConstants.au3>
GUICreate("gui", 400,400)
Global $Label1 = GUICtrlCreateCheckbox("box1", 20, 10, 50, 12)
Global $Label2 = GUICtrlCreateCheckbox("box2", 20, 30, 50, 12)
GUISetState(@SW_SHOW)


Dim $aBefehl[2][2]=[  _
['test1','$Label1'], _
['test2','$Label2']]
_ArrayDisplay($aBefehl)


;~     GUICtrlSetState($Label1,$GUI_CHECKED); damit funktioniert es


    GUICtrlSetState($aBefehl[0][1],$GUI_CHECKED); mit dem Namen $Label1 aus dem Array funktioniert es nicht.

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case -3
            Exit
    EndSwitch
 WEnd

Alles anzeigen

**autoBert**

Um einem Control etwas zuzuweisen benötigst du die ControlID, in deinem Array steht aber ein Text.

Wenn du Controls über Arrayelemente beeinflussen willst muß auch die ControlID im Array gespeichert sein. Hier mal ein kleines Beispiel mit Buttons:

C

#include <GUIConstantsEx.au3>
#include <Array.au3>


Opt('MustDeclareVars', 1)
Global $aBtnIds[10][3]
$aBtnIds[0][2] = "0101"
$aBtnIds[1][2] = "0100"
$aBtnIds[2][2] = "0110"
$aBtnIds[3][2] = "1100"
$aBtnIds[4][2] = "1100"
$aBtnIds[5][2] = "1100"
$aBtnIds[6][2] = "1100"
$aBtnIds[7][2] = "1100"
$aBtnIds[8][2] = "1100"
$aBtnIds[9][2] = "_Farben"




Global $hGui = GUICreate('Buttontest', 105, 145)
Global $msg, $Text


For $iTop = 0 To 2
	For $iLeft = 0 To 2
		$Text=$iTop * 3 + $iLeft + 1
		$aBtnIds[$Text-1][0] = GUICtrlCreateButton($Text, 10 + $iLeft * 30, 10 + $iTop * 30, 25, 25)
		;$aBtnIds[$Text-1][0] enthält jetzt die ID
		ConsoleWrite($Text & ': ' & $aBtnIds[$Text-1][0] & @CRLF)
		GUICtrlSetBkColor(-1, 0x990000)
		$aBtnIds[$Text-1][1] = False
	Next
Next
$aBtnIds[9][0] = GUICtrlCreateButton('OK', 10, 110, 90, 25)
GUISetState()


While 1
	$msg = GUIGetMsg()
	Switch $msg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $aBtnIds[0][0] To $aBtnIds[8][0]
			_Click($msg - $aBtnIds[0][0], True)
		Case $aBtnIds[9][0]
			;_Click($msg - $aBtnIds[0][0])
			Call($aBtnIds[9][2]) ;ruft die hinterlegte Func auf
	EndSwitch
WEnd


Func _Click($iBtn, $bColorToggle = False)
	If $bColorToggle Then
		If $aBtnIds[$iBtn][1] Then
			GUICtrlSetBkColor($aBtnIds[$iBtn][0], 0x990000)
		Else
			GUICtrlSetBkColor($aBtnIds[$iBtn][0], 0x059122)
		EndIf
		$aBtnIds[$iBtn][1] = Not $aBtnIds[$iBtn][1]
	EndIf
	MsgBox(0, 'Buttonclick', 'Button with ID ' & $aBtnIds[$iBtn][0] & ' was clicked.' & @CRLF & 'The text of the button is: ' & ControlGetText('Buttontest', '', $aBtnIds[$iBtn][0]) & @CRLF & 'Data: ' & $aBtnIds[$iBtn][2] & @CRLF & 'True/False: ' & $aBtnIds[$iBtn][1], 5, $hGui)
EndFunc   ;==>_Click


Func _Farben()
	Local $sText = '', $aBtns
	For $i = 0 To 8
		$sText &= $aBtnIds[$i][1]
		If $i < 8 Then $sText &= '|'
	Next
	$sText = StringReplace($sText, 'True', 'Grün')
	$sText = StringReplace($sText, 'False', 'Rot')
	ConsoleWrite($sText & @CRLF)
	$aBtns = StringSplit($sText, '|')
	$aBtns[0] = UBound($aBtns) - 1
	_ArrayDisplay($aBtns, 'Farben', '', 32)
EndFunc   ;==>_Farben

Alles anzeigen

mm4040

Hey , Danke - gelesen habe ich das schon mit der ControlID, aber ich habe nicht verstanden, warum es dann wenn ich den Checkboxnamen als Text in die Anweisung schreibe funktioniert.? Ich nehme aus dem Array doch auch nur den Text. ?? Hmm - ist halt so.
Trotzdem Danke

**Bitnugger**

AutoIt

Dim $aBefehl[2][2]=[  _
['test1', $Label1], _
['test2', $Label2]]
_ArrayDisplay($aBefehl)
GUICtrlSetState($aBefehl[0][1],$GUI_CHECKED)

So funktioniert es, da nun nicht der Name der Variable als 'Text' im Array gespeichert wird, sondern die benötigte ID des Controls, welches du mit GUICtrlSetState() ansprechen willst.

**autoBert**

Zitat von Bitnugger
AutoIt
Dim $aBefehl[2][2]=[  _
['test1', $Label1], _
['test2', $Label2]]
_ArrayDisplay($aBefehl)
GUICtrlSetState($aBefehl[0][1],$GUI_CHECKED)
So funktioniert es, da nun nicht der Name der Variable als 'Text' im Array gespeichert wird, sondern die benötigte ID des Controls, welches du mit GUICtrlSetState() ansprechen willst.

Dann bist du ein Zauberer, noch kein Control erstellt aber schon dem bisher noch nicht erstellten Control ein Status zuweisen

**Bitnugger**

Nein, zaubern kann ich sicher nicht... leider - ich vertraue jedoch darauf, dass @mm4040 mit den korrigierten Zeilen aus seinem Beispiel in Post #1 etwas anzufangen weiß.