WINAPI GetLogicalProcessorInformation

powerbass4

Anfänger

Beiträge

9
11. November 2016 um 19:02
- #1
Hi, ich brauche mal Hilfe von den "C++ Könnern" unter euch....
Die Funktion "WINAPI GetLogicalProcessorInformation" ist leider nicht in den AutoIt Includes zu finden, also wollte ich sie selber basteln; ....leider ohne Erfolg.
Einfache Funktionen konnte ich schon adaptieren, aber diese weicht irgendwie ins Unbekannte ab.
Ich hoffe mir kann jemand helfen.... und dann sollte die Funktion in die Includes rein (WinAPISys.au3).

C

BOOL WINAPI GetLogicalProcessorInformation( _Out_ PSYSTEM_LOGICAL_PROCESSOR_INFORMATION Buffer, _Inout_ PDWORD ReturnLength );

https://msdn.microsoft.com/en-us/library/…4(v=vs.85).aspx

C

typedef struct _SYSTEM_LOGICAL_PROCESSOR_INFORMATION { ULONG_PTR ProcessorMask; LOGICAL_PROCESSOR_RELATIONSHIP Relationship; union { struct { BYTE Flags; } ProcessorCore; struct { DWORD NodeNumber; } NumaNode; CACHE_DESCRIPTOR Cache; ULONGLONG Reserved[2]; }; } SYSTEM_LOGICAL_PROCESSOR_INFORMATION, *PSYSTEM_LOGICAL_PROCESSOR_INFORMATION;
Alles anzeigen

https://msdn.microsoft.com/en-us/library/…4(v=vs.85).aspx
CODe auf dem Bildschirm....
chesstiger

Forenmaskottchen

Beiträge

1.555
11. November 2016 um 22:07
- #2
So, fertig. Müsste so klappen. Zumindest produziert das Beispiel bei mir eine sinnvolle Ausgabe.
Zu erwähnen ist, dass die Funktion a) Quick'n'Dirty umgesetzt ist und b) in der Struct SYSTEM_LOGICAL_PROCESSOR_INFORMATION bei dem Union NumaNode das Byte Flags nur über Umwege lesbar ist (Adresse von NodeNumber holen und Struct mit Byte an selber Stelle erstellen ODER Bit-Operationen mit NodeNumber).
Kannst ja mal rumprobieren, ob das so passt.
[autoit]

