Treeview Style wechseln

**BugFix**

Ich steh gerade auf dem Schlauch. Eigentlich sollte der folgende Code beim Treeview umschalten zwischen Ansicht mit und ohne Checkbox-Style.
Aber das Treeview "friert" ein statt den Style zu ändern. Wo liegt der Hase im Pfeffer?

AutoIt

#include <WinAPI.au3>
#include <TreeViewConstants.au3>


Global $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
Global $iStyleEx = BitOR($WS_EX_COMPOSITED, $WS_EX_CLIENTEDGE)
Global $fSwapped = False


$hGui = GUICreate('')
$cTreeview = GUICtrlCreateTreeView(10, 10, 200, 200, $iStyle, $iStyleEx)
$hTreeview = GUICtrlGetHandle($cTreeview)
$cSwap = GUICtrlCreateButton('SwapStyle', 10, 230, 100, 20)


GUISetState()


For $i = 1 To 20
	GUICtrlCreateTreeViewItem('Item ' & $i, $cTreeview)
Next


While 1
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $cSwap
			If Not $fSwapped Then
				$iStyle = BitOR($iStyle, $TVS_CHECKBOXES)
			Else
				$iStyle = BitXOR($iStyle, $TVS_CHECKBOXES)
			EndIf
			_WinAPI_SetWindowLong($hTreeview, $GWL_STYLE, $iStyle)
			_WinAPI_RedrawWindow($hTreeview)
			$fSwapped = Not $fSwapped
	EndSwitch
WEnd

Alles anzeigen

**Bitnugger**

Bei mir musste ich zuerst noch ein Include hinzufügen, um dein Script zu testen...
#include <WindowsConstants.au3>

Dann habe ich mich gefragt, wieso du den Style nicht mit GUICtrlSetStyle() änderst... und habe in der Hilfe dazu dann folgendes gelesen:
Remarks
Some styles cannot be changed dynamically, check MSDN documentation. $CBS_UPPERCASE combo style is one example.

Mit GUICtrlSetStyle() kannst du den Checkbox-Style zwar setzen, jedoch nicht wieder entfernen...

**BugFix**

Habe jetzt eine On-The-Fly-Lösung gebastelt. Ich erstelle zwei Treeview mit den Styles und blende bei Stylewechsel das andere Treeview ein und fülle es mit den Item, die ich in einem Array vorhalte.

AutoIt

#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <GuiTreeView.au3>


Global $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
Global $iStyleCheck = BitOR($iStyle, $TVS_CHECKBOXES)
Global $iStyleEx = BitOR($WS_EX_COMPOSITED, $WS_EX_CLIENTEDGE)
Global $fSwapped = False, $Ctrl
Global $aValues = _CreateValueArray()


$hGui = GUICreate('')
$cTreeview1 = GUICtrlCreateTreeView(10, 10, 200, 200, $iStyle, $iStyleEx)
$cTreeview2 = GUICtrlCreateTreeView(10, 10, 200, 200, $iStyleCheck, $iStyleEx)
GUICtrlSetState(-1, $GUI_HIDE)
$cSwap = GUICtrlCreateButton('SwapStyle', 10, 230, 100, 20)
$Ctrl = $cTreeview1


GUISetState()


_FillTreeview($Ctrl)


While 1
	Switch GUIGetMsg()
		Case -3
			Exit
		Case $cSwap
			GUICtrlSetState($Ctrl, $GUI_HIDE)
			If Not $fSwapped Then
				$Ctrl = $cTreeview2
			Else
				$Ctrl = $cTreeview1
			EndIf
			_FillTreeview($Ctrl)
			GUICtrlSetState($Ctrl, $GUI_SHOW)
			$fSwapped = Not $fSwapped
	EndSwitch
WEnd


Func _FillTreeview($Ctrl)
	_GUICtrlTreeView_DeleteAll($Ctrl)
	For $i = 0 To UBound($aValues) -1
		$r = GUICtrlCreateTreeViewItem($aValues[$i], $Ctrl)
	Next
EndFunc


Func _CreateValueArray()
	Local $a[20]
	For $i = 0 To 19
		$a[$i] = 'Item ' & $i+1
	Next
	Return $a
EndFunc

Alles anzeigen