Frage zu Child Windows bzw. Owned Windows

Kleffer

Hallo

In der Hilfe bin ich über Parent bzw. Child Windows und über Owner bzw. owned Windows gestolpert.
Etwa in der Beschreibung zu _GUITooltip_Create finden sich beide Bezeichnungen. Ich verstehe den Unterschied hier nicht.
Parent / Child kenne ich als nützlichen Parameter von GUICreate.
Wo ist bei einem Tooltip der Unterschied zwischen Parent und dem Fenster zu dem dem das Control gehört?

Viele Grüße aus der Hundehütte.

**Kanashius**

Ein Child-Fenster ist ein ganz normales Fenster, nur dass es zu dem anderen Fenster gehört. Es ist dem Fenster untergeordnet und kann nicht ohne dieses existieren. (Ein Child-Window kann z.b. auch ohne ränder,... in einem Fenster sein und du merkst nichtmal, dass es 2 Fenster sind)

**Bitnugger**

Zitat von Kleffer

Wo ist bei einem Tooltip der Unterschied zwischen Parent und dem Fenster zu dem dem das Control gehört?

Bei einem ToolTip() gibt es keinen... denn dazu müsste die interne AutoIt-Funktion ein Window-Handle als Parameter anbieten, was aber nicht der Fall ist, weil ein eigenes Window kreiert wird.

Wäre es anders, würde dies hier nicht funktionieren... tut es aber!

AutoIt

ToolTip('Huhu...')

Edit: Lese jetzt erst, dass es hier um _GUITooltip geht...

Bei dem _GUITooltip kannst du hingegen ein Window-handle angeben, auf welchem dieser angezeigt werden soll. Hier denke ich, verhält sich das etwa so...
Wurden die GUITooltips vom Parent-Window erzeugt und wird dieses geschlossen, sind die Tips für das Owner-Window nicht mehr verfügbar. Wurden die GUITooltips vom Owner-Window erzeugt und wird dieses geschlossen, sind sie für das Parent-Window nicht mehr verfügbar.

Wenn du ein Scrript schreibst und eine GUI kreiert, dann ist diese GUI dein "Owner-Window". Dein Prozess ist dann also analog dazu dein "Owner-Prozess" der von einem anderen Prozess gestartet wurde, dem "Parent-Prozess", von dem wir uns neben dem "Proccess-Handle", der "PID" und zig anderen Infos, auch dessen "Window-Handle" besorgen können... und genau dieses Window-Handle ist dann dein "Parent-Window".

Ich habe dir mal ein kleines Script getippert, dass du auf unterschiedliche Weise starten solltest, da sich dann das "Parent-Window" entsprechend ändert und du es so besser nachvollziehen kannst.
Z. B.:

Starte das Script direkt aus SciTE heraus, ohne es vorher zu kompilieren.
Starte das kompilierte Script (also die EXE) mit dem Windows-Explorer
Starte das kompilierte Script in der Eingabeaufforderung
Starte das kompilierte Script mit einem anderen Script via Run("WinInfo.exe")
Kompiliere das andere Script und starte es nochmals damit.

Dann schließe mal dein Child-Window... dann dein Owner-Window... was in dem Fall das Parent-Window ist... dann umgekehrt...

WinInfo.au3

AutoIt