#include <Array.au3>
#include <Memory.au3>
[/autoit][autoit][/autoit][autoit]
#cs
BOOL WINAPI GetLogicalProcessorInformation(
_Out_ PSYSTEM_LOGICAL_PROCESSOR_INFORMATION Buffer,
_Inout_ PDWORD ReturnLength
);
[/autoit][autoit][/autoit][autoit]
AUS: Kernel32.dll
#ce
Global Const $RELATIONPROCESSORCORE = 0
[/autoit][autoit][/autoit][autoit]
$atSLPI = GetLogicalProcessorInformation()
$hMem = @extended
$iCores = 0
For $i = 0 To UBound($atSLPI) - 1
If $atSLPI[$i].Relationship = $RELATIONPROCESSORCORE Then
$iCores += 1
EndIf
Next
ConsoleWrite("Detected " & $iCores & " processor cores on your system." & @CRLF)
_MemGlobalFree($hMem) ;Immer dran denken, den Speicher wieder freizugeben!!!
[/autoit][autoit][/autoit][autoit][/autoit][autoit]
Func GetLogicalProcessorInformation()
Local $hDll, $hMem, $tBufferSize, $tBuffer, $tSLPI, $atSLPI, $tagSLPI, $iOffset
$hDll = DllOpen("Kernel32.dll")
$tBufferSize = DllStructCreate("dword size;")
DllCall($hDll, "bool", "GetLogicalProcessorInformation", "struct*", 0, "DWORD_PTR", DllStructGetPtr($tBufferSize, "size"))
[/autoit][autoit][/autoit][autoit]
$hMem = _MemGlobalAlloc($tBufferSize.size, $GPTR) ;Nötig, da sonst nach Verlassen der Funktion der Speicherbereich freigegeben wird...
$tBuffer = DllStructCreate("byte[" & $tBufferSize.size & "]", $hMem)
DllCall($hDll, "bool", "GetLogicalProcessorInformation", "struct*", DllStructGetPtr($tBuffer), "DWORD_PTR", DllStructGetPtr($tBufferSize, "size"))
[/autoit][autoit][/autoit][autoit]
$tagSLPI = "ULONG_PTR ProcessorMask; WORD Relationship; STRUCT; DWORD NodeNumber; ENDSTRUCT; STRUCT; BYTE Level; BYTE Associativity; WORD LineSize; DWORD Size; INT Type; ENDSTRUCT; UINT64 Reserved[2]"
$iOffset = 0
Local $atSLPI[0]
While ($iOffset + 40) < $tBufferSize.size
$tSLPI = DllStructCreate($tagSLPI, DllStructGetPtr($tBuffer) + $iOffset)
_ArrayAdd($atSLPI, $tSLPI)
$iOffset += DllStructGetSize($tSLPI)
WEnd
[/autoit][autoit][/autoit][autoit]
DllClose($hDll)
Return SetExtended($hMem, $atSLPI)
EndFunc
[/autoit]
[Tutorial] Sauber Programmieren
[Tutorial] GDI+ Rundumschlag
[Blockierte Grafik: http://service.sebastian-walter.net/datediff/chess.php]

12. November 2016 um 12:33

#3

Hi,
@chesstiger, gut angefangen, dann stark nachgelassen^^
Du hast die "UNION" nicht in deine Struct verbaut....und auch nicht die Anzahl der Cores aus der Anzahl der gesetzten Bits aus ProcessorMask.
Die Struct ist mitnichten 40Bytes (s. meinen nächsten Post^^), das Ergebnis deiner "Berechnung" entspricht also nicht der Erwartung. Mein AMD-Quadcore wird mit deinem Script mit 7 Cores ausgegeben....

Bei 32bit ist eine "Line" der Struct 24 Bytes (4 Bytes ProcessorMask + 4 Bytes Relationship + 16 Bytes, in denen die UNION residiert)
Bei 64bit ist eine "Line" der Struct 32 Bytes (8 Bytes ProcessorMask + 8 Bytes Relationship + 16 Bytes, in denen die UNION residiert)

~~Mach da mal ne schicke auch für 64Bit gültige Version draus, incl. dem OO-Gedöns zum Abfragen der Struct-Items, das sieht nämlich wenigstens gut aus^^~~ //siehe EDIT unten

AutoIt

#include <Array.au3>
#include <WinAPI.au3>


#AutoIt3Wrapper_UseX64=n


;variablen zuordnen
Enum $RelationProcessorCore, _
        $RelationNumaNode, _
        $RelationCache, _
        $RelationProcessorPackage, _
        $RelationGroup, _
        $RelationAll




Global $processorCoreCount = 0, _
        $logicalProcessorCount = 0, _
        $processorPackageCount = 0, _
        $numaNodeCount = 0, _
        $L1CacheCount = 0, _
        $L2CacheCount = 0, _
        $L3CacheCount = 0, _
        $L1CacheSize = 0, _
        $L2CacheSize = 0, _
        $L3CacheSize = 0








$dll = DllOpen("kernel32.dll")
ConsoleWrite('- Debug(' & @ScriptLineNumber & ') : $dll = ' & $dll & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
ConsoleWrite('- : $dll = ' & $dll & @CRLF)               ;### Debug Console


;adresse holen
$procaddress = DllCall($dll, "ptr", "GetProcAddress", "ptr", _WinAPI_GetModuleHandle("kernel32.dll"), "str", "GetLogicalProcessorInformation")
ConsoleWrite('- : $ret = ' & $procaddress[0] & @CRLF)    ;### Debug Console


;Funktion callen, um buffer größe zu erhalten
$return_length = 0
$ret = DllCallAddress("uint", $procaddress[0], "dword", 0, "uint*", $return_length)
;~ ConsoleWrite('- : $ret = ' & $ret & @CRLF ) ;### Debug Console
$return_length = $ret[2]
;~ ConsoleWrite('- : $return_length = ' & $return_length & @CRLF ) ;### Debug Console
;~ _arraydisplay($ret)




$struct_bytes = DllStructCreate("byte [" & $return_length & "]")
$ptr = DllStructGetPtr($struct_bytes)
;~ ConsoleWrite('- : $ptr = ' & $ptr & @CRLF ) ;### Debug Console




;Funktion callen, um bufferpointer  zu übergeben und buffer zu füllen
$ret = DllCallAddress("uint", $procaddress[0], "ptr", $ptr, "uint*", $return_length)
;~ ConsoleWrite('- : $ret = ' & $ret[0] & @CRLF ) ;### Debug Console
;~ _arraydisplay($ret)


;zeig´s mir baby!!!
$ret = DllStructGetData($struct_bytes, 1)
ConsoleWrite('- : $ret = ' & ($ret) & @CRLF)             ;### Debug Console
For $i = 3 To $return_length * 2 Step 48
    $a = StringMid($ret, $i, 48)
    ConsoleWrite("    " & $a & @CRLF)
Next




ConsoleWrite(@CRLF & @CRLF & "+ Ergebnisse:" & @CRLF & @CRLF)


;zuordnen


For $i = 0 To $return_length - 24 Step 24


    $a = StringMid($ret, 3 + $i * 2, 48)
    ConsoleWrite($a & @CRLF)


;~ ;PLPI = PSYSTEM_LOGICAL_PROCESSOR_INFORMATION
    $struct_PLPI = DllStructCreate("dword ProcessorMask;" & _
            "dword Relationship;" & _
            "byte [16];", $ptr + $i)


    ;die "union" nachbasteln....alle
    $struct_Processorcore = DllStructCreate("byte Flags", DllStructGetPtr($struct_PLPI) + 8)


    $struct_NumaNode = DllStructCreate("dword NodeNumber", DllStructGetPtr($struct_PLPI) + 8)


    $struct_CACHE_DESCRIPTOR = DllStructCreate("byte Level;" & _
            "byte Associativity;" & _
            "word Linesize;" & _
            "dword Size;" & _
            "dword Type", DllStructGetPtr($struct_PLPI) + 8)






;~     $structsize = DllStructGetSize($struct_PLPI)
;~     ConsoleWrite('- : $structsize = ' & $structsize & @CRLF ) ;### Debug Console








    ;Daten auslesen
    $ProcessorMask = DllStructGetData($struct_PLPI, "ProcessorMask")
    ConsoleWrite('> $ProcessorMask = ' & $ProcessorMask & @CRLF)
    $Relationship = DllStructGetData($struct_PLPI, "Relationship")
    ConsoleWrite('> $Relationship  = ' & $Relationship)




    $Relationship = Int(DllStructGetData($struct_PLPI, "Relationship"))


    Switch $Relationship


        Case $RelationProcessorCore                      ;0 es werden Prozessor daten abgefragt
            ConsoleWrite("  ProcessorCore" & @CRLF)
            $ProcessorCore = DllStructGetData($struct_Processorcore, "Flags")
            ConsoleWrite('- : $ProcessorCore = ' & $ProcessorCore & @CRLF) ;### Debug Console


            $processorCoreCount += 1


            $logicalProcessorCount += CountSetBits($ProcessorMask)


        Case $RelationNumaNode
            ConsoleWrite("  NumaNode" & @CRLF)
            $NodeNumber = DllStructGetData($struct_NumaNode, "NodeNumber")
            ConsoleWrite('- : $NodeNumber = ' & $NodeNumber & @CRLF) ;### Debug Console


            $numaNodeCount += 1


        Case $RelationCache
            ConsoleWrite("  RelationCache" & @CRLF)
            $Level = DllStructGetData($struct_CACHE_DESCRIPTOR, "Level")
            ConsoleWrite('- : $Level = ' & $Level & @CRLF) ;### Debug Console
            $Associativity = DllStructGetData($struct_CACHE_DESCRIPTOR, "Associativity")
            ConsoleWrite('- : $Associativity = ' & $Associativity & @CRLF) ;### Debug Console
            $Linesize = DllStructGetData($struct_CACHE_DESCRIPTOR, "Linesize")
            ConsoleWrite('- : $Linesize = ' & $Linesize & @CRLF) ;### Debug Console
            $Size = DllStructGetData($struct_CACHE_DESCRIPTOR, "Size")
            ConsoleWrite('- : $Size = ' & $Size & @CRLF) ;### Debug Console
            $Type = DllStructGetData($struct_CACHE_DESCRIPTOR, "Type")
            ConsoleWrite('- : $Type = ' & $Type & @CRLF) ;### Debug Console


            Switch $Level
                Case 1
                    $L1CacheCount += 1
                    $L1CacheSize += $Size
                Case 2
                    $L2CacheCount += 1
                    $L2CacheSize += $Size
                Case 3
                    $L3CacheCount += 1
                    $L3CacheSize += $Size
            EndSwitch








        Case $RelationProcessorPackage
            ConsoleWrite("  ProcessorPackage" & @CRLF)
            $processorPackageCount += 1


        Case $RelationGroup
            ConsoleWrite("  Group" & @CRLF)






    EndSwitch












    ConsoleWrite(@CRLF & @CRLF)


Next






$returnstring = "GetLogicalProcessorInformation:" & @CRLF & @CRLF & _
        StringFormat("Number %-30s = %u", "Processorcores", $processorCoreCount) & @CRLF & _
        StringFormat("Number %-30s = %u", "NumaNodes", $numaNodeCount) & @CRLF & _
        StringFormat("Number %-30s = %u", "logicalProcessorCount", $logicalProcessorCount) & @CRLF & _
        StringFormat("Number %-30s = %u", "processorPackageCount", $processorPackageCount) & @CRLF & _
        StringFormat("Number %-30s = %u/%u/%u", "Level1/2/3-Caches", $L1CacheCount, $L2CacheCount, $L3CacheCount) & @CRLF & _
        StringFormat("Number %-30s = %u/%u/%u", "L1/L2/L3 cache sizes (kB)", $L1CacheSize / 1024, $L2CacheSize / 1024, $L3CacheSize / 1024) & @CRLF & _
        ""


ConsoleWrite($returnstring & @CRLF)


MsgBox(0, "GetLogicalProcessorInformation", $returnstring)






Func CountSetBits($uint)                                 ;zählt gesetzte bits
    $anz = 0
    For $i = 0 To 31
        If BitAND(2 ^ $i, $uint) Then $anz += 1
    Next
    Return $anz
EndFunc                                                  ;==>CountSetBits

Alles anzeigen

//EDIT bitte auch für 64Bit testen!

AutoIt

#include <Array.au3>
#include <WinAPI.au3>




#AutoIt3Wrapper_UseX64=y		;für 32/64Bit


;variablen zuordnen
Enum $RelationProcessorCore, _
        $RelationNumaNode, _
        $RelationCache, _
        $RelationProcessorPackage, _
        $RelationGroup, _
        $RelationAll




Global $processorCoreCount = 0, _
        $logicalProcessorCount = 0, _
        $processorPackageCount = 0, _
        $numaNodeCount = 0, _
        $L1CacheCount = 0, _
        $L2CacheCount = 0, _
        $L3CacheCount = 0, _
        $L1CacheSize = 0, _
        $L2CacheSize = 0, _
        $L3CacheSize = 0




If @AutoItX64 Then
    $32_64 = 32
	$sSize=16
Else
    $32_64 = 24
	$sSize=8
EndIf






$dll = DllOpen("kernel32.dll")
;~ ConsoleWrite('- Debug(' & @ScriptLineNumber & ') : $dll = ' & $dll & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
;~ ConsoleWrite('- : $dll = ' & $dll & @CRLF)               ;### Debug Console


;adresse holen
$procaddress = DllCall($dll, "ptr", "GetProcAddress", "ptr", _WinAPI_GetModuleHandle("kernel32.dll"), "str", "GetLogicalProcessorInformation")
;~ ConsoleWrite('- : $ret = ' & $procaddress[0] & @CRLF)    ;### Debug Console


;Funktion callen, um buffer größe zu erhalten
$return_length = 0
$ret = DllCallAddress("uint", $procaddress[0], "dword", 0, "uint*", $return_length)
;~ ConsoleWrite('- : $ret = ' & $ret & @CRLF ) ;### Debug Console
$return_length = $ret[2]
;~ ConsoleWrite('- : $return_length = ' & $return_length & @CRLF ) ;### Debug Console
;~ _ArrayDisplay($ret)




$struct_bytes = DllStructCreate("byte [" & $return_length & "]")
$ptr = DllStructGetPtr($struct_bytes)
;~ ConsoleWrite('- : $ptr = ' & $ptr & @CRLF ) ;### Debug Console




;Funktion callen, um bufferpointer  zu übergeben und buffer zu füllen
$ret = DllCallAddress("uint", $procaddress[0], "ptr", $ptr, "uint*", $return_length)
;~ ConsoleWrite('- : $ret = ' & $ret[0] & @CRLF ) ;### Debug Console
;~ _arraydisplay($ret)


;zeig´s mir baby!!!
$ret = DllStructGetData($struct_bytes, 1)
ConsoleWrite('- : $ret = ' & ($ret) & @CRLF)             ;### Debug Console
For $i = 3 To $return_length * 2 Step $32_64*2
    $a = StringMid($ret, $i, $32_64*2)
    ConsoleWrite("    " & $a & @CRLF)
Next




ConsoleWrite(@CRLF & @CRLF & "+ Ergebnisse:" & @CRLF & @CRLF)


;zuordnen


For $i = 0 To $return_length - $32_64 Step $32_64


    $a = StringMid($ret, 3 + $i * 2, $32_64*2)
    ConsoleWrite($a & @CRLF)


;~ ;PLPI = PSYSTEM_LOGICAL_PROCESSOR_INFORMATION
    $struct_PLPI = DllStructCreate("uint_ptr ProcessorMask;" & _
            "uint_ptr Relationship;" & _
            "byte [" & $32_64-16 & "]", $ptr + $i)


    ;die "union" nachbasteln....alle
    $struct_Processorcore = DllStructCreate("byte Flags", DllStructGetPtr($struct_PLPI) + $sSize)


    $struct_NumaNode = DllStructCreate("dword NodeNumber", DllStructGetPtr($struct_PLPI) + $sSize)


    $struct_CACHE_DESCRIPTOR = DllStructCreate("byte Level;" & _
            "byte Associativity;" & _
            "word Linesize;" & _
            "dword Size;" & _
            "dword Type", DllStructGetPtr($struct_PLPI) + $sSize)






;~     $structsize = DllStructGetSize($struct_PLPI)
;~     ConsoleWrite('- : $structsize = ' & $structsize & @CRLF ) ;### Debug Console








    ;Daten auslesen
    $ProcessorMask = DllStructGetData($struct_PLPI, "ProcessorMask")
    ConsoleWrite('> $ProcessorMask = ' & $ProcessorMask & @CRLF)
    $Relationship = DllStructGetData($struct_PLPI, "Relationship")
    ConsoleWrite('> $Relationship  = ' & $Relationship)




    $Relationship = Int(DllStructGetData($struct_PLPI, "Relationship"))


    Switch $Relationship


        Case $RelationProcessorCore                      ;0 es werden Prozessor daten abgefragt
            ConsoleWrite("  ProcessorCore" & @CRLF)
            $ProcessorCore = DllStructGetData($struct_Processorcore, "Flags")
            ConsoleWrite('- : $ProcessorCore = ' & $ProcessorCore & @CRLF) ;### Debug Console


            $processorCoreCount += 1


            $logicalProcessorCount += CountSetBits($ProcessorMask)


        Case $RelationNumaNode
            ConsoleWrite("  NumaNode" & @CRLF)
            $NodeNumber = DllStructGetData($struct_NumaNode, "NodeNumber")
            ConsoleWrite('- : $NodeNumber = ' & $NodeNumber & @CRLF) ;### Debug Console


            $numaNodeCount += 1


        Case $RelationCache
            ConsoleWrite("  RelationCache" & @CRLF)
            $Level = DllStructGetData($struct_CACHE_DESCRIPTOR, "Level")
            ConsoleWrite('- : $Level = ' & $Level & @CRLF) ;### Debug Console
            $Associativity = DllStructGetData($struct_CACHE_DESCRIPTOR, "Associativity")
            ConsoleWrite('- : $Associativity = ' & $Associativity & @CRLF) ;### Debug Console
            $Linesize = DllStructGetData($struct_CACHE_DESCRIPTOR, "Linesize")
            ConsoleWrite('- : $Linesize = ' & $Linesize & @CRLF) ;### Debug Console
            $Size = DllStructGetData($struct_CACHE_DESCRIPTOR, "Size")
            ConsoleWrite('- : $Size = ' & $Size & @CRLF) ;### Debug Console
            $Type = DllStructGetData($struct_CACHE_DESCRIPTOR, "Type")
            ConsoleWrite('- : $Type = ' & $Type & @CRLF) ;### Debug Console


            Switch $Level
                Case 1
                    $L1CacheCount += 1
                    $L1CacheSize += $Size
                Case 2
                    $L2CacheCount += 1
                    $L2CacheSize += $Size
                Case 3
                    $L3CacheCount += 1
                    $L3CacheSize += $Size
            EndSwitch








        Case $RelationProcessorPackage
            ConsoleWrite("  ProcessorPackage" & @CRLF)
            $processorPackageCount += 1


        Case $RelationGroup
            ConsoleWrite("  Group" & @CRLF)






    EndSwitch












    ConsoleWrite(@CRLF & @CRLF)


Next






$returnstring = "GetLogicalProcessorInformation: "&32*(1+@AutoItX64)&"Bit" & @CRLF & @CRLF & _
        StringFormat("Number %-30s = %u", "Processorcores", $processorCoreCount) & @CRLF & _
        StringFormat("Number %-30s = %u", "NumaNodes", $numaNodeCount) & @CRLF & _
        StringFormat("Number %-30s = %u", "logicalProcessorCount", $logicalProcessorCount) & @CRLF & _
        StringFormat("Number %-30s = %u", "processorPackageCount", $processorPackageCount) & @CRLF & _
        StringFormat("Number %-30s = %u/%u/%u", "Level1/2/3-Caches", $L1CacheCount, $L2CacheCount, $L3CacheCount) & @CRLF & _
        StringFormat("Number %-30s = %u/%u/%u", "L1/L2/L3 cache sizes (kB)", $L1CacheSize / 1024, $L2CacheSize / 1024, $L3CacheSize / 1024) & @CRLF & _
        ""


ConsoleWrite($returnstring & @CRLF)


MsgBox(0, "GetLogicalProcessorInformation", $returnstring)






Func CountSetBits($uint)                                 ;zählt gesetzte bits
    $anz = 0
    For $i = 0 To 31
        If BitAND(2 ^ $i, $uint) Then $anz += 1
    Next
    Return $anz
EndFunc                                                  ;==>CountSetBits

Alles anzeigen

powerbass4

Anfänger

Beiträge

9
12. November 2016 um 15:12
- #4
@chesstiger uihhh das ging aber schnell !
@Andy hast das im engl. Forum also gesehen....
Mit meinem Ansatz war ich voll auf dem Holzweg.....

Danke Leute !

evtl. optimiert das noch jemand und legt es den AutoIt Devs vor....
CODe auf dem Bildschirm....
Andy

Märchenonkel

Reaktionen

2

Beiträge

4.291
12. November 2016 um 16:07
- #5
Zitat von powerbass4

Mit meinem Ansatz war ich voll auf dem Holzweg.....

Da ich absolut kein C-Fuzzi bin, habe ich mir entsprechenden Code/Dokumentationen angeschaut und trotzdem nicht durchgeblickt ! <--hat auch nichts gebracht....
Ich habe mir die _SYSTEM_LOGICAL_PROCESSOR_INFORMATION -Struct mit 48 Bytes vorgestellt (anhand des inhaltes des kompletten Speicherbereichs, daher auch die Aufteilung/Visualisierung mittels StringMid() ), allerdings nie begriffen, wie die Einzelteile mit der UNION korrespondieren...nachts um 2 dann ins Bett und geträumt....
Nach 4h Schlaf besinnt man sich auf seine Fähigkeiten:
Was IMMER, und zwar in jeder Programmiersprache funktioniert, ist Debugging!
Also habe ich erst mal versucht, folgenden Code zu compilieren, was aber mit einem Linker-Fehler nicht funktionieren wollte (MinGW):
https://msdn.microsoft.com/de-de/library/…4(v=vs.85).aspx
Da nicht compilierbar, habe ich dann folgendes hingefriemelt:

C

#include <windows.h> #include <malloc.h> #include <stdio.h> #include <tchar.h> typedef enum _LOGICAL_PROCESSOR_RELATIONSHIP { RelationProcessorCore, RelationNumaNode, RelationCache, RelationProcessorPackage, RelationGroup, RelationAll = 0xffff } LOGICAL_PROCESSOR_RELATIONSHIP; typedef enum _PROCESSOR_CACHE_TYPE { CacheUnified, CacheInstruction, CacheData, CacheTrace } PROCESSOR_CACHE_TYPE; typedef struct _CACHE_DESCRIPTOR { BYTE Level; BYTE Associativity; WORD LineSize; DWORD Size; PROCESSOR_CACHE_TYPE Type; } CACHE_DESCRIPTOR; typedef struct _SYSTEM_LOGICAL_PROCESSOR_INFORMATION { ULONG_PTR ProcessorMask; LOGICAL_PROCESSOR_RELATIONSHIP Relationship; union { struct { BYTE Flags; } ProcessorCore; struct { DWORD NodeNumber; } NumaNode; CACHE_DESCRIPTOR Cache; ULONGLONG Reserved[2]; } ; /* anonymous union */ } SYSTEM_LOGICAL_PROCESSOR_INFORMATION; int GET_THE_INFO (void) { ULONG_PTR groesse = 0; groesse = groesse + sizeof (SYSTEM_LOGICAL_PROCESSOR_INFORMATION); // oder _SYSTEM_LOGICAL_PROCESSOR_INFORMATION oder CACHE_DESCRIPTOR um die Größen rauszufinden printf ("\nError %lu\n", GetLastError()); printf("\nSize = %lu\n", (ULONG_PTR) groesse ); return (0); } int main() { GET_THE_INFO(); return 0; }
Alles anzeigen

Nach geschmeidigem Hieb auf F8 (Compile and Execute) hat sich dann herausgestellt, dass die Struct SYSTEM_LOGICAL_PROCESSOR_INFORMATION nur 24Bytes groß war!
Dann fiel es mir wie Schuppen aus den Haaren und alles bekam Sinn:
Jeweils 4 Bytes für ProcessorMask(ulong_ptr) und LOGICAL_PROCESSOR_RELATIONSHIP Relationship (eine Aufzählung, Typ ist UINT(-ptr)) sind zusammen 8 Bytes, der Rest musste die UNION sein.
In der UNION wird der gleiche Speicher mit unterschiedlichen Typen belegt, der größte "zählt", also die beiden ULONGLONG (jeweils 8 = 16 bytes) Reserved[2].
Der Rest war simpel, es wurde jeweils eine Struct "in" der UNION erstellt, mit entsprechenden Typen.
"Alte Hasen" kennen mein Beispiel DllStruct Funktionen für Autoit
Letztendlich sehe ich in diesem Vorgehen keinen großen Sinn, es ist beschissen zu lesen/verstehen und noch beschissener umzusetzen (man sehe sich den C-Code an!)
Ich gehe mal davon aus dass jemand das so gemacht hat "weil er es kann" bzw. weil die Sprache das kann...naja
ciao
Andy

"Schlechtes Benehmen halten die Leute doch nur deswegen für eine Art Vorrecht, weil keiner ihnen aufs Maul haut." Klaus Kinski
"Hint: Write comments after each line. So you can (better) see what your program does and what it not does. And we can see what you're thinking what your program does and we can point to the missunderstandings." A-Jay
Wie man Fragen richtig stellt... Tutorial: Wie man Script-Fehler findet und beseitigt...X-Y-Problem
UEZ

Auch am Arsch geht ein Weg vorbei...

Reaktionen

3

Beiträge

2.540
12. November 2016 um 21:39
- #6
https://www.autoitscript.com/forum/topic/90…i_getsysteminfo
Auch am Arsch geht ein Weg vorbei...
¯\_(ツ)_/¯
Andy

Märchenonkel

Reaktionen

2

Beiträge

4.291
12. November 2016 um 22:00
- #7
@UEZ, in keinem der dort verlinkten Scripte finde ich etwas dazu, außer :

Zitat von Ascend4ent

GetLogicalProcessorInformation should report the right information too, but at the moment I don't know how to interpret it ....

Die sind alle mit anderen Funktionen weitergekommen
ciao
Andy

"Schlechtes Benehmen halten die Leute doch nur deswegen für eine Art Vorrecht, weil keiner ihnen aufs Maul haut." Klaus Kinski
"Hint: Write comments after each line. So you can (better) see what your program does and what it not does. And we can see what you're thinking what your program does and we can point to the missunderstandings." A-Jay
Wie man Fragen richtig stellt... Tutorial: Wie man Script-Fehler findet und beseitigt...X-Y-Problem

In deinem Webbrowser ist JavaScript deaktiviert. Um alle Funktionen dieser Website nutzen zu können, muss JavaScript aktiviert sein.