Ergebnisse in unterschiedlichen Farben darstellen

rollod

Hallo,

ich beschäftige mich seit langem mal wieder mit AutoIt, und bleibe prompt an einer vermeindlich einfachen Stelle hängen.
Ich will die Ergebnisse von Ping Tests Zeilenweise in unterschiedlichen Farben in einer Liste aufführen...

Derzeit ändert sich immer die Farbe aller Zeilen...
Was sagen die Profis? Wie kann ich Einzelne Werte in verschiedenen Farben darstellen?

Viele Grüße!

AutoIt

#include <GUIConstants.au3>
#include <GuiStatusBar.au3>
#include <EditConstants.au3>


HotKeySet("^!a", "MeinExit")


#Region Style 
$uGUI = GUICreate("PingTest", 350, 600, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 300, -1, 0x00000018)
GUISetBkColor(0x00E0FFFF)
GUISetFont(9, 300)
GuiCtrlCreateTab(0, 0, 350, 580)
$info = GUICtrlCreateButton ("?",330,4,18,18)
$StatusBar = _GUICtrlStatusBar_Create($uGUI)
_GUICtrlStatusBar_SetText($StatusBar, "Bereit")
#EndRegion


#Region Menü


$1 = GuiCtrlCreateTabItem("PingTest")
	$10 = GUICtrlCreateButton("Test :", 20, 70, 90, 20)
	$10_input = GUICtrlCreateInput("www.google.de", 120, 70, 200, 20)
	$clear = GUICtrlCreateButton ("leeren", 50,520,60,20)


	GuiCtrlSetState(1, $GUI_CHECKED)
	$InfoFeld = GUICtrlCreateEdit("", 20, 150, 300, 350, $ES_READONLY)




#EndRegion


#Region Betriebsschleife
GUISetState ()
While 1
$msg = GUIGetMsg()
HotKeySet("^!a", "MeinExit")
If $msg = $GUI_EVENT_CLOSE Then MeinExit() 
If $msg = $10 Then M10();Test
If $msg = $clear Then M50();clear
Wend
#EndRegion


Func M10();Test
$10_Wert = GUICtrlRead($10_input)


	If $10_Wert = "" Then
	_GUICtrlStatusBar_SetText($StatusBar, "Fehler: Kein Wert angegeben!")
	return false
	EndIf


Global $ping = Ping($10_Wert, 250)	


If $ping Then
   GUICtrlSetData($InfoFeld, GUICtrlSetColor(-1, 0x02BD0C) & "Verbindung OK" & @CRLF, 1)
   _GUICtrlStatusBar_SetText($StatusBar, "OK")
Else
   GUICtrlSetData($InfoFeld,GUICtrlSetColor(-1, 0xff0000) & "Verbindungs Fehler" & @CRLF, 1)
   _GUICtrlStatusBar_SetText($StatusBar, "Fehler")
EndIf	
return 1
EndFunc


Func M50();Clear
GUICtrlSetData($InfoFeld, "")
_GUICtrlStatusBar_SetText($StatusBar, "Bereit")
EndFunc


Func MeinExit()
Exit
EndFunc

Alles anzeigen

**Bitnugger**

Dazu fallen mir spontan zwei Lösungen ein...

1.) du benutzt anstelle eines einfachen Edit-Controls ein RichEdit-Control.

2.) du benutzt ein Listview und fängst die Message $NM_CUSTOMDRAW ab.
Unterschiedliche-Textfarben-innerhalb-einer-ListView

**autoBert**

zum 2, Lösungsvorschlag ein Beispiel:

AutoIt

;https://autoit.de/index.php/Thread/38907-Tool-f%C3%BCr-Serverstatus/?postID=311257#post311257
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <GuiMenu.au3>
#include <array.au3>


Global $eON, $eOFF


Dim $aNames[20][2]
$aNames[0][0] = "Jürgen"
$aNames[1][0] = "Peter"
$aNames[2][0] = "Bert"
$aNames[3][0] = "Christina"
$aNames[4][0] = "Alex"
$aNames[5][0] = "Astrid"
$aNames[6][0] = "Roberto"
$aNames[7][0] = "Heinz"
$aNames[8][0] = "Iwan"
$aNames[9][0] = "Robertina"
$aNames[10][0] = "Hans"
$aNames[11][0] = "Peter II."
$aNames[12][0] = "Tina"
$aNames[13][0] = "Michael"
$aNames[14][0] = "Gunnar"
$aNames[15][0] = "Kurt"
$aNames[16][0] = "Gerald"
$aNames[17][0] = "Alfred"
$aNames[18][0] = "Stefanie"
$aNames[19][0] = "Nicole"
Dim $aItems[20]


