3CXPhone Verfügbarkeits-Status beim Windows-Login und -Logout setzen

Clibo

3CX ist eine tolle digitale Telefonanlage für VoIP, leider etwas sehr "Amercian Style", einige sinnvolle Funktionen fehlen, so kann man den Verfügbarkeits-Status aller Anschlüsse über die Öffnungszeiten steuern, was bei uns allerdings überhaupt nicht sinnvoll ist, da jeder ganz unterschiedliche arbeitet. Besser wäre es über das Windows-Login resp. Logout. Das Login haben wir hinbekommen inkl. Abwarten auf den Start von 3CXPhone (siehe Skript), beim Logout gibt es aber ein Problem: einen vom User indivuell gesetzten Verfügbarkeitsstatus sollte nicht überschrieben werden, aber über das das Kommandozeilentool "CallTriggerCmd.exe" lässt sich der aktuelle Status nicht abfragen, zumindest gemäss der Hilfe.

Hat jemand dafür eine Lösung?

Vielen Dank & Grüsse, Clibo

**chip**

Kenn die Anlage nicht, daher die Frage wo wird denn das Verfügbarkeitsstatus eingegeben?

**Bitnugger**

Bei einer derart erschlagenden Menge an Informationen, die du mit deiner Frage hier anbietest, drängt sich einem doch beinahe der Verdacht auf, dass du gar keine Antwort haben willst...

Hier ein paar Korrekturen und Hinweise für dich... teste das Script mal.

Spoiler anzeigen

AutoIt

;-- TIME_STAMP   2016-05-23 18:07:26


; Während 2min wird geprüft ob 3CXPhone gestartet ist, falls ja wird der Status auf "Verfügbar" gesetzt.
; Leider ist der Wert für Status "Verfügbar" nicht bei allen Usern der gleiche, sodass dieser erst aus
; den verfügbaren Profile ermittelt werden muss.


#include <AutoItConstants.au3>
#include <StringConstants.au3>
#include <MsgBoxConstants.au3> ; wird nur zum Testen gebraucht


_ThreeCXSetAvailable()


Func _ThreeCXSetAvailable()
	Local $sEnvVar = EnvGet("PROGRAMDATA")
	Local $sFilePath = $sEnvVar & '\3CXPhone for Windows\PhoneApp\CallTriggerCmd.exe' ; einfache Hochkomma, die doppelten braucht es für den Command-Aufruf
	Local $sArguments = ' --set-active-profile=' ; die Status-Nr. wird erst unter ermittelt
	Local $iPID, $hWnd, $sOutput = "", $value


	If FileExists($sFilePath) = 0 Then Exit 1	; Beim Debuggen immer Exit-Code setzen, damit man nachvollziehen kann, an welcher Stelle das Programm ausgestiegen ist.


	;~~~ WinWait() liefert ein Handle oder 0, keine PID!
	$hWnd = WinWait("3CX", "", 120) ; max. 2min warten bis 3CXPhone beim Windows-Login bereit ist
	If IsHWnd($hWnd) = 0 Then Exit 2


	$iPID = Run('"' & $sFilePath & '"' & " -p", "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD) ; die verfügbaren Stati abfragen
	If @error Then Exit 3


	While 1
		$sOutput &= StdoutRead($iPID) ; StdOut auslesen und Text zusammen fügen
		If @error Then ExitLoop
	WEnd


	;~~~ Testwerte, um zu sehen was die Funktion als Ergebnis liefert...
	ConsoleWrite('Test: $value = ' & _ThreeCXGetValue('3456 Available blablabla...') & @CRLF)
	ConsoleWrite('Test: $value = ' & _ThreeCXGetValue('mirdochegalwieviele... 344443456 Available blablabla...') & @CRLF)


	$value = _ThreeCXGetValue($sOutput)


	MsgBox(BitOR($MB_OK, $MB_ICONINFORMATION), "$value, $sOutput", '--set-active-profile=' & $value & @CRLF & @CRLF & $sOutput)
	Run('"' & $sFilePath & '"' & $sArguments & $value, "", @SW_MINIMIZE) ; CallTriggerCmd.exe mit dem entsprechenden Statuswert aufrufen
	If @error Then Exit 6
EndFunc  ;==>_ThreeCXSetAvailable


Func _ThreeCXGetValue($sOutput)
	Local $aSplit, $value
	;~~~ Vor 'Available' steht der gesuchte Zahlenwert - unklar wieviele Digits der Wert aufweist; egal - wir kriegen sie alle! ;-)
	$aSplit = StringSplit($sOutput, 'Available', $STR_ENTIRESPLIT + $STR_NOCOUNT)
	If @error Then Exit 4
	$value = StringReverse(Number(StringReverse(StringStripWS($aSplit[0], $STR_STRIPALL))))


	If StringIsDigit($value) = 1 Then
		Return $value
	Else
		MsgBox(BitOR($MB_SYSTEMMODAL, $MB_OK, $MB_ICONERROR), "", "$value, $sOutput")
		Exit 5
	EndIf
EndFunc  ;==>_ThreeCXGetValue

Alles anzeigen