Senden von Escape-Sequenzen an Drucker (ESC/POS)

Dexter

Liebe Gemeinde,

da ich kein gescheites Programm finden konnte, um unterwegs Quittungen für Kunden auszudrucken, ohne auf einen DIN A4-Drucker zurückgreifen zu müssen, habe ich mir ein kleines Skript mit der printMG.dll von Martin erstellt, um einen kleinen 80 mm Bluetooth-Bondrucker anzusteuern. Das klappt soweit wunderbar, was den Inhalt angeht. Nur mit der Formatierung habe ich ein kleines Problem.

Zum Hintergrund: Generell benutzt man bei Kassenanwendungen häufig den Raw- oder Textmodus, da das einfach schneller geht, als Grafiken zum Drucker zu schicken. Z.B. hinterlegt man ein Logo einmal im Speicher des Druckers und löst es zum Anfang des Druckvorgangs einfach aus, statt die ganze Grafik neu zu übermitteln.

Auch für Textformatierungen und andere Dinge gibt es dann entsprechende Escape-Sequenzen (Lade öffnen, Schrift doppelt breit, doppelt hoch, etc.), die man einfach in den Druck mit einbauen kann.

Dummerweise bin ich anscheinend zu doof, um die Sequenzen richtig zu senden. Probiert habe ich z.B. den Druck in doppelter Höhe. Dazu müsste ich die Sequenz ESC ! n an den Drucker schicken. n steht dann für die Art des Drucks (n = 16 ist doppelte Höhe, n = 32 ist doppelte Breite). Es gilt also, dem Drucker zu sagen ESC ! 16. Dazu habe ich z.B.

_PrintText( $Prn Chr( 27) & Chr( 33) & 16 ) sowie _PrintText( $Prn {ESC} & {!} & 16 ) oder auch send( Chr( 27) & Chr( 33) & 16 ) ausprobiert. Leider hat nichts davon funktioniert.

Hat vielleicht schon einmal jemand von Euch mit solchen Escape-Sequenzen gearbeitet oder sonstwie eine Idee, wie ich diese korrekt an den Drucker schicken kann? Über jedwede Unterstützung würde ich mich riesig freuen.

**Kanashius**

Also, mit Escapesequenzen nicht, aber _PrintText( $Prn Chr( 27) & Chr( 33) & 16 ) Kann nicht funktionieren, denn Variablen müssen immer irgendwie verknüpft sein. {ESC} sendet nicht die Taste, sondern den String. AutoIt markiert es nur, falls man damit die Taste meint, damit man weiß, dass es richtig geschrieben ist,... es ist aber immernoch der String "{ESC}". 27 ist richtig escape, wie du gefunden hast. Ob wirklich das Zeichen für Escape oder der String "ESC" gemeint ist weiß ich jetzt nicht. 33 ist das Rufzeichen, also auch richtig, man kann auch "!" schreiben. 16 wird als Zahl auch dahinter gepackt. Vielleicht fehlen dort nur die Leerzeichen, weiß grad nicht, ob die bei dir dorthin müssen.
Was du sendest sieht so aus:
[ESC] ist dabei nicht der String, sondern das ASCII-Zeichen 27
_PrintText( $Prn Chr( 27) & Chr( 33) & 16 ) Erstmal nen Error wegen $PRN CHR(27), sonst wäre das Ergebnis bei _PrintText( $Prn & Chr( 27) & Chr( 33) & 16 ) : "Was in $PRN steht[ESC]!16"
_PrintText( $Prn {ESC} & {!} & 16 ) Erstmal nen Error wegen $PRN {ESC}, sonst wäre das Ergebnis bei _PrintText( $Prn &"{ESC}" & {!} & 16 ) : "Was in $PRN steht{ESC}{!}16"
send( Chr( 27) & Chr( 33) & 16 ) Sendet als Tastendruck: [ESC]!16
Was du vermutlich möchtest: Chr(27)&" "&Chr(33)&" "&16

