Hauptform sperren/entsperren

DerSchatten

Ich möchte gerne wenn eine MsgBox geöffnet ist das hauptformular sperren, damit dort nicht hinein geklickt werden kann.Dazu habe ich jetzt mal die Funktion GUISetState(@SW_DISABLE, $Form1) verwendet.
Und unter der MsgBox wieder mit GUISetState(@SW_ENABLE, $Form1) aktiviert.

Code

Case $Menue_System_1 ; 32bit Geräteübersicht
			GUISetState(@SW_DISABLE, $Form1)
			$geraete32 = "Dell Latidude E6330                    " & @CRLF & _ 
			"Dell Latitude E6530" & @CRLF & _ 
			"Lenovo M92 ThinkCentre" & @CRLF & _ 
			"Dell Latitude E7240" & @CRLF & _ 
			"Lenovo ThinkPad T440" & @CRLF & _ 
			"Lenovo ThinkCentre M83" & @CRLF & _ 
			"Lenovo ThinkPad T540p" & @CRLF & _ 
			"Lenovo Thinkpad T450" & @CRLF & _ 
			"HP EliteBook 820 G3" & @CRLF & _ 
			"HP EliteBook 850 G3" & @CRLF & _ 
			"HP 7800 Highend" & @CRLF & _ 
			"HP 7800 Standard" & @CRLF & _ 
			"Acer Veriton M665" & @CRLF & _ 
			"HP DC 8100 CMT" & @CRLF & _ 
			"HP DC 8100 CMT" & @CRLF & _ 
			"Lenovo M91p ThinkCentre" & @CRLF & _ 
			"Lenovo T400" & @CRLF & _ 
			"Lenovo T410" & @CRLF & _ 
			"Dell Latitude E6510" & @CRLF & _ 
			"Dell Latitude E6520" & @CRLF & _ 
			"Dell Latitude E6320" & @CRLF & _ 
			"Dell Latitude E6220" & @CRLF & _ 
			"Acer Veriton S6610G" & @CRLF & _ 
			"Acer Veriton M6610G" & @CRLF & _ 
			"Acer Veriton M6620G" & @CRLF & _ 
			"Virtueller PC"


			MsgBox(0, "32bit Geräteübersicht V1.08.3", $geraete32)
			GUISetState(@SW_ENABLE, $Form1)

Alles anzeigen

Jetzt habe ich allerdings das Problem das mit das HauptGUI im Windows in den Hintergrund springt.
Ich muß es dann erst wieder unten in der Taskleiste anklicken um es anzuzeigen.

Gibt es da eine einfach Möglichkeit das zu verhindern? Oder muß ich das dann wieder umständlich mit Focus in den Vordergrund rücken?

**chip**

Bei mir springt da nichts in den Hintergrund. Bitte poste mal eine lauffähiges Beispiel in dem dein Problem passiert.

DerSchatten

Hier:

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListview.au3>


Global $sHeader = 'Produkt-Bezeichnung|Produkt-ID|Version|Dat.Inst.|Lokation'
Global $aHeader = StringSplit($sHeader, '|')


$Form1 = GUICreate("Installierte Produkte - Windows 7 32bit (Lenovo T450)", 964, 600)


Global $idListView = GUICtrlCreateListView($sHeader, 0, 0, 966, 580)
Global $hListView = GUICtrlGetHandle($idListView)


$Menue_Main = GUICtrlCreateMenu("Gerätetyp/Betriebssystem")
$Menue_Main_1 = GUICtrlCreateMenuItem("Windows 7 32bit (Lenovo T450)", $Menue_Main)
$Menue_Main_2 = GUICtrlCreateMenuItem("Windows 7 64bit (Lenovo T450)", $Menue_Main)
$Menue_Main_3 = GUICtrlCreateMenuItem("Windows 7 32bit (Lenovo T540P)", $Menue_Main)
$Menue_Main_4 = GUICtrlCreateMenuItem("Windows 7 64bit (Lenovo T540P)", $Menue_Main)
$Menue_Main_5 = GUICtrlCreateMenuItem("Windows 7 32bit (Dell E6530)", $Menue_Main)
$Menue_Main_6 = GUICtrlCreateMenuItem("Windows 7 32bit (Lenovo M83)", $Menue_Main)


$Menue_Main = GUICtrlCreateMenu("Übersicht")
$Menue_System_1 = GUICtrlCreateMenuItem("32bit Geräteübersicht", $Menue_Main)
$Menue_System_2 = GUICtrlCreateMenuItem("64bit Geräteübersicht", $Menue_Main)


GUICtrlSetState($Menue_Main_1, $GUI_CHECKED)


$Menue_ListView = GUICtrlCreateContextMenu($idListView)
$Menue_ListView_1 = GUICtrlCreateMenuItem("Kopieren", $Menue_ListView)
Local $aItem


