Explorer öffnen und verschieben.

**Tweaky**

Hi,
ich würde gerne den Explorer öffnen und diesen dann in der Größe verändern.
Eigentlich kein Problem.

Run gibt ja eine PID zurück.
Allerdings brauche ich für WinMove ein Handle.
Ist es irgendwie möglich aus der PID das Handle zu erzeugen?

Oder muss ich über den Titel gehen?

Danke

**Kanashius**

Mit ner Schleife durch WinList laufen und mit WinGetProcess gucken, ob die PID übereinstimmt. (Können auch mehrere sein)

**Tweaky**

Irgendwie klappt es nicht.
Habe ich da einen Denkfehler?

AutoIt

#Region ;************ Includes ************
#include <Array.au3>
#EndRegion ;************ Includes ************


$sExplorer_a = Run("explorer.exe /N,/E," & "C:\", "", @SW_MAXIMIZE)
$sExplorer_b = Run("explorer.exe /N,/E," & "D:\", "", @SW_MAXIMIZE)


ConsoleWrite($sExplorer_a & @CRLF)
ConsoleWrite($sExplorer_b & @CRLF & @CRLF)
Sleep(1000)


Local $aList = WinList("[REGEXPCLASS:^(Explore|Cabinet)WClass$]")


_ArrayDisplay($aList)


For $i = 1 To $aList[0][0]
	$sPID = WinGetProcess($aList[$i][1])
	ConsoleWrite($sPID & @TAB & $aList[$i][0] & @TAB & $aList[$i][1] & @CRLF)


	If $sPID = $sExplorer_a Or $sPID = $sExplorer_b Then
		MsgBox(0, 0, 0)
		WinMove($aList[$i][1], "", 50, 30)
	EndIf
Next

Alles anzeigen

**Kanashius**

Das Script ist richtig. Das hängt mit der explorer.exe zusammen. Wenn du notepad öffnest funktioniert es z.B..
Die Fenster hängen sich da an andere Prozesse, nicht an den, den du startest...

**autoBert**

Ich denke es liegt an @SW_MAXIMIZE, das ein verschieben nicht klappt.

**Bitnugger**

_GetNewExplorerWindow

AutoIt

;-- TIME_STAMP   2016-09-14 12:26:25


#Region ;************ Includes ************
#include <Array.au3>
#EndRegion ;************ Includes ************


Local $hWnd_Explorer_a = _GetNewExplorerWindow("explorer.exe /N,/E," & "C:\", "", @SW_MAXIMIZE)
Local $iPID_Explorer_a = @extended
If @error Then Exit 2


Local $hWnd_Explorer_b = _GetNewExplorerWindow("explorer.exe /N,/E," & @MyDocumentsDir, "", @SW_MAXIMIZE)
Local $iPID_Explorer_b = @extended
If @error Then Exit 3


ConsoleWrite(StringFormat('$hWnd_Explorer_a: %s \t $iPID_Explorer_a: %s', $hWnd_Explorer_a, $iPID_Explorer_a) & @CRLF)
ConsoleWrite(StringFormat('$hWnd_Explorer_b: %s \t $iPID_Explorer_b: %s', $hWnd_Explorer_b, $iPID_Explorer_b) & @CRLF)


WinMove($hWnd_Explorer_a, '', 250, 250, 800, 600, 5)
WinMove($hWnd_Explorer_b, '', 450, 350, 800, 600, 10)
Exit


; Befehlszeilenoptionen für Windows-Explorer
; EXPLORER.EXE [/n][/e][,/root,<Objekt>][[,/select],<Unterobjekt>]
; https://support.microsoft.com/de-de/kb/130510
Func _GetNewExplorerWindow($sExplorer, $sWorkingDir = '', $sShow_Flag = Default, $Opt_Flag = '')
	If (IsDeclared('g_aWinList') = $DECLARED_GLOBAL) = False Then Global $g_aWinList
	$g_aWinList = WinList('[CLASS:CabinetWClass]')


	RunWait($sExplorer, $sWorkingDir, $sShow_Flag, $Opt_Flag)
	If @error Then Exit 1


	Local $__aWinList = $g_aWinList
	$g_aWinList = WinList('[CLASS:CabinetWClass]')
	If $g_aWinList[0][0] = 0 Or $g_aWinList[0][0] < $__aWinList[0][0] Then Return SetError(1, 0, 0)


	For $i = 1 To $g_aWinList[0][0] Step 1
		If _ArraySearch($__aWinList, $g_aWinList[$i][1], 1, 0, 0, 0, 1, 1) = -1 Then Return SetError(0, WinGetProcess($g_aWinList[$i][1]), $g_aWinList[$i][1])
	Next
EndFunc

Alles anzeigen