Ansonsten bräuchte ich mehr von dem Script, und die Info, ob du per Handy ein Programm auf deinem Rechner ansteuern möchtest, welcher dann Tastendrücke simuliert,...

Dexter

Hallo @Kanashius und schon mal vielen lieben Dank für Deine Hilfe.

Du hast natürlich Recht, Variablen müssen verknüpft sein. In meinem Fall hab ich Dussel ein Komma nach dem $Prn vergessen.

Ich liste hier mal kurz die Druckfunktion des Scripts ohne jegliche Escape-Sequenzen, dann kann man sich das im Kontext wahrscheinlich besser vorstellen. Der Übersichtlichkeit halber lasse ich die Teile zum Auffangen von Fehlern mal weg.

Code

Func _Print()
    Local $Prn = _PrintDllStart($pErr)
    Local $sPrinter = "Pos-80-Series"
    _PrintSetDocTitle($Prn, "Zahlungsbeleg")


    ; start printing operation
    _PrintStartPrint($Prn)
    ;_PrintSetFont($Prn,$FontName,$FontSize,$FontCol=0,$Fontstyle = '')
    ;To check that the text will fit a space use _PrintGetTextHeight and _PrintGetTextWidth
    ;_PrintText($hDll,$sText,$ix=-1,$iy=-1,$iAngle=0)
    _PrintText($Prn, "            Musterfirma GmbH & Co.         ", 10, 20)
    _PrintText($Prn, "                                           ", 10, 60)
    _PrintText($Prn, "               Musterstraße 99             ", 10, 100)
    _PrintText($Prn, "              12345 Musterstadt            ", 10, 140)
    _PrintText($Prn, "                                           ", 10, 180)
    _PrintText($Prn, "              Tel: 0123 4567890            ", 10, 220)
    _PrintText($Prn, "                                           ", 10, 260)
    _PrintText($Prn, "                                           ", 10, 300)
    _PrintText($Prn, "           ZAHLUNGSBELEG NR. " & $sLfdNr    , 10, 340)
    _PrintText($Prn, "                                           ", 10, 380)
    _PrintText($Prn, "   Kd.Nr.: " & $sKundenNr & "      Datum: " & $sCurrentDate , 10, 420)
    _PrintText($Prn, "                                          " , 10, 460)
    _PrintText($Prn, "   Kunde:  " & $sKunde                      , 10, 500)
    _PrintText($Prn, "           " & $sZusatz                     , 10, 540)
    _PrintText($Prn, "           " & $sStrasze                    , 10, 580)
    _PrintText($Prn, "           " & $sPLZ & " " & $sOrt          , 10, 620)
    _PrintText($Prn, "                                           ", 10, 660)
    _PrintText($Prn, "   EUR " & $sBetrag & " dankend in bar erhalten." , 10, 700)
    _PrintText($Prn, "                                           ", 10, 740)
    _PrintText($Prn, "   Verw.zweck: " & $sGrund , 10, 780)
    _PrintText($Prn, "                                           ", 10, 820)
    _PrintText($Prn, "       * Dieser Beleg berechtigt nicht *   ", 10, 860)
    _PrintText($Prn, "            * zum Vorsteuerabzug *         ", 10, 900)
    _PrintEndPrint($Prn)


	Local $sLfdNr		= Int(IniRead( $sIniPath , "CurrentData" , "LfdNr" , " " ))
	IniWrite( $sIniPath , "CurrentData" , "LfdNr" , $sLfdNr + 1 )
	Local $hFileOpen = FileOpen( $sFile, $FO_APPEND + $FO_UTF8 )
    If $hFileOpen = -1 Then
        MsgBox($MB_SYSTEMMODAL, "Fehler", "Die Werte konnten nicht ins Archiv geschrieben werden.")
        Return False
	EndIf
	FileWriteLine( $hFileOpen , String( $sLfdNr ) & ";" & String( $sCurrentDate ) & ";" & $sKundenNr & ";" & $sKunde & ";" & $sZusatz & ";" & $sStrasze & ";" & $sPLZ & ";" & $sOrt & ";" & $sBetrag & @CRLF )
	FileClose($hFileOpen)
