Wert aus xml-Datei auslesen

Baden2016

Ich versuche verzeifelt einen Wert (startDate) aus einer xml datei auszulesen. Vielleicht kann mir jemand helfen

Meine XML-Datei:

XML

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<TaskOrder title="Refresh D101074A">
<TemplateTask labelId="D101074A" template="bad74.xsl">
<data>
    <appointments>
        <appointment>
            <id>14833</id>
            <organisator>Mustermann, Max</organisator>
            <title>Workshop</title>
            <subtitle></subtitle>
            <from>2016-05-23T07:00:00Z</from>
            <startDate>23.05.2016 09:00</startDate>
            <endDate>23.05.2016 17:00</endDate>
            <to>2016-05-23T15:00:00Z</to>
            <attendeeCount>0</attendeeCount>
            <room>
                <id>7353</id>
                <name>Besprechungsraum</name>
            </room>
        </appointment>
    </appointments>
</data>
</TemplateTask>
</TaskOrder>

Alles anzeigen

Mein autoit Skript:

AutoIt

#include <File.au3>
#include <Array.au3>
#include <_XMLDOMWrapper.au3>


$xmlFile = "D:\Program Files (x86)\XXX\XXX\data\XXX\Daten\room.xml"


If FileExists($xmlFile) Then
   $ret = _XMLFileOpen ($xmlFile)
   if $ret =0 then Exit
   $xPath = "//TaskOrder/TemplateTask/data/appointments/appointment/startDate"


   $startDate = _XMLGetValue($xPath)




   MsgBox(0, "test", $startDate & " " & @error & " " & @extended)
Else
    MsgBox(0, "Fehler", $wert)
EndIf

Alles anzeigen

Ich bekomme leider immer einen leeren Wert zurück.
Im Voraus danke für eure Hilfe

n00b-it

Versuche es doch mit den String-Funktionen

Gesendet von meinem SM-G920F mit Tapatalk

Edit:
Schnell mal das Gerät gewechselt.
So sollte es funktionieren

AutoIt

#Region    ;************ Includes ************
#Include <String.au3>
#Include <Array.au3>
#EndRegion ;************ Includes ************


$hFile = FileOpen("test.xml")
$aFileContent = FileReadToArray($hFile)


For $i = 0 To UBound($aFileContent) - 1
	$aStartDate = _StringBetween($aFileContent[$i], '<startDate>', '</startDate>')
	_ArrayDisplay($aStartDate)
Next


FileClose($hFile)

Alles anzeigen

**Bitnugger**

_XMLGetValue() liefert dir bei Erfolg als Ergebnis ein Array und die Variable $wert wurde nicht dekalriert!

Dein Script müsste ergo so aussehen...

AutoIt

#include <Array.au3>
#include <File.au3>
#include <_XMLDOMWrapper.au3>


Local $xmlFile = "D:\Program Files (x86)\XXX\XXX\data\XXX\Daten\room.xml"


If Not FileExists($xmlFile) Then
	MsgBox(262160, "_XMLGetValue", "Ops, konnte 'room.xml' nicht finden!", 10)
	Exit 1
EndIf


Local $hXML = _XMLFileOpen($xmlFile)
If $hXML = 0 Then
	MsgBox(262160, "_XMLGetValue", "Ops, konnte 'room.xml' nicht öffnen!", 10)
	Exit 2
EndIf


Local $xPath = "/TaskOrder/TemplateTask/data/appointments/appointment/startDate"
Local $aStartDate = _XMLGetValue($xPath)
If @error Then
	MsgBox(262160, "_XMLGetValue", "_XMLGetValue konnte den gesuchten Wert nicht finden! " & @error & " " & @extended)
	Exit 3
Else
	ConsoleWrite('$aStartDate[1] : '  & $aStartDate[1] & @CRLF)
	_ArrayDisplay($aStartDate, "$aStartDate")
EndIf

Alles anzeigen