Timer und Knopfdrücke gleichzeitig

LaMagnos

Hallo,

Ich möchte das ein timer die Zeit hochzählt bis ich oft genug auf ein Knopf gedrückt habe.
Außerdem das angezeigt wird wie oft ich den Knopf bereits gedrückt habe.

Das Problem ist das ich es zwar hinbekomme ein Timer zu erstellen der im Sekunden Takt zählt, aber dabei ein knopf zu drücken ist unmöglich weil sich das Program scheinbar immer noch in der "While" schleife aufhält.

AutoIt

func timerstarten()
global $timer = 0


;Hier dann irgendwie noch ne Knopfdruck rein der dann im "Label" angezeigt wird;
   While $timer < 3


	   $timer = $timer + 1
	   Sleep (1000)
	   GUICtrlSetData($Anzeige, $timer)
   WEnd




EndFunc

Alles anzeigen

Ich denke mir mal ich darf keine "While" Schleife benutzen ?

Schlaue Köpfe und kenner können mir bei einer so einfachen Frage bestimmt helfen oder ?

PS: Wer Schreibfehler findet darf sie behalten

**BugFix**

Zitat von LaMagnos

Ich möchte das ein timer die Zeit hochzählt bis ich oft genug auf ein Knopf gedrückt habe.
Außerdem das angezeigt wird wie oft ich den Knopf bereits gedrückt habe.

Ich verstehe nur Bahnhof...
Stell bitte ein zumindest rudimentär funktionsfähiges Skript ein, das erklärt, was du vorhast. Aus deiner Beschreibung wird das nicht ersichtlich.
Und Sleep unterbricht dein Programm, ist also für einen Timer ungeeignet, dazu gibt es TimerInit/TimerDiff.
Eine Schleife innerhalb einer Funktion ist nur dann sinnvoll, wenn dort eine definierte Anzahl von Ereignissen abgearbeitet wird. Da in deiner Schleife aber nichts passiert ausser: <Programm Stop> - <Zähler hoch> - <Programm Stop> - <Zähler hoch> ... kannst du auch keine anderen Ereignisse berücksichtigen.

**Kanashius**

Normalerweise wird der Timer in die Hauptschleife integriert.
Dort wird dann eine bool-variable geprüft (true/false). In der Funktion zum Starten wird dann diese Variable auf true gesetzt und ab dann wird der Timer abgearbeitet.

Beispielscript:

AutoIt

#include <Date.au3>
global $clicks=0,$clickerActive=false,$neededClicksToStop=5,$clickTimer
global $width=150,$height=100
$hGui=GUICreate("Fenster",$width,$height)
$LabelClicks=GUICtrlCreateLabel("Click Counter: 0",5,5,$width-10)
$ButtonClick=GUICtrlCreateButton("Start",5,35,$width-10)
$LabelTimer=GUICtrlCreateLabel("00:00:00",5,70,$width-10)


GUISetState()


while 1
	$msg=GUIGetMsg()
	Switch $msg
		Case $ButtonClick
			if NOT $clickerActive then
				;Starten des Timers
				GUICtrlSetData($ButtonClick,"Click")
				GUICtrlSetData($LabelClicks,"Click Counter: 0")
				$clickerActive=true
				$clickTimer=TimerInit()
			else
				;Erhöhen der Klicks
				$clicks+=1
				GUICtrlSetData($LabelClicks,"Click Counter: "&$clicks)
				;Ende des Timers
				if $clicks>=$neededClicksToStop then
					$clicks=0
					$clickerActive=false
					GUICtrlSetData($ButtonClick,"Nochmal")
				endif
			endif
		Case -3
			exit
	EndSwitch
	if $clickerActive then
		local $iHours,$iMins,$iSecs
		_TicksToTime(TimerDiff($clickTimer),$iHours,$iMins,$iSecs)
		$time=($iHours<10?"0"&$iHours:$iHours)&":"&($iMins<10?"0"&$iMins:$iMins)&":"&($iSecs<10?"0"&$iSecs:$iSecs)
		if $time<>GUICtrlRead($LabelTimer) then
			GUICtrlSetData($LabelTimer,$time)
		endif
	EndIf
WEnd

Alles anzeigen

Theoretisch kannst du in einer Funktion auch GuiGetMsg aufrufen, du müsstest aber alle Buttons, die während des Timers noch funtionieren sollen, nocheinmal mit Funktionen listen...
wobei man das auch wieder in eine Funktion auslagern kann^^

LaMagnos

Okey sry hab mir schon gedacht das der Text oben unverständlich ist :C

Hier nochmal genau:

ich möchte dass man den Knopf 100 mal drücken muss in einer Vorgegebenen Zeit (5 Sek.), wenn man dann die 100er Marker erreicht hat soll sich eine
Msg Box öffnen die die Zeit anzeigt, wenn man ÜBER die 5 Sekunden war und wenn man unter der Zeit war etwas anderes.
Außerdem soll man im GUI sehen können wie oft man schon gedrückt hat, und wenn man dann "verloren" hat (also über die 5sek. Marke ist) soll es sich
wieder reseten

Ich konnte leider keinen anderen Code schicken, weil der den ich habe wirklich nicht zu gebrauchen ist und nur dazu diente rum zu probieren xD

Aber vielen Dank für die Antworten und das sich hier Leute Zeit nehmen denn ganzen Code einfach so zu schreiben, Danke!

**Andy**

Zitat von LaMagnos

Aber vielen Dank für die Antworten und das sich hier Leute Zeit nehmen denn ganzen Code einfach so zu schreiben, Danke!

Du hast in "Hilfe und Unterstützung" gepostet, damit man dir hilft, und nicht damit man dir den Code komplett schreibt!

SOLLTE GENAU DAS (den Code schreiben) jemand tun, kann er/sie sich auf etwas gefasst machen!