EndFunc

Alles anzeigen

Mit der wie folgt eingebauten Sequenz passiert zwar schon mal etwas, aber nicht das Richtige. Schreibe ich z.B.
_PrintText($Prn, Chr( 27 ) & Chr( 33 ) & 16 & " ZAHLUNGSBELEG NR. " & $sLfdNr , 10, 340)
dann wird ab dem Wort Zahlungsbeleg alles in einem größeren, fetten Font gedruckt bis zum Schluss. Versuche ich, das in der nächsten Zeile mit
_PrintText($Prn, Chr( 27 ) & Chr( 33 ) & 0 & " ", 10, 380)
wieder auf Null zu stellen, kommt ein noch größerer Font bis zum Schluss.

Wenn ich so wie hier noch Leerzeichen dazu mache
_PrintText($Prn, Chr( 27 ) & " " & Chr( 33 ) & " " & 16 & " ZAHLUNGSBELEG NR. " & $sLfdNr , 10, 340)
dann wird ab dieser Stelle alles mit dem normalen Font gedruckt, aber an jeder zweiten Druckposition ein Leerzeichen eingefügt, sodass es wie gesperrter Text aussieht (B e i s p i e l).

P.S.: Nein, ein Handy ist hier nicht im Spiel, Tastendrücke wollte ich eigentlich keine übertragen.

**Kanashius**

Sicher, dass dort 0 hin muss für normal? Normal wird ein Font in Pixel angegeben, also 16 pixel, normal wären dann 12. 0 Würd ja heißen überhaupt keine Größe. Könnte mir dort den Fehler vorstellen.

Kannst du mir mal das Modell nennen?
Dort sind unterschiede in den Escapesequenzen, siehe Epson: http://lprng.sourceforge.net/DISTRIB/RESOURCES/PPD/epson.htm

Spoiler anzeigen

27 33 n
ESC ! n

Master select where n is a combination of:
0 Pica 16 Double Strike
1 Elite 32 Double Wide
4 Condensed 64 Italic
8 Emphasized 128 Underline
Pica & Elite and Condensed/Emphasized are mutually exclusive

Dexter

Ja, genau, wie in Deiner Liste. Das Modell ist ein Chinakracher von Hoin, aber der hält sich an diese Epson-Sequenzen (die haben irgendwann mal quasi den Standard gesetzt).

Die Sequenzen entsprechen daher nahezu Deinen, ich habe den Teil mal aus meiner Anleitung beigefügt.

24-01-_2017_03-54-18.png

P.S.: Pixel gibt man bei diesen Druckern übrigens nicht an. Die haben eingebaute Fonts (oft nur zwei), die man einfach abruft und dann sagt, ob sie doppelt hoch, breit oder beides sein sollen. Man hat das früher wohl so eingeführt, weil alles über alte Ports ging und man wollte, dass es trotzdem schnell geht. Will man dann doppelt hoch und breit, addiert man die Bits und schickt z.B. einfach 16 + 32, also 48 als Wert.

**Bitnugger**

So evtl.

printexample2.au3

AutoIt

;-- TIME_STAMP   2017-01-25 17:50:34   v 0.1


#include <File.au3>
#include 'printMGv2.au3'
#include <WinAPIShPath.au3>


Global $iReset = 0x00 ; Alle Werte auf Default setzen
Global $iFontA = 0x00 ; Character font A (12x24)
Global $iFontB = 0x01 ; Character font B ( 9x17)
Global $iEmphasized = 0x08 ; Text hervorheben
Global $iDoubleH = 0x10 ; Doppelte Höhe
Global $iDoubleW = 0x20 ; Doppelte Breite
Global $iUnderline = 0x80 ; Text unterstreichen


