Listview - Abfrage mit Tastatur

Falke

Hallo Community,

ich bin schon seit längerem mit AutoIt aktiv, und programmiere damit sehr gerne.

Ich habe jetzt aber ein Problem für das ich auch im Forum nichts passendes gefunden habe.

Hier mein Testscript.

C

#Region - Timestamp
; 21.07.2016 20:10:30
#EndRegion


#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Compile_Both=y
#AutoIt3Wrapper_UseX64=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <WindowsConstants.au3>
#include <PrgInfo_UDF.au3>
#include <GuiStatusBar.au3>
#include <GuiListView.au3>
#include <GuiComboBox.au3>


Opt("GUIOnEventMode", 1)


#Region ### START Koda GUI section ### Form=X:\Dropbox\AutoIT\Picture Manager\TestForum.kxf
Global $hGui = GUICreate("hGui", 603, 401, -1, -1)
Global $hInp = GUICtrlCreateInput("", 8, 16, 273, 21)
Global $hLv = GUICtrlCreateListView("Titel|Status", 304, 16, 281, 369)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 100)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 50)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


GUIRegisterMsg($WM_NOTIFY, "LV_NOTIFY")
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")


_GUICtrlListView_AddItem($hLv, "Titel 1", 0)
_GUICtrlListView_AddSubItem($hLv, 0, "OK", 1)
_GUICtrlListView_AddItem($hLv, "Titel 2", 1)
_GUICtrlListView_AddSubItem($hLv, 1, "Fehler", 1)
_GUICtrlListView_AddItem($hLv, "Titel 3", 2)
_GUICtrlListView_AddSubItem($hLv, 2, "OK", 1)
_GUICtrlListView_AddItem($hLv, "Titel 4", 3)
_GUICtrlListView_AddSubItem($hLv, 3, "OK", 1)
_GUICtrlListView_AddItem($hLv, "Titel 5", 4)
_GUICtrlListView_AddSubItem($hLv, 4, "OK", 1)


While 1
	Sleep(100)
WEnd


Func _Exit()
	GUIDelete()
	Exit
EndFunc   ;==>_Exit


Func LV_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg, $wParam
	Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
	$hWndListView = GUICtrlGetHandle($hLv)
	If Not IsHWnd(GUICtrlGetHandle($hLv)) Then $hWndListView = GUICtrlGetHandle(GUICtrlGetHandle($hLv))
	$tNMHDR = DllStructCreate($tagNMHDR, $lParam)
	$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
	$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
	$iCode = DllStructGetData($tNMHDR, "Code")
	Switch $hWndFrom
		Case GUICtrlGetHandle($hLv)
			Switch $iCode
				Case $NM_CLICK
					GUICtrlSetData($hInp, _GUICtrlListView_GetItemText($hLv, Int(_GUICtrlListView_GetSelectedIndices($hLv))))
				Case $LVN_KEYDOWN
					$tInfo = DllStructCreate($tagNMLVKEYDOWN, $lParam)
					Switch DllStructGetData($tInfo, "VKey")
						Case 38; Hoch
							_GUICtrlListView_ClickItem($hLv, Int(_GUICtrlListView_GetSelectedIndices($hLv)) - 1)
						Case 40; Runter
							_GUICtrlListView_ClickItem($hLv, Int(_GUICtrlListView_GetSelectedIndices($hLv)) + 1)
						Case 35; End
							_GUICtrlListView_ClickItem($hLv, _GUICtrlListView_GetItemCount($hLv) - 1)
						case 36; Home
							_GUICtrlListView_ClickItem($hLv, 0)
					EndSwitch
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Das ganze funktioniert einwandfrei, solange ich es unter 32bit (#AutoIt3Wrapper_UseX64=n) laufen lasse. Kompiliere ich es aber im 64bit (#AutoIt3Wrapper_UseX64=y) Modus erkennt er die Tasten nicht mehr.

Ich hoffe ihr könnt mir weiterhelfen.

Gruß Falke

**autoBert**

Läuft bei mir auch als 64bit EXE. AutoIt 3.3.14.2 und Win 10 x64.Welches OS u. AutoItversion benutzt du.
Übrigens du benutzt PrgInfo_UDF.au3, diese muste ich auskommentieren. Kannst du sie bitte dem Eröffnungspost anhängen.

Falke

Hallo autoBert,

ich benutze das gleiche Betriebssystem und die gleiche AutoItversion wie du. Die PrgInfo_UDF ist nur ein überbleibsel von meiner copy-paste aktion. Diese UDF stellt lediglich einen Info/About Splashscreen für mich zur verfügung, und hat für diese Demo keine Relevanz. Ich habe sie trotzdem mal angehängt...

Gruß Falke

bazii

Hallo,

ich kann die Erscheinung mit dem Threadsteller teilen, dass mit der produzierten 64bit.exe keine Ausgabe im linken Textfeld erfolgt.

Also wenn ich mit der 32Bit.exe mit der Maus hoch und runterklicke, nach dem ich einmal auf die rechtsseitig stehenden Werte geklickt habe, werden die dort stehenden Werte richtig im linksseitig stehenden Textfeld angezeigt. Dies erfolgte bei mir unter Win10x64 Hostsystem mit der 64.bit.exe auch nicht. Das Textfeld bleibt nach Betätigung der "nach unten" oder der "nach oben" Taste leer. Das kommt im ersten Posting vielleicht nicht ganz rüber, daher benenne ich das jetzt mal mit meinen Worten.

Nachtrag: Falls ich das nun falsch benannt habe muss ich autoBert zustimmen. Denn die Funktionalität der hoch und runter Taste ist gegeben.

**autoBert**

Ich habe nur auf die Funktionalität der Tasten geachtet, diese ist bei mir bei bei 32- und 64-Bit compilaten gegeben. Allerdings jetzt, da Bazii mich darauf aufmerksam gemacht hat, das Textfeld wird bei mir im 64-Bit Compilat auch nicht upgedatet.

**Oscar**

Das scheint ein Bug in AutoIt zu sein!
Wenn man sich die Definition von "$tagNMLVKEYDOWN" mal anschaut, dann steht da am Anfang "align 1;".
Laut MSDN ist das aber nicht korrekt.
Und wenn man die Definition dann mal ohne das "align 1;" macht, dann funktioniert das Script auch im x64-Modus.

Edit: ~~Was ist denn mit dem Editor los? Man kann gar keinen AutoIt-Code mehr einfügen.~~ Habe das Script jetzt als Anhang eingefügt.

Edit2: Alles zurück! Geht jetzt doch wieder! Lag bei mir an Firefox! Habe ihn gerade mal neugestartet.

AutoIt

#Region - Timestamp
; 21.07.2016 20:10:30
#EndRegion - Timestamp


#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Compile_Both=y
#AutoIt3Wrapper_UseX64=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <WindowsConstants.au3>
;~ #include <PrgInfo_UDF.au3>
#include <GuiStatusBar.au3>
#include <GuiListView.au3>
#include <GuiComboBox.au3>


Opt("GUIOnEventMode", 1)


Global Const $tagNMLVKEYDOWN_debug = $tagNMHDR & ";word VKey;uint Flags"


#Region ### START Koda GUI section ### Form=X:\Dropbox\AutoIT\Picture Manager\TestForum.kxf
Global $hGui = GUICreate("hGui", 603, 401, -1, -1)
Global $hInp = GUICtrlCreateInput("", 8, 16, 273, 21)
Global $hLv = GUICtrlCreateListView("Titel|Status", 304, 16, 281, 369)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 100)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 50)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