;-- TIME_STAMP   2016-11-19 22:59:03
; Constants
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
; Includes
#include <Array.au3>
#include <GuiListView.au3>
#include <GUIToolTip.au3>
#include <Process.au3>
#include <WinAPI.au3>
#include <WinAPISys.au3>
#include <WinAPIProc.au3>
_Main()
Func _Main()
	#region - GUI Create
	Local $x = @DesktopWidth -80, $msg, $hWndOwner, $idLV, $hLV, $idButton_Exit, $hButton_Exit, $aInfo[2][7], $hWndParent, $iPID, _
	$sSpacer1 = '~~~~~~~~~~~~~~~~~~~~~~~~'
	$sSpacer2 = '~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
	Local Enum $enPID, $enProcName, $enHW, $enWT, $enCW, $enO, $enP
	Local Enum $enOwner, $enParent
	$hWndOwner = GUICreate('Unsere GUI', $x, 145, -1, -1)
	GUISetFont(8.5, 800, 0, 'Courier New')
	$idLV = GUICtrlCreateListView('PID|Process-Name|Window-Handle/ClassName|Window-Title|Child-Windows|Owner|Parent', 0, 0, $x, 100)
	$hLV  = GUICtrlGetHandle($idLV)
	_GUICtrlListView_SetColumnWidth($idLV, 0, 50)	; PID
	_GUICtrlListView_SetColumnWidth($idLV, 1, Int($x*0.10))	; Process-Name
	_GUICtrlListView_SetColumnWidth($idLV, 2, Int($x*0.15))	; Window-Handle/ClassName
	_GUICtrlListView_SetColumnWidth($idLV, 3, Int($x*0.15))	; Window-Title
	_GUICtrlListView_SetColumnWidth($idLV, 4, Int($x*0.51))	; Child-Windows
	_GUICtrlListView_SetColumnWidth($idLV, 5, 50)	; Owner
	_GUICtrlListView_SetColumnWidth($idLV, 6, 50)	; Parent
	_GUICtrlListView_JustifyColumn($idLV, 0, 1)
	$idButton_Exit = GUICtrlCreateButton('Exit', 5, 110, $x -10, 25)
	$hButton_Exit  = GUICtrlGetHandle($idButton_Exit)
	Local $hToolTip = _GUIToolTip_Create(0)
	GUISetState()
	#endregion
	; Owner PID - oder mit WinGetProcess($hWnd)
	$aInfo[$enOwner][$enPID] = @AutoItPID
	; Owner ProcessName
	$aInfo[$enOwner][$enProcName] = _ProcessGetName(@AutoItPID)
	; Owner Window-Handle
	$aInfo[$enOwner][$enHW] = $hWndOwner & '/' & _WinAPI_GetClassName($hWndOwner)
	; Owner Window-Title
	$aInfo[$enOwner][$enWT] = WinGetTitle($hWndOwner)
	; Owner Child-Window-Handles
	Local $aOwnerChildWindows = _WinAPI_EnumChildWindows($hWndOwner)
	$aInfo[$enOwner][$enCW] = _ArrayToString($aOwnerChildWindows, ', ')
	; Owner
	$aInfo[$enOwner][$enO] = 'X'
	_ArrayAdd($aOwnerChildWindows, $sSpacer1 & '|' & $sSpacer2)
	_ArrayDisplay($aOwnerChildWindows, '$aOwnerChildWindows - ' & $aInfo[$enOwner][$enWT])
	;  Parent PID
	$aInfo[$enParent][$enPID] = _WinAPI_GetParentProcess()
	; Parent ProcessName
	$aInfo[$enParent][$enProcName] = _ProcessGetName($aInfo[$enParent][$enPID])
	; Parent Window-Handle
	Local $aParentProcessWindows = _WinAPI_EnumProcessWindows($aInfo[$enParent][$enPID], False)
	For $i = 1 To $aParentProcessWindows[0][0] Step 1
		If WinGetProcess($aParentProcessWindows[$i][0]) = $aInfo[$enParent][$enPID] Then
			$aInfo[$enParent][$enHW] = $aParentProcessWindows[$i][0]
			$aInfo[$enParent][$enWT] = WinGetTitle($aInfo[$enParent][$enHW])
			If $aInfo[$enParent][$enWT] = '' Then ContinueLoop
			ExitLoop
		EndIf
	Next
	; Parent Child-Window-Handles
	Local $aParentChildWindows = _WinAPI_EnumChildWindows($aInfo[$enParent][$enHW])
	_ArrayAdd($aParentChildWindows, $sSpacer1 & '|' & $sSpacer2)
	$aInfo[$enParent][$enHW] &= '/' & _WinAPI_GetClassName($aInfo[$enParent][$enHW])
	$aInfo[$enParent][$enCW] = _ArrayToString($aParentChildWindows, ', ')
	$aInfo[$enParent][$enP] = 'X'
	_ArrayDisplay($aParentChildWindows, '$aParentChildWindows - ' & $aInfo[$enParent][$enWT])
	_GUICtrlListView_AddArray($idLV, $aInfo)
	Local $hWndParent = $aInfo[$enParent][$enHW]
	; add tools to the tooltip controls
	_GUIToolTip_AddTool($hToolTip, $hWndOwner, "$hWndOwner - $hLV", $hLV)
	_GUIToolTip_AddTool($hToolTip, $hWndOwner, "$hWndOwner - $hButton_Exit", $hButton_Exit)
	#region - ChildGUI Create
	Local $aWinPos = WinGetPos($hWndOwner)
	Local $hWndChildOwner = GUICreate('MyChildGUI', 400, 45, -1, $aWinPos[1] + $aWinPos[3] + 20, -1, -1, $hWndOwner)
	$idChildButton_Exit = GUICtrlCreateButton('Exit', 5, 10, 390, 25)
	$hChildButton_Exit  = GUICtrlGetHandle($idChildButton_Exit)
	_GUIToolTip_AddTool($hToolTip, $hWndChildOwner, "$hWndChildOwner - $hChildButton_Exit", $hChildButton_Exit)
	GUISetState()
	GUISwitch($hWndOwner)
	#endregion
	#region - GUI SelectLoop
	While 1
		$msg = GUIGetMsg()
		Select
			Case $msg = $GUI_EVENT_CLOSE Or $msg = $idButton_Exit
				Exit
			Case $msg = $idChildButton_Exit
				GUIDelete($hWndChildOwner)
			;Case $msg =
			;Case $msg =
			;Case $msg =
		EndSelect
	WEnd
	#endregion
	; Destroy the tooltip controls
	_GUIToolTip_Destroy($hToolTip)
EndFunc

Alles anzeigen