Global $iMask = BitOR($iFontA, $iFontB, $iEmphasized, $iDoubleH, $iDoubleW, $iUnderline)
ConsoleWrite('$iMask = ' & _Hex($iMask) & @CRLF)


_Print()


Func _Print()
	Local $sIniFile = _WinAPI_PathRemoveExtension(@ScriptFullPath)


	Local $sLfdNr       = Int(IniRead($sIniFile, "CurrentData", "LfdNr", '1'))
	Local $sKundenNr    = 1234567
	Local $sCurrentDate = 'Heute'
	Local $sKunde       = 'Ike'
	Local $sZusatz      = 'Der Berliner'
	Local $sStrasse     = 'Am Zoo 42'
	Local $sPLZ         = 1234
	Local $sOrt         = 'Berlin'
	Local $sBetrag      = 10000000
	Local $sGrund       = 'Lebensberechtigungskarte'


	IniWrite($sIniFile, "CurrentData", "LfdNr", $sLfdNr + 1)


	Local $pErr = '', $Prn = _PrintDllStart($pErr), $sPrinter = "Pos-80-Series"


	; _PrintSelectPrinter($Prn, $sPrinter, False)


	_PrintSetDocTitle($Prn, "Zahlungsbeleg")


	; start printing operation
	_PrintStartPrint($Prn)
	;_PrintSetFont($Prn,$FontName,$FontSize,$FontCol=0,$Fontstyle = '')
	;To check that the text will fit a space use _PrintGetTextHeight and _PrintGetTextWidth
	;_PrintText($hDll,$sText,$ix=-1,$iy=-1,$iAngle=0)
	_PrintESC($Prn, $sPrinter, 'ADEU'	, "            Musterfirma GmbH & Co.         ", 10, 20)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 60)
	_PrintESC($Prn, $sPrinter, 'BDEU'	, "               Musterstraße 99             ", 10, 100)
	_PrintESC($Prn, $sPrinter, 'BDEU'	, "              12345 Musterstadt            ", 10, 140)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 180)
	_PrintESC($Prn, $sPrinter, 'BDEU'	, "              Tel: 0123 4567890            ", 10, 220)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 260)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 300)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "           ZAHLUNGSBELEG NR. " & $sLfdNr, 10, 340)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 380)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "   Kd.Nr.: " & $sKundenNr & "      Datum: " & $sCurrentDate, 10, 420)
	_PrintESC($Prn, $sPrinter, ''		, "                                          ", 10, 460)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "   Kunde:  " & $sKunde, 10, 500)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "           " & $sZusatz, 10, 540)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "           " & $sStrasse, 10, 580)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "           " & $sPLZ & " " & $sOrt, 10, 620)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 660)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "   EUR " & $sBetrag & " dankend in bar erhalten.", 10, 700)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 740)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "   Verw.zweck: " & $sGrund, 10, 780)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 820)
	_PrintESC($Prn, $sPrinter, 'ADE'	, "       * Dieser Beleg berechtigt nicht *   ", 10, 860)
	_PrintESC($Prn, $sPrinter, 'ADE'	, "            * zum Vorsteuerabzug *         ", 10, 900)
	_PrintEndPrint($Prn)


	Local $hArchiv = FileOpen(@ScriptDir & '\Archiv.dat', $FO_APPEND + $FO_UTF8)
	If $hArchiv = -1 Then
		MsgBox($MB_SYSTEMMODAL, "Fehler", "Die Werte konnten nicht ins Archiv geschrieben werden.")
		Return False
	EndIf
	;                                     1  2  3  4  5  6  7  8  9        1:Int  , 2:String     , 3:Int     , 4:String, 5:String, 6:String , 7:Int, 8:String, 9:Int
	FileWriteLine($hArchiv, StringFormat('%i;%s;%i;%s;%s;%s;%i;%s;%i\r\n', $sLfdNr, $sCurrentDate, $sKundenNr, $sKunde, $sZusatz, $sStrasse, $sPLZ, $sOrt, $sBetrag))
	FileClose($hArchiv)


	_PrintDllClose($Prn)
