Doppelklick auf die Fensterleiste (Caption) einer AutoIt GUI auswerten

AutoMit

Hallo,

was ist der sicherste Weg, um festzustellen, ob mit der Maus ein Linksklick, Doppelklick, Rechtsklick (ggf. in Verbindung mit shift und / oder strg) auf die Caption einer AutoIt-GUI erfolgte?

Ziel: jeweils eine benutzerdefinierte Funktion aufzurufen, wenn einer der obigen Aktionen auf die Caption der Form registriert wurde.

Mausklick auf Controls wie Button auswerten, das klappt. Wie macht man das bei der Form (Caption)?

Danke

**alpines**

Du kannst doch einfach die Zeit messen ob dein Control innerhalb von einem bestimmten Intervall zweimal geklickt wurde.
Mit GUIGetCursorInfo() und OnEvent mit Right Mouse Down kannst du den Rechtsklick abfangen und ebenfalls abfragen ob er in einer bestimmten Zeit mehrmals geklickt wurde.

**alpines**

Hier hast du mal ein Beispiel wie das ganze aussehen kann, den Linksklick habe ich ebenfalls mit einem GUIEvent gelöst und nicht per GUICtrlSetOnEvent, weil das Event auf dem Control komischerweise jedes mal über 400ms braucht. Das ganze kann man sicherlich schöner lösen aber es tut seinen Job:

AutoIt

#include <GUIConstantsEx.au3>


Global Const $I_THRESHHOLD = 750
Global $bRightClicked, $bLeftClicked
Global $tmrRightClick, $tmrLeftClick


Opt("GUIOnEventMode", 1)
$hGUI = GUICreate("Form1", 183, 62, -1, -1)
GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, _Label_Click)
GUISetOnEvent($GUI_EVENT_SECONDARYDOWN, _Label_Click)
GUISetOnEvent($GUI_EVENT_CLOSE, _Exit)


$hLabel = GUICtrlCreateLabel("Caption", 48, 16, 94, 33)
GUICtrlSetFont(-1, 18, 800, 0, "MS Sans Serif")
GUISetState(@SW_SHOW)


While Sleep(10)
WEnd


Func _Label_Click()
	$aInfo = GUIGetCursorInfo()


	If $aInfo[4] = $hLabel Then
		If $aInfo[2] Then ;Primary Down
			If Not $bLeftClicked Then
				$tmrLeftClick = TimerInit()
				$bLeftClicked = True
			Else
				If TimerDiff($tmrLeftClick) >= $I_THRESHHOLD Then
					GUICtrlSetData($hLabel, Round(TimerDiff($tmrLeftClick), 0) & "ms")
					GUICtrlSetColor($hLabel, 0xFF0000)
					$bLeftClicked = True
					$tmrLeftClick = TimerInit()
				Else
					GUICtrlSetData($hLabel, Round(TimerDiff($tmrLeftClick), 0) & "ms")
					GUICtrlSetColor($hLabel, 0x00FF00)
					$bLeftClicked = False


					;Erfolgreicher Links-Doppelklick
				EndIf
			EndIf
		ElseIf $aInfo[3] Then ;Secondary Down
			If GUIGetCursorInfo($hGUI)[4] = $hLabel Then
				If Not $bRightClicked Then
					$tmrRightClick = TimerInit()
					$bRightClicked = True
				Else
					If TimerDiff($tmrRightClick) >= $I_THRESHHOLD Then
						GUICtrlSetData($hLabel, Round(TimerDiff($tmrRightClick), 0) & "ms")
						GUICtrlSetColor($hLabel, 0xFF0000)
						$bRightClicked = True
						$tmrRightClick = TimerInit()
					Else
						GUICtrlSetData($hLabel, Round(TimerDiff($tmrRightClick), 0) & "ms")
						GUICtrlSetColor($hLabel, 0x00FF00)
						$bRightClicked = False


						;Erfolgreicher Rechts-Doppelklick
					EndIf
				EndIf
			EndIf
		EndIf
	EndIf
EndFunc


Func _Exit()
	Exit
EndFunc

Alles anzeigen

AutoMit

Hallo alpines, vielen Dank - das sieht sehr interessant aus - und besonderen Dank für die Codezeilen.