_GUICtrlListView_SetColumnWidth($idListView, 0, 330)
_GUICtrlListView_SetColumnWidth($idListView, 1, 50)
_GUICtrlListView_SetColumnWidth($idListView, 2, 50)
_GUICtrlListView_SetColumnWidth($idListView, 3, 50)
_GUICtrlListView_SetColumnWidth($idListView, 4, 416)


_GUICtrlListView_RegisterSortCallBack($idListView)


GUISetState(@SW_SHOW, $Form1)


Load('t450x86.txt')
_GUICtrlListView_SortItems($idListView, 0)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg


        Case $GUI_EVENT_CLOSE
			_GUICtrlListView_UnRegisterSortCallBack($idListView)
            Exit


		Case $idListView
			_GUICtrlListView_SortItems($idListView, GUICtrlGetState($idListView))


		Case $Menue_ListView_1 ; Auswahl kopieren
			$aItem = _GUICtrlListView_GetItemTextArray($idListview)
			ClipPut($aItem[1] & " (" & $aItem[2] & ")")


		Case $Menue_Main_1 ; Windows 7 32bit (Lenovo T450)
			If BitAND(GUICtrlRead($Menue_Main_1), $GUI_CHECKED) <> $GUI_CHECKED Then
				WinSetTitle($Form1, "", "Installierte Produkte - Windows 7 32bit (Lenovo T450)")
				GUICtrlSetState($Menue_Main_1, $GUI_CHECKED)
				GUICtrlSetState($Menue_Main_2, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_3, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_4, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_5, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_6, $GUI_UNCHECKED)
				Load('t450x86.txt')
				_GUICtrlListView_SortItems($idListView, 0)
			EndIf


		Case $Menue_Main_2 ; Windows 7 64bit (Lenovo T450)
			If BitAND(GUICtrlRead($Menue_Main_2), $GUI_CHECKED) <> $GUI_CHECKED Then
				WinSetTitle($Form1, "", "Installierte Produkte - Windows 7 64bit (Lenovo T450)")
				GUICtrlSetState($Menue_Main_1, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_2, $GUI_CHECKED)
				GUICtrlSetState($Menue_Main_3, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_4, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_5, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_6, $GUI_UNCHECKED)
				Load('t450x64.txt')
				_GUICtrlListView_SortItems($idListView, 0)
			EndIf


		Case $Menue_Main_3 ; Windows 7 32bit (Lenovo T540P)
			If BitAND(GUICtrlRead($Menue_Main_3), $GUI_CHECKED) <> $GUI_CHECKED Then
				WinSetTitle($Form1, "", "Installierte Produkte - Windows 7 32bit (Lenovo T540P)")
				GUICtrlSetState($Menue_Main_1, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_2, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_3, $GUI_CHECKED)
				GUICtrlSetState($Menue_Main_4, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_5, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_6, $GUI_UNCHECKED)
				Load('t540px86.txt')
				_GUICtrlListView_SortItems($idListView, 0)
			EndIf


		Case $Menue_Main_4 ; Windows 7 64bit (Lenovo T540P)
			If BitAND(GUICtrlRead($Menue_Main_4), $GUI_CHECKED) <> $GUI_CHECKED Then
				WinSetTitle($Form1, "", "Installierte Produkte - Windows 7 64bit (Lenovo T540P)")
				GUICtrlSetState($Menue_Main_1, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_2, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_3, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_4, $GUI_CHECKED)
				GUICtrlSetState($Menue_Main_5, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_6, $GUI_UNCHECKED)
				Load('t540px64.txt')
				_GUICtrlListView_SortItems($idListView, 0)
			EndIf


		Case $Menue_Main_5 ; Windows 7 32bit (Dell E6530)
			If BitAND(GUICtrlRead($Menue_Main_5), $GUI_CHECKED) <> $GUI_CHECKED Then
				WinSetTitle($Form1, "", "Installierte Produkte - Windows 7 32bit (Dell E6530)")
				GUICtrlSetState($Menue_Main_1, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_2, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_3, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_4, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_5, $GUI_CHECKED)
				GUICtrlSetState($Menue_Main_6, $GUI_UNCHECKED)
				Load('e6530x86.txt')
				_GUICtrlListView_SortItems($idListView, 0)
			EndIf


		Case $Menue_Main_6 ; Windows 7 32bit (Lenovo M83)
			If BitAND(GUICtrlRead($Menue_Main_6), $GUI_CHECKED) <> $GUI_CHECKED Then
				WinSetTitle($Form1, "", "Installierte Produkte - Windows 7 32bit (Lenovo M83)")
				GUICtrlSetState($Menue_Main_1, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_2, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_3, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_4, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_5, $GUI_UNCHECKED)
				GUICtrlSetState($Menue_Main_6, $GUI_CHECKED)
				Load('m83.txt')
				_GUICtrlListView_SortItems($idListView, 0)
			EndIf


		Case $Menue_System_1 ; 32bit Geräteübersicht
			GUISetState(@SW_DISABLE, $Form1)
			$geraete32 = "Dell Latidude E6330                    " & @CRLF & _ 
			"Dell Latitude E6530" & @CRLF & _ 
			"Lenovo M92 ThinkCentre" & @CRLF & _ 
			"Dell Latitude E7240" & @CRLF & _ 
			"Lenovo ThinkPad T440" & @CRLF & _ 
			"Lenovo ThinkCentre M83" & @CRLF & _ 
			"Lenovo ThinkPad T540p" & @CRLF & _ 
			"Lenovo Thinkpad T450" & @CRLF & _ 
			"HP EliteBook 820 G3" & @CRLF & _ 
			"HP EliteBook 850 G3" & @CRLF & _ 
			"HP 7800 Highend" & @CRLF & _ 
			"HP 7800 Standard" & @CRLF & _ 
			"Acer Veriton M665" & @CRLF & _ 
			"HP DC 8100 CMT" & @CRLF & _ 
			"HP DC 8100 CMT" & @CRLF & _ 
			"Lenovo M91p ThinkCentre" & @CRLF & _ 
			"Lenovo T400" & @CRLF & _ 
			"Lenovo T410" & @CRLF & _ 
			"Dell Latitude E6510" & @CRLF & _ 
			"Dell Latitude E6520" & @CRLF & _ 
			"Dell Latitude E6320" & @CRLF & _ 
			"Dell Latitude E6220" & @CRLF & _ 
			"Acer Veriton S6610G" & @CRLF & _ 
			"Acer Veriton M6610G" & @CRLF & _ 
			"Acer Veriton M6620G" & @CRLF & _ 
			"Virtueller PC"


			MsgBox(0, "32bit Geräteübersicht V1.08.3", $geraete32)
			GUISetState(@SW_ENABLE, $Form1)


		Case $Menue_System_2 ; 64bit Geräteübersicht
			GUISetState(@SW_DISABLE, $Form1)
			$geraete64 = "Lenovo T440                               " & @CRLF & _ 
			"Lenovo M83" & @CRLF & _ 
			"Lenovo T540p" & @CRLF & _ 
			"Lenovo T450" & @CRLF & _ 
			"HP DC 8100 CMT" & @CRLF & _ 
			"Dell Latitude E6510" & @CRLF & _ 
			"Dell Latitude E6520" & @CRLF & _ 
			"Dell Latitude E6320" & @CRLF & _ 
			"Dell Latitude E6220" & @CRLF & _ 
			"Acer Veriton S6610G" & @CRLF & _ 
			"Acer Veriton M6610G" & @CRLF & _ 
			"Acer Veriton M6620G" & @CRLF & _ 
			"Virtueller PC"


			MsgBox(0, "64bit Geräteübersicht V1.01.1", $geraete64)
			GUISetState(@SW_ENABLE, $Form1)


   EndSwitch