EndFunc   ;==>_Print


Func _PrintESC($Prn, $sPrinter, $sESC, $Txt, $x, $y)
	Local $n = $iMask, $aSplit = StringSplit('!' & $sESC, '')


	For $i = 1 To $aSplit[0] Step 1
		Switch $aSplit[$i]
			Case '!' ; No ESC Code - print text only
				$n = '!'
				ExitLoop
			Case 'A' ; Character font A (12x24)
				$n = BitXOR($n, $iFontA)
			Case 'B' ; Character font B ( 9x17)
				$n = BitXOR($n, $iFontB)
			Case 'D' ; Doppelte Höhe und Breite
				$n = BitXOR($n, $iDoubleH, $iDoubleW)
			Case 'E' ; Text hervorheben
				$n = BitXOR($n, $iEmphasized)
			Case 'H' ; Doppelte Höhe
				$n = BitXOR($n, $iDoubleH)
			Case 'W' ; Doppelte Breite
				$n = BitXOR($n, $iDoubleW)
			Case 'U' ; Text unterstreichen
				$n = BitXOR($n, $iUnderline)
			Case Else ; Alle Werte auf Default setzen
				$n = $iReset
				ExitLoop
		EndSwitch
	Next


	Switch $n
		Case '!'
			ConsoleWrite(StringFormat('_PrintText(%s, %s, %i, %i)\r\n', $Prn, $Txt, $x, $y))
			_PrintText($Prn, $Txt, $x, $y)
		Case Else
			Local $aData = [0x1B, 0x21, $n]


			ConsoleWrite(StringFormat('_PrintBytesDirect(%s, %s, %s)\r\n', $Prn, $sPrinter, _ArrayToString($aData, ', ')))
			_PrintBytesDirect($Prn, $sPrinter, $aData)


			ConsoleWrite(StringFormat('_PrintText(%s, %s, %i, %i)\r\n', $Prn, $Txt, $x, $y))
			_PrintText($Prn, $Txt, $x, $y)


			$aData[2] = $iReset
			ConsoleWrite(StringFormat('_PrintBytesDirect(%s, %s, %s)\r\n', $Prn, $sPrinter, _ArrayToString($aData, ', ')))
			_PrintBytesDirect($Prn, $sPrinter, $aData)
	EndSwitch
EndFunc   ;==>_PrintESC


Func _Hex($iDec)
	Return '0x' & Hex($iDec, 6)
EndFunc   ;==>_Hex

Alles anzeigen

Dexter

Vielen lieben Dank@'Bitnugger', dass Du auch versuchst, mir zu helfen.
Mit Deinen Änderungen im Script funktioniert zwar alles, aber nach wie vor ohne Formatierung. Also quasi so, als hätte sich nichts geändert.

Konntest Du das mal an einem Bondrucker ausprobieren? Vielleicht schlummert noch irgendwo ein Fehler im Script... *grübel*

**Bitnugger**

Zitat von Dexter

Konntest Du das mal an einem Bondrucker ausprobieren?

Nein, habe leider keinen.

Das könnte helfen... sonst bin ich mit meinem Latein auch am Ende.

printexample3

AutoIt

;-- TIME_STAMP   2017-01-26 01:05:27   v 0.1


#include <File.au3>
#include 'printMGv2.au3'
#include <WinAPIShPath.au3>


Global $iReset = 0x00 ; Alle Werte auf Default setzen
Global $iFontA = 0x00 ; Character font A (12x24)
Global $iFontB = 0x01 ; Character font B ( 9x17)
Global $iEmphasized = 0x08 ; Text hervorheben
Global $iDoubleH = 0x10 ; Doppelte Höhe
Global $iDoubleW = 0x20 ; Doppelte Breite
Global $iUnderline = 0x80 ; Text unterstreichen


Global $iMask = BitOR($iFontA, $iFontB, $iEmphasized, $iDoubleH, $iDoubleW, $iUnderline)
ConsoleWrite('$iMask = ' & _Hex($iMask) & @CRLF)