$hGUI=GUICreate("", 220, 400)
$listview = GUICtrlCreateListView("Name|Status", 10, 10, 210, 350)
$hLV=GUICtrlGetHandle($listview)
For $i = 0 To 19
	$aItems[$i] = GUICtrlCreateListViewItem($aNames[$i][0] & "|Offline", $listview)
Next
_GUICtrlListView_SetColumnWidth($listview, 0, 140)
_GUICtrlListView_SetColumnWidth($listview, 1, 40) ;0 = unsichtbar
_GUICtrlListView_RegisterSortCallBack($listview)


_RandomOnOff()
 GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
  GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")


GUISetState(@SW_SHOW)


Global $aCMnuItems[1]
;GUICtrlSetColor(-1, 0x22C21F)
;GUICtrlSetColor(-1, 0xAA0000)


While 1
	$msg = GUIGetMsg()
	Switch $msg
		Case $GUI_EVENT_CLOSE
			_GUICtrlListView_UnRegisterSortCallBack($listview)
			Exit
		Case $listview
			_GUICtrlListView_SortItems($ListView, GUICtrlGetState($ListView))
			#cs
		Case $idCMnuLV
			For $i = $aCMnuItems[0] to 1  Step -1
				GUICtrlDelete($aCMnuItems[$i])
				;_ArrayDelete($aCMnuItems)
			Next
			$aItemSel=_GUICtrlListView_GetSelectedIndices($listview,True)
			If $aItemSel[0]>0 Then
				$bEnabled=(_GUICtrlListView_GetItemText($listview,$aItemSel[1],1)='On')
			Else
				$bEnabled=False
			EndIf
			If $bEnabled Then
				GUICtrlSetState($idSendMsg,$Gui_ENABLE)
			Else
				GUICtrlSetState($idSendMsg,$Gui_DISABLE)
			EndIf
			#ce
	EndSwitch
WEnd


Func _RandomOnOff()
	_GUICtrlListView_BeginUpdate($listview)
	For $i = 0 To 19
		If Random(1, 3, 1) = 1 Then
			$aNames[$i][1] = "Off"
		Else
			$aNames[$i][1] = "On"
		EndIf
	Next
	For $i = 0 To 19
		$iItem = _GUICtrlListView_FindText($listview, $aNames[$i][0], -1, False, True)
		If $aNames[$i][1] = "Off" Then
			GUICtrlSetData($aItems[$iItem], "|Off")
			GUICtrlSetBkColor($aItems[$iItem], 0xAA0000)
		Else
			GUICtrlSetData($aItems[$iItem], "|On")
			GUICtrlSetBkColor($aItems[$iItem], 0x22C21F)
		EndIf
	Next
	If GUICtrlGetState($ListView) = 1 Then
		_GUICtrlListView_SortItems($listview, 0)
		_GUICtrlListView_SortItems($listview, 1)
	EndIf
	_GUICtrlListView_EndUpdate($listview)
	AdlibRegister("_RandomOnOff", Random(5000, 10000, 1))
EndFunc   ;==>_RandomOnOff


Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
  #forceref $hWnd, $iMsg, $lParam
  Switch _WinAPI_LoWord($wParam)
    Case $eOn
      MsgBox( 0, "Item", "On" )
    Case $eOff
      MsgBox( 0, "Item", "Off" )
  EndSwitch
  Return $GUI_RUNDEFMSG
EndFunc


Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
  #forceref $hWnd, $iMsg, $wParam
  Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
  Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
  Local $iCode = DllStructGetData($tNMHDR, "Code")
  Switch $hWndFrom
    Case $hLV
      Switch $iCode
        Case $NM_RCLICK
          Local $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
          Local $iItem = DllStructGetData($tInfo, "Index")
          If $iItem > -1 Then
            Local $hMenu = _GUICtrlMenu_CreatePopup(), $bOn = Mod( $iItem, 2 ) = 0
            _GUICtrlMenu_InsertMenuItem( $hMenu, 0, "On", $eOn )
            _GUICtrlMenu_SetItemEnabled( $hMenu, 0, $bOn )
            _GUICtrlMenu_InsertMenuItem( $hMenu, 1, "Off", $eOff )
            _GUICtrlMenu_SetItemEnabled( $hMenu, 1, Not $bOn )
            _GUICtrlMenu_TrackPopupMenu( $hMenu, $hGUI )
            _GUICtrlMenu_DestroyMenu( $hMenu )
          EndIf
      EndSwitch
  EndSwitch
  Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

ist zwar nur eine Simulation, sollte dich aber auf eine Idee bringen