DLL registrieren mit Rückgabewert

Don

Hallo,

ist es möglich eine DLL zu registrieren bzw. deregistrieren und dazu einen Rückgabewert zu erhalten?
Ich möchte wissen, ob die Ausführung des Befehls erfolgreich war oder ob ein Fehler aufgetreten ist.

Habe es mit dem folgenden Code probiert, aber da kommt leider nix zurück. Wird wohl nichts nach StdOut geschrieben.
Alternativen?

AutoIt

ConsoleWrite(_getDOSOutput('regsvr32.exe /u /s '& $sFilepath)& @CRLF)


Func _getDOSOutput($command)
    Local $text = '', $Pid = Run('"' & @ComSpec & '" /c ' & $command, 'C:\', @SW_HIDE, 2 + 4)
    While 1
            $text &= StdoutRead($Pid, False, False)
            If @error Then ExitLoop
            Sleep(10)
    WEnd
    Return StringStripWS($text, 7)
EndFunc   ;==>_getDOSOutput

Alles anzeigen

Viele Grüße

**Kanashius**

Probier mal StderrRead, Fehler werden oft auch dort hineingeschrieben

Micha_he

Ich tippe darauf, das Du den Rückgabewert von @ComSpec (also der neu gestarten Kommandozeile) bekommst.

Versuch dein Run() mal direkt mit 'RegSvr32.exe'. Liegt ja als Exe-Datei direkt im System32-Ordner und daher ist @ComSpec sowieso nicht notwendig !

Edit (zum Errorlevel): RegSvr32 scheint das kein Errorlevel zurückzugeben !

Edit (zur Rückgabe StdoutRead): RegSvr32 gibt Rückgaben in ein eigenes Output-Fenster. Wird schwer dies umzuleiten...

Don

Zitat von Kanashius

Probier mal StderrRead, Fehler werden oft auch dort hineingeschrieben

Hab die Funktion mal entsprechend erweitert, aber es wird immer noch nichts zurückgeschrieben.

AutoIt

Func _getDOSOutput($command)
    Local $etext = ''
    Local $text = '', $Pid = Run('"' & @ComSpec & '" /c ' & $command, 'C:\', @SW_HIDE, 2 + 4)
    While 1
        $text &= StdoutRead($Pid, False, False)
			If @error Then ExitLoop
		Sleep(10)
	WEnd
	While 1
		$etext &= StderrRead($Pid)
			If @error Then ExitLoop
	WEnd
	ConsoleWrite("err"& $etext & @CRLF)
    Return StringStripWS($text, 7)
EndFunc   ;==>_getDOSOutput

Alles anzeigen

**Bitnugger**

Evtl. geht es ja so...

DllReg

AutoIt

;-- TIME_STAMP   2017-02-04 00:08:07


#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_UseX64=n
#AutoIt3Wrapper_Change2CUI=y
#AutoIt3Wrapper_Res_requestedExecutionLevel=requireAdministrator
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


#RequireAdmin


#include <WinAPIReg.au3>


If $CMDLINE[0] <> 2 Then _Usage()


FileChangeDir(@SystemDir)


Global $iRes, $sRes
Switch $CMDLINE[1]
	Case '-u'
		$iRes = _WinAPI_DllUninstall(StringFormat('"%s"', $CMDLINE[2]))
		$sRes = ($iRes = 1) ? 'unregister successful!' : 'unregister failed!'
	Case '-i'
		$iRes = _WinAPI_DllInstall(StringFormat('"%s"', $CMDLINE[2]))
		$sRes = ($iRes = 1) ? 'registration successful!' : 'registration failed!'
	Case Else
		_Usage($CMDLINERAW & ' - Wrong parameters!')
EndSwitch


ConsoleWrite(StringFormat('"%s" - %s', $CMDLINE[2], $sRes) & @CRLF)
Exit


Func _Usage($sMsg = '')
	If $sMsg <> '' Then ConsoleWrite($sMsg & @CRLF & @CRLF)


	ConsoleWrite(@ScriptName & ' -u|-i $sFilePath' & @CRLF)
	ConsoleWrite(@ScriptName & ' -u "C:\Program Files (x86)\AutoIt3\AutoItX\AutoItX3.dll"' & @CRLF)
	ConsoleWrite(@ScriptName & ' -i "C:\Program Files (x86)\AutoIt3\AutoItX\AutoItX3.dll"' & @CRLF)
	Exit 1
EndFunc

Alles anzeigen