_Print()


Func _Print()
	Local $sIniFile = _WinAPI_PathRemoveExtension(@ScriptFullPath)


	Local $sLfdNr       = Int(IniRead($sIniFile, "CurrentData", "LfdNr", '1'))
	Local $sKundenNr    = 1234567
	Local $sCurrentDate = 'Heute'
	Local $sKunde       = 'Ike'
	Local $sZusatz      = 'Der Berliner'
	Local $sStrasse     = 'Am Zoo 42'
	Local $sPLZ         = 1234
	Local $sOrt         = 'Berlin'
	Local $sBetrag      = 10000000
	Local $sGrund       = 'Lebensberechtigungskarte'


	IniWrite($sIniFile, "CurrentData", "LfdNr", $sLfdNr + 1)


	Local $pErr = '', $Prn = _PrintDllStart($pErr), $sPrinter = "Pos-80-Series"


	Local $sDefaualtPrinter = _PrintGetPrinter($Prn)	; Aktuellen Standard-Drucker merken
	_PrintSelectPrinter($Prn, $sPrinter, True)			; Temporär als Standard-Drucker setzen


	_PrintSetDocTitle($Prn, "Zahlungsbeleg")


	; start printing operation
	_PrintStartPrint($Prn)
	;_PrintSetFont($Prn,$FontName,$FontSize,$FontCol=0,$Fontstyle = '')
	;To check that the text will fit a space use _PrintGetTextHeight and _PrintGetTextWidth
	;_PrintText($hDll,$sText,$ix=-1,$iy=-1,$iAngle=0)
	_PrintESC($Prn, $sPrinter, 'ADEU'	, "            Musterfirma GmbH & Co.         ", 10, 20)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 60)
	_PrintESC($Prn, $sPrinter, 'BDEU'	, "               Musterstraße 99             ", 10, 100)
	_PrintESC($Prn, $sPrinter, 'BDEU'	, "              12345 Musterstadt            ", 10, 140)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 180)
	_PrintESC($Prn, $sPrinter, 'BDEU'	, "              Tel: 0123 4567890            ", 10, 220)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 260)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 300)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "           ZAHLUNGSBELEG NR. " & $sLfdNr, 10, 340)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 380)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "   Kd.Nr.: " & $sKundenNr & "      Datum: " & $sCurrentDate, 10, 420)
	_PrintESC($Prn, $sPrinter, ''		, "                                          ", 10, 460)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "   Kunde:  " & $sKunde, 10, 500)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "           " & $sZusatz, 10, 540)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "           " & $sStrasse, 10, 580)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "           " & $sPLZ & " " & $sOrt, 10, 620)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 660)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "   EUR " & $sBetrag & " dankend in bar erhalten.", 10, 700)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 740)
	_PrintESC($Prn, $sPrinter, 'BDE'	, "   Verw.zweck: " & $sGrund, 10, 780)
	_PrintESC($Prn, $sPrinter, ''		, "                                           ", 10, 820)
	_PrintESC($Prn, $sPrinter, 'ADE'	, "       * Dieser Beleg berechtigt nicht *   ", 10, 860)
	_PrintESC($Prn, $sPrinter, 'ADE'	, "            * zum Vorsteuerabzug *         ", 10, 900)
	_PrintEndPrint($Prn)


	Local $hArchiv = FileOpen(@ScriptDir & '\Archiv.dat', $FO_APPEND + $FO_UTF8)
	If $hArchiv = -1 Then
		MsgBox($MB_SYSTEMMODAL, "Fehler", "Die Werte konnten nicht ins Archiv geschrieben werden.")
		Return False
	EndIf
	;                                     1  2  3  4  5  6  7  8  9        1:Int  , 2:String     , 3:Int     , 4:String, 5:String, 6:String , 7:Int, 8:String, 9:Int
	FileWriteLine($hArchiv, StringFormat('%i;%s;%i;%s;%s;%s;%i;%s;%i\r\n', $sLfdNr, $sCurrentDate, $sKundenNr, $sKunde, $sZusatz, $sStrasse, $sPLZ, $sOrt, $sBetrag))
	FileClose($hArchiv)


	_PrintSelectPrinter($Prn, $sDefaualtPrinter, True)			; Standard-Drucker wieder zurücksetzen
	_PrintDllClose($Prn)