GUIRegisterMsg($WM_NOTIFY, "LV_NOTIFY")
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")


_GUICtrlListView_AddItem($hLv, "Titel 1", 0)
_GUICtrlListView_AddSubItem($hLv, 0, "OK", 1)
_GUICtrlListView_AddItem($hLv, "Titel 2", 1)
_GUICtrlListView_AddSubItem($hLv, 1, "Fehler", 1)
_GUICtrlListView_AddItem($hLv, "Titel 3", 2)
_GUICtrlListView_AddSubItem($hLv, 2, "OK", 1)
_GUICtrlListView_AddItem($hLv, "Titel 4", 3)
_GUICtrlListView_AddSubItem($hLv, 3, "OK", 1)
_GUICtrlListView_AddItem($hLv, "Titel 5", 4)
_GUICtrlListView_AddSubItem($hLv, 4, "OK", 1)


While 1
	Sleep(100)
WEnd


Func _Exit()
	GUIDelete()
	Exit
EndFunc   ;==>_Exit


Func LV_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg, $wParam
	Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
	$hWndListView = GUICtrlGetHandle($hLv)
	If Not IsHWnd(GUICtrlGetHandle($hLv)) Then $hWndListView = GUICtrlGetHandle(GUICtrlGetHandle($hLv))
	$tNMHDR = DllStructCreate($tagNMHDR, $lParam)
	$hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
	$iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
	$iCode = DllStructGetData($tNMHDR, "Code")
	Switch $hWndFrom
		Case GUICtrlGetHandle($hLv)
			Switch $iCode
				Case $NM_CLICK
					GUICtrlSetData($hInp, _GUICtrlListView_GetItemText($hLv, Int(_GUICtrlListView_GetSelectedIndices($hLv))))
				Case $LVN_KEYDOWN
					$tInfo = DllStructCreate($tagNMLVKEYDOWN_debug, $lParam)
					ConsoleWrite(DllStructGetData($tInfo, "VKey") & @CR)
					Switch DllStructGetData($tInfo, "VKey")
						Case 38; Hoch
							_GUICtrlListView_ClickItem($hLv, Int(_GUICtrlListView_GetSelectedIndices($hLv)) - 1)
						Case 40; Runter
							_GUICtrlListView_ClickItem($hLv, Int(_GUICtrlListView_GetSelectedIndices($hLv)) + 1)
						Case 35; End
							_GUICtrlListView_ClickItem($hLv, _GUICtrlListView_GetItemCount($hLv) - 1)
						Case 36; Home
							_GUICtrlListView_ClickItem($hLv, 0)
					EndSwitch
			EndSwitch
	EndSwitch
	Return $GUI_RUNDEFMSG
EndFunc   ;==>LV_NOTIFY

Alles anzeigen

Falke

Hallo Oscar,

so kenne ich dich aus verschiedenen Threads
Danke euch allen für die Hilfe. Danke Oscar für die Lösung.

Gruß Falke