Ich komme auf 140 ms minimal - typisch um 200 ms bei Doppelklick.

Caption des Fensters
==================

Ich habe mir das Beispiel aus der Hilfe zu GUIGetCursorInfo() erneut angesehen und vor der Fragestellung damit experimentiert.
"$array[4] = ID des Controls, über dem sich der Mauszeiger gerade befindet (0 wenn nicht über einem Item)"
Das bedeutet, das eine freie Fläche auf der Form ebenso wie die Caption die ID 0 haben.

Wie erkenne ich zuverlässig, dass ich der Doppelklick ... auf die Caption gesetzt wurde?

Gibt es für einen Doppelklick (L/R) auf die Caption eine eindeutigere Kennzeichung als über die ID (GUIGetCursorInfo())?

**Kanashius**

Du kannst die WM_LBUTTONDOWN oder WM_LBUTTONUP Message registrieren (GuiRegisterMsg).
Der wParam enthät dann die Info, ob eine Taste gedrückt war, als der Klick ausgeführt wurde:

MK_CONTROL
0x0008
The CTRL key is down.

MK_LBUTTON
0x0001
The left mouse button is down.

MK_MBUTTON
0x0010
The middle mouse button is down.

MK_RBUTTON
0x0002
The right mouse button is down.

MK_SHIFT
0x0004
The SHIFT key is down.

MK_XBUTTON1
0x0020
The first X button is down.

MK_XBUTTON2
0x0040
The second X button is down.

https://msdn.microsoft.com/en-us/library/…7(v=vs.85).aspx

Auf Shift und Ctrl kannst du dann gesondert reagieren

MfG Kanashius

AutoMit

Zitat von Kanashius

Du kannst die WM_LBUTTONDOWN oder WM_LBUTTONUP Message registrieren (GuiRegisterMsg).

Danke Kanashius. Zur Erkennung des Doppelklicks nehme ich hier auch einen Timer, da es laut URL keinen Parameter "Doppelklick" gibt.

**alpines**

Du meinst die Fensterleiste, da musst du mit den WMs rangehen.

@AutoMit Es gibt eine Message die nur Doppelklicks annimmt und somit der Timer überflüssig wird.

@Kanashius du kannst WM_LBUTTONDOWN nicht für die Caption registrieren. Da brauchst du $WM_NCLBUTTONDBLCLK oder $WM_NCLBUTTONDOWN.
Das Problem bei dem Script hier ist, das das Windows Kontextmenu das zweite klicken blockiert. Du müsstest das also irgendwie deaktivieren bevor es geöffnet wird.

Die Zusätze wie STRG und ALT kriegst du aus den Parametern mit den jeweiligen Bit-Operationen raus, schau dich einfach mal auf der msdn Seite um.

Hier mal das ganze mit Blockade, klappt einwandfrei:

AutoIt

#include <WindowsConstants.au3>


Opt("GUIOnEventMode", 1)
$hGUI = GUICreate("Form1", 183, 62, -1, -1)
GUIRegisterMsg($WM_CONTEXTMENU, _ContextMenu)
GUIRegisterMsg($WM_NCLBUTTONDBLCLK, _Label_Click)
GUIRegisterMsg($WM_NCRBUTTONDOWN, _Label_Click)
GUISetOnEvent(-3, _Exit)


$hLabel = GUICtrlCreateLabel("Caption", 48, 16, 94, 33)
GUICtrlSetFont(-1, 18, 800, 0, "MS Sans Serif")
GUISetState(@SW_SHOW)


While Sleep(10)
WEnd


Func _ContextMenu($hWnd, $nMsg, $wParam, $lParam)
	Return 0
EndFunc


Func _Label_Click($hWnd, $nMsg, $wParam, $lParam)
	MsgBox(0,0,$hWnd & @CRLF & $nMsg & @CRLF & $wParam & @CRLF & $lParam)
	Return 0
EndFunc


Func _Exit()
	Exit
EndFunc

Alles anzeigen

AutoMit

@alpines - vielen Dank - ich habe den Beitragstitel entsprechend auf "Fensterleiste" angepasst - ja, die meine ich.

Problem gelöst Grün gesetzt.

Danke Euch beiden, das ist eine super Hilfe!