EndFunc   ;==>_Print


Func _PrintESC($Prn, $sPrinter, $sESC, $Txt, $x, $y)
	Local $n = $iMask, $aSplit = StringSplit('!' & $sESC, '')


	For $i = 1 To $aSplit[0] Step 1
		Switch $aSplit[$i]
			Case '!' ; No ESC Code - print text only
				$n = '!'
				ExitLoop
			Case 'A' ; Character font A (12x24)
				$n = BitXOR($n, $iFontA)
			Case 'B' ; Character font B ( 9x17)
				$n = BitXOR($n, $iFontB)
			Case 'D' ; Doppelte Höhe und Breite
				$n = BitXOR($n, $iDoubleH, $iDoubleW)
			Case 'E' ; Text hervorheben
				$n = BitXOR($n, $iEmphasized)
			Case 'H' ; Doppelte Höhe
				$n = BitXOR($n, $iDoubleH)
			Case 'W' ; Doppelte Breite
				$n = BitXOR($n, $iDoubleW)
			Case 'U' ; Text unterstreichen
				$n = BitXOR($n, $iUnderline)
			Case Else ; Alle Werte auf Default setzen
				$n = $iReset
				ExitLoop
		EndSwitch
	Next


	Local $iErr
	Switch $n
		Case '!'
			ConsoleWrite(StringFormat('_PrintText(%s, %s, %i, %i)\r\n', $Prn, $Txt, $x, $y))
			_PrintText($Prn, $Txt, $x, $y)
		Case Else
			Local $aData = [0x1B, 0x21, $n]


			$iErr = _PrintBytesDirect($Prn, $sPrinter, $aData)
			ConsoleWrite(StringFormat('$iErr = %08i _PrintBytesDirect(%s, %s, %s)\r\n', $iErr, $Prn, $sPrinter, _ArrayToString($aData, ', ')))


			ConsoleWrite(StringFormat('_PrintText(%s, %s, %i, %i)\r\n', $Prn, $Txt, $x, $y))
			_PrintText($Prn, $Txt, $x, $y)


			$aData[2] = $iReset
			$iErr = _PrintBytesDirect($Prn, $sPrinter, $aData)
			ConsoleWrite(StringFormat('$iErr = %08i _PrintBytesDirect(%s, %s, %s)\r\n', $iErr, $Prn, $sPrinter, _ArrayToString($aData, ', ')))
	EndSwitch
EndFunc   ;==>_PrintESC


Func _Hex($iDec)
	Return '0x' & Hex($iDec, 6)
EndFunc   ;==>_Hex

Alles anzeigen

Das hier hast du bereits gesehen?

PrintWinAPI.au3

Dexter

Nochmal danke für Deine Mühe @Bitnugger. Leider hat es so auch nicht geklappt, der Text kommt unverändert normal aus dem Drucker. Ist schon krass, was man manchmal veranstalten muss, um einfach Rohdaten irgendwohin zu schicken.

Das Ding mit der PrintWinAPI.au3 hatte ich mir auch angesehen, aber das scheint definitiv über die Nutzung von grafischen Druckdaten hinauszulaufen wegen GDI & Co. Klar, ist ja auch heutzutage eigentlich der Normalfall. Trotzdem wundert mich, dass es so kompliziert ist, einen solch rudimentären Drucker anzusprechen. Gerade, wo doch in weltweit in jedem 2. Laden einer steht. *seufz*

**Bitnugger**

Evtl. hilft dir dies hier weiter: Drucker per Kommandozeile (CMD) verwalten – rundll32.exe printui.dll