WEnd


Func Load($system)
	Local $hFile, $sContent, $aNewItems
	$hFile = FileOpen(@ScriptDir & '\' & $system, 0)
	If $hFile <> -1 Then
		$sContent = FileRead($hFile)
		FileClose($hFile)
		$sContent = StringTrimRight($sContent, 2)
		$aNewItems = StringSplit($sContent, @CRLF, 1)
		If Not IsArray($aNewItems) Then Return
		_GUICtrlListView_BeginUpdate($hListView)
		_GUICtrlListView_DeleteAllItems($hListView)
		For $i = 1 To $aNewItems[0]
			GUICtrlCreateListViewItem($aNewItems[$i], $idListView)
		Next
		_GUICtrlListView_EndUpdate($hListView)
	EndIf
EndFunc

Alles anzeigen

Lottich

Hey

einfach nach dem GUISetState(@SW_ENABLE... folgende Zeile einfügen:

AutoIt

WinActivate("Installierte Produkte - Windows 7 32bit (Lenovo T450)")

Das ist der Titel deiner GUI. Mit WinActivate bekommt die GUI wieder den Fokus.

Nachtrag: Wenn sich der Titel im Programmverlauf mal ändern sollte, dann würd ich den Titel bei einer Änderung in eine globale Variable speichern und
diese Variable bei WinActivate eintragen.

**chip**

Warum der komische Effekt genau passiert, kann ich dir nicht sagen. So kannst du das aber umgehen:

AutoIt

GUISetState(@SW_ENABLE, $Form1)
GUISetState(@SW_RESTORE, $Form1)

**Oscar**

Umgehen kann man den Effekt auch, indem man die MsgBox als Child-Window erstellt.
Also beim MsgBox-Befehl $Form1 als Parent eintragen: MsgBox(0, "32bit Geräteübersicht V1.08.3", $geraete32, 0, $Form1)