Dateien nach Alter/Bearbeitungszeit/Zugriffszeit auflisten.

**autoiter**

Hi Leute,

Ich habe hier mal ein Skript, das Dateien, die ein bestimmtes min/max Alter haben, auflistet. UDF wäre wohl zu viel, auch wenn ich einen entsprechenden Header erstellt habe. Kritik wird gerne angenommen.

EDIT: Thread weiter lesen. Unten finden sich bessere Funktionen!

AutoIt

#include-once


; #FUNCTION# =======================================================================================================================================================
; Title .........: _ListFilesByAge
; AutoIt Version : 3.3.15.0 (Beta)
; Description ...: Lists files with specific age limits
; Syntax.........: _ListFilesByAge( $sSearchFolder [, $iAge = -1 [, $iAgeAndOlder = 1 [, $iSort = 0 [, $sUnit = "d" [, $iRecursiveSearch = 0 [, iFullPath = 1 [, $sFileListFullPath = ""]]]]]]] )
; Parameters ....: $iAge - Name of the service.
;                  $iAgeAndOlder 		- 0 = all files
;                                  	  	  1 = all files older than $iAge
;                                  	  	  2 = all files newer than $iAge
;                  $iSort		 		- 0 = no sorting
;                                  	  	  1 = sort in descending order
;                                  	  	  2 = sort in ascending order
;                  $sUnit		 		- time unit. Valid units of _DateDiff (y = years, m = months, w = weeks, d = days, h = hours, n = minutes, s = seconds)
;                  $iTimestampType		- defines which timestamp is used.
;                                  	  	  0 = creation time
;                                  	  	  1 = last modification time
;                                  	  	  2 = last access time
;                  $iRecursiveSearch	- 0 = only files in given folder
;                                  		  1 = lists files in given folder and files in subfolders
;                  $iFullPath		 	- 0 = file name only
;                                  		  1 = full file path
;                  $sFileListFullPath	- full path to a text file, with all found files. If empty, no textfile ist created.
;
; Return values .: Success - array with all found files.
;                  Failure - error message
;                            Sets @error = 1
; Author ........: autoiter
; Link ..........:
; Example .......:
;~ Local $aReturnedFiles = _ListFilesByAge(@DesktopDir, 5, 1, 2, "d", 1, 0, 1)
;~ If @error Then MsgBox(0, @error, $aReturnedFiles)
;~ _ArrayDisplay($aReturnedFiles)
; ==================================================================================================================================================================


#include <File.au3>
#include <Date.au3>




Func _ListFilesByAge($sSearchFolder, $iAge = -1, $iAgeAndOlder = 1, $iSort = 0, $sUnit = "d", $iTimestampType = 0, $iRecursiveSearch = 0, $iFullPath = 1, $sFileListFullPath = "")
	If Number($iAge) = 0 Then Return SetError(1, "", "Invalid value for $iAge")
	If $iAgeAndOlder <> 0 And $iAgeAndOlder <> 1 And $iAgeAndOlder <> 2 Then Return SetError(1, "", "Invalid value for $iAgeAndOlder")
	If $iSort <> 0 And $iSort <> 1 And $iSort <> 2 Then Return SetError(1, "", "Invalid value for $iSort")
	If $sUnit <> "d" And $sUnit <> "y" And $sUnit <> "m" And $sUnit <> "w" And $sUnit <> "h" And $sUnit <> "m" And $sUnit <> "s" Then Return SetError(1, "", "Invalid unit")
	If $iTimestampType <> 0 And $iTimestampType <> 1 And $iTimestampType <> 2 Then Return SetError(1, "", "Invalid value for $iTimestampType")
	If $iRecursiveSearch <> 0 And $iRecursiveSearch <> 1 Then Return SetError(1, "", "Invalid value for $iRecursiveSearch")
	If $iFullPath <> 0 And $iFullPath <> 1 Then Return SetError(1, "", "Invalid value for $iFullPath")


	If $sFileListFullPath <> "" Then
		Local $hFileOpen = FileOpen($sFileListFullPath, 10)
		If @error Then Return SetError(1, "", "FileOpen error. Couldn't create: " & $sFileListFullPath)
	EndIf


	Local $aFiles = _FileListToArrayRec($sSearchFolder, "*", $FLTAR_FILES, $iRecursiveSearch, 0, $FLTAR_FULLPATH)
	If @error Then
		If $sFileListFullPath <> "" Then
			FileClose($hFileOpen)
			FileDelete($sFileListFullPath)
		EndIf
		Return SetError(1, "", "_FileListToArrayRec error. Error value: " & @error)
	EndIf


	If $iTimestampType = 0 Then
		$iTimestampType = $FT_CREATED
	ElseIf $iTimestampType = 1 Then
		$iTimestampType = $FT_MODIFIED
	ElseIf $iTimestampType = 2 Then
		$iTimestampType = $FT_ACCESSED
	EndIf


	Local $aReturnedFiles[$aFiles[0] + 1][3]


	If $iAgeAndOlder = 0 Then
		$aReturnedFiles = __ListFilesByAge_AllFiles($aFiles, $iAge, $sUnit, $iTimestampType, $aReturnedFiles)
	ElseIf $iAgeAndOlder = 1 Then
		$aReturnedFiles = __ListFilesByAge_OldFiles($aFiles, $iAge, $sUnit, $iTimestampType, $aReturnedFiles)
	ElseIf $iAgeAndOlder = 2 Then
		$aReturnedFiles = __ListFilesByAge_NewFiles($aFiles, $iAge, $sUnit, $iTimestampType, $aReturnedFiles)
	EndIf
	If $aReturnedFiles = 0 Then Return SetError(1, "", "No hits")


	If $iSort = 1 Then
		_ArraySort($aReturnedFiles, 0, 0, 0, 2)
	ElseIf $iSort = 2 Then
		_ArraySort($aReturnedFiles, 1, 0, 0, 2)
	EndIf
	_ArrayColDelete($aReturnedFiles, 2)


	If $iFullPath = 0 Then $aReturnedFiles = __ListFilesByAge_DeletePaths($aReturnedFiles)


	If $sFileListFullPath <> "" Then
		_FileWriteFromArray($hFileOpen, $aReturnedFiles)
		FileClose($hFileOpen)
	EndIf


	Return $aReturnedFiles
EndFunc   ;==>_ListFilesByAge




; #following funtions internal use only# ===========================================================================================================
Func __ListFilesByAge_AllFiles($aFiles, $iAge, $sUnit, $iTimestampType, $aReturnedFiles)
	Local $aFileTime, $sFileTime, $iDateCalc, $iCount = 0
	For $i = 1 To $aFiles[0]
		$aFileTime = FileGetTime($aFiles[$i], $iTimestampType)
		$sFileTime = $aFileTime[0] & "/" & $aFileTime[1] & "/" & $aFileTime[2] & " " & $aFileTime[3] & ":" & $aFileTime[4] & ":" & $aFileTime[5]
		$iDateCalcDay = _DateDiff($sUnit, $sFileTime, _NowCalc())
		$iDateCalcSec = _DateDiff('s', $sFileTime, _NowCalc())
		$aReturnedFiles[$iCount][0] = $aFiles[$i]
		$aReturnedFiles[$iCount][1] = $sFileTime
		$aReturnedFiles[$iCount][2] = $iDateCalcSec
		$iCount += 1
	Next
	ReDim $aReturnedFiles[$iCount][3]
	Return $aReturnedFiles
EndFunc   ;==>__ListFilesByAge_AllFiles


Func __ListFilesByAge_OldFiles($aFiles, $iAge, $sUnit, $iTimestampType, $aReturnedFiles)
	Local $aFileTime, $sFileTime, $iDateCalc, $iCount = 0
	For $i = 1 To $aFiles[0]
		$aFileTime = FileGetTime($aFiles[$i], $iTimestampType)
		$sFileTime = $aFileTime[0] & "/" & $aFileTime[1] & "/" & $aFileTime[2] & " " & $aFileTime[3] & ":" & $aFileTime[4] & ":" & $aFileTime[5]
		$iDateCalcDay = _DateDiff($sUnit, $sFileTime, _NowCalc())
		$iDateCalcSec = _DateDiff('s', $sFileTime, _NowCalc())
		If $iDateCalcDay >= $iAge Then
			$aReturnedFiles[$iCount][0] = $aFiles[$i]
			$aReturnedFiles[$iCount][1] = $sFileTime
			$aReturnedFiles[$iCount][2] = $iDateCalcSec
			$iCount += 1
		EndIf
	Next
	If $iCount = 0 Then Return 0
	ReDim $aReturnedFiles[$iCount][3]
	Return $aReturnedFiles
EndFunc   ;==>__ListFilesByAge_OldFiles


Func __ListFilesByAge_NewFiles($aFiles, $iAge, $sUnit, $iTimestampType, $aReturnedFiles)
	Local $aFileTime, $sFileTime, $iDateCalc, $iCount = 0
	For $i = 1 To $aFiles[0]
		$aFileTime = FileGetTime($aFiles[$i], $iTimestampType)
		$sFileTime = $aFileTime[0] & "/" & $aFileTime[1] & "/" & $aFileTime[2] & " " & $aFileTime[3] & ":" & $aFileTime[4] & ":" & $aFileTime[5]
		$iDateCalcDay = _DateDiff($sUnit, $sFileTime, _NowCalc())
		$iDateCalcSec = _DateDiff('s', $sFileTime, _NowCalc())
		If $iDateCalcDay <= $iAge Then
			$aReturnedFiles[$iCount][0] = $aFiles[$i]
			$aReturnedFiles[$iCount][1] = $sFileTime
			$aReturnedFiles[$iCount][2] = $iDateCalcSec
			$iCount += 1
		EndIf
	Next
	If $iCount = 0 Then Return 0
	ReDim $aReturnedFiles[$iCount][3]
	Return $aReturnedFiles
EndFunc   ;==>__ListFilesByAge_NewFiles


Func __ListFilesByAge_DeletePaths($aReturnedFiles)
	Local $aString
	For $i = 0 To UBound($aReturnedFiles) - 1
		$aString = StringSplit($aReturnedFiles[$i][0], "\")
		$aReturnedFiles[$i][0] = $aString[$aString[0]]
	Next
	Return $aReturnedFiles
EndFunc   ;==>__ListFilesByAge_DeletePaths

Alles anzeigen

**Bitnugger**

Very nice!

Im Header fehlt bei "iFullPath" das "$"

$iAgeAndOlder - 0 = all files .................... ok
$iAgeAndOlder - 1 = all files older than $iAge ... $iDateCalcDay >= $iAge --> all files older than $iAge or the same as $iAge
$iAgeAndOlder - 2 = all files newer than $iAge ... $iDateCalcDay <= $iAge --> all files newer than $iAge or the same as $iAge

Hier muss < 0 hin.. nicht = 0

AutoIt

If Number($iAge) < 0 Then Return SetError(1, "", "Invalid value for $iAge")

Hier fragst du 2x "m" ab... das 2-te m muss ein n sein...

AutoIt

If $sUnit <> "d" And $sUnit <> "y" And $sUnit <> "m" And $sUnit <> "w" And $sUnit <> "h" And $sUnit <> "m" And $sUnit <> "s" Then ConsoleWrite("Invalid unit" & @CRLF)

Hm, die drei Funktionen sind ja fast identisch...

__ListFilesByAge_AllFiles() ; hier wird $iAge als Parameter mit angegeben, in der Funktion aber nicht genutzt...
__ListFilesByAge_OldFiles()
__ListFilesByAge_NewFiles()

somit lässt sich das auch leicht in einer Funktion erledigen, womit du das Script drastisch verkürzen kannst...

__ListFilesByAge()

AutoIt

;-- TIME_STAMP   2017-02-07 10:13:55


#include-once
#include <File.au3>
#include <Date.au3>


; #FUNCTION# =======================================================================================================================================================
; Title .........: _ListFilesByAge
; AutoIt Version : 3.3.15.0 (Beta)
; Description ...: Lists files with specific age limits
; Syntax.........: _ListFilesByAge( $sSearchFolder [, $iAge = -1 [, $iAgeAndOlder = 1 [, $iSort = 0 [, $sUnit = "d" [, $iRecursiveSearch = 0 [, $iFullPath = 1 [, $sFileListFullPath = ""]]]]]]] )
; Parameters ....: $iAge                - Name of the service.
;                  $iAgeAndOlder 		- 0 = all files
;                                  	  	  1 = only files older or same old as $iAge
;                                  	  	  2 = only files newer or same old as $iAge
;                                  	  	  3 = only files older than $iAge
;                                  	  	  4 = only files newer than $iAge
;                  $iSort		 		- 0 = no sorting
;                                  	  	  1 = sort in descending order
;                                  	  	  2 = sort in ascending order
;                  $sUnit		 		- time unit. Valid units of _DateDiff (y = years, m = months, w = weeks, d = days, h = hours, n = minutes, s = seconds)
;                  $iTimestampType		- defines which timestamp is used.
;                                  	  	  0 = creation time
;                                  	  	  1 = last modification time
;                                  	  	  2 = last access time
;                  $iRecursiveSearch	- 0 = only files in given folder
;                                  		  1 = lists files in given folder and files in subfolders
;                  $iFullPath		 	- 0 = file name only
;                                  		  1 = full file path
;                  $sFileListFullPath	- full path to a text file, with all found files. If empty, no textfile ist created.
;
; Return values .: Success - array with all found files.
;                  Failure - error message
;                            Sets the @error flag to non-zero.
; Author ........: autoiter
; Link ..........:
; Example .......:
;~ Local $aReturnedFiles = _ListFilesByAge(@DesktopDir, 5, 1, 2, "d", 1, 0, 1)
;~ If @error Then MsgBox(0, @error, $aReturnedFiles)
;~ _ArrayDisplay($aReturnedFiles)
; ==================================================================================================================================================================
Func _ListFilesByAge($sSearchFolder, $iAge = -1, $iAgeAndOlder = 1, $iSort = 0, $sUnit = "d", $iTimestampType = 0, $iRecursiveSearch = 0, $iFullPath = 1, $sFileListFullPath = "")
	If $iSort < 0 Or $iSort > 2 Then Return SetError(3, "", "Invalid value for $iSort")
	If IsInt($iAge) = 0 Or $iAge < 0 Then Return SetError(1, "", "Invalid value for $iAge")
	If StringReplace("dymwhns", $sUnit, '') And @extended <> 1 Then Return SetError(4, "", "Invalid unit")
	If $iAgeAndOlder < 0 Or $iAgeAndOlder > 4 Then Return SetError(2, "", "Invalid value for $iAgeAndOlder")
	If $iTimestampType <> 0 Or $iTimestampType > 2 Then Return SetError(5, "", "Invalid value for $iTimestampType")
	If $iRecursiveSearch < 0 Or $iRecursiveSearch > 2 Then Return SetError(6, "", "Invalid value for $iRecursiveSearch")


	If $sFileListFullPath <> "" Then
		Local $hFileOpen = FileOpen($sFileListFullPath, 10)
		If @error Then Return SetError(8, "", "FileOpen error. Couldn't create: " & $sFileListFullPath)
	EndIf


	Local $aFiles = _FileListToArrayRec($sSearchFolder, "*", $FLTAR_FILES, $iRecursiveSearch, 0, $FLTAR_FULLPATH)
	Local $iError = @error
	If $iError Then
		If $sFileListFullPath <> "" Then
			FileClose($hFileOpen)
			FileDelete($sFileListFullPath)
		EndIf
		Return SetError(9, "", "_FileListToArrayRec error. Error value: " & $iError)
	EndIf


	Local $aReturnedFiles[$aFiles[0]][3]


	$aReturnedFiles = __ListFilesByAge($aFiles, $iAge, $iAgeAndOlder, $sUnit, $iTimestampType, $aReturnedFiles)


	If $aReturnedFiles = 0 Then Return SetError(10, "", "No hits")


	$iSort = ($iSort = 0) ? -1 : ($iSort = 1) ? 0 : 1
	If $iSort >= 0 Then _ArraySort($aReturnedFiles, $iSort, 0, 0, 2)
	_ArrayColDelete($aReturnedFiles, 2)


	If $iFullPath = 0 Then $aReturnedFiles = __ListFilesByAge_DeletePaths($aReturnedFiles)


	If $sFileListFullPath <> "" Then
		_FileWriteFromArray($hFileOpen, $aReturnedFiles)
		FileClose($hFileOpen)
	EndIf


	Return SetError(0, $aFiles[0], $aReturnedFiles)
EndFunc   ;==>_ListFilesByAge


; #following funtions internal use only# ===========================================================================================================
Func __ListFilesByAge(ByRef $aFiles, $iAge, $iAgeAndOlder, $sUnit, $iTimestampType, $aReturnedFiles)
	Local Static $aFx = [_F0, _F1, _F2, _F3, _F4]
	Local $sFx = $aFx[$iAgeAndOlder], $aFileTime, $sFileTime, $iDateCalc, $iCount = 0


	For $i = 1 To $aFiles[0]
		$aFileTime = FileGetTime($aFiles[$i], $iTimestampType)
		$sFileTime = StringFormat('%s/%s/%s %s:%s', $aFileTime[0], $aFileTime[1], $aFileTime[2], $aFileTime[3], $aFileTime[4], $aFileTime[5])
		$iDateCalcDay = _DateDiff($sUnit, $sFileTime, _NowCalc())
		$iDateCalcSec = _DateDiff('s', $sFileTime, _NowCalc())
		If $sFx($iDateCalcDay, $iAge) Then
			$aReturnedFiles[$iCount][0] = $aFiles[$i]
			$aReturnedFiles[$iCount][1] = $sFileTime
			$aReturnedFiles[$iCount][2] = $iDateCalcSec
			$iCount += 1
		EndIf
	Next


	If $iCount = 0 Then Return 0
	ReDim $aReturnedFiles[$iCount][3]
	Return $aReturnedFiles
EndFunc   ;==>__ListFilesByAge


; all files
Func _F0(ByRef $iDateCalcDay, ByRef $iAge)
	Return True
EndFunc   ;==>_F0
; older or same old files as $iAge
Func _F1(ByRef $iDateCalcDay, ByRef $iAge)
	Return $iDateCalcDay >= $iAge
EndFunc   ;==>_F1
; newer or same old files as $iAge
Func _F2(ByRef $iDateCalcDay, ByRef $iAge)
	Return $iDateCalcDay <= $iAge
EndFunc   ;==>_F2
; older files than $iAge
Func _F3(ByRef $iDateCalcDay, ByRef $iAge)
	Return $iDateCalcDay > $iAge
EndFunc   ;==>_F3
; newer files than $iAge
Func _F4(ByRef $iDateCalcDay, ByRef $iAge)
	Return $iDateCalcDay < $iAge
EndFunc   ;==>_F4


Func __ListFilesByAge_DeletePaths($aReturnedFiles)
	Local $hDll = DllOpen('shlwapi.dll')
	For $i = 0 To UBound($aReturnedFiles) - 1
		$aReturnedFiles[$i][0] = DllCall($hDll, 'none', 'PathStripPathW', 'wstr', $aReturnedFiles[$i][0])[1]
	Next
	DllClose($hDll)
	Return $aReturnedFiles
EndFunc   ;==>__ListFilesByAge_DeletePaths

Alles anzeigen

__ListFilesByAge_Example()

AutoIt

;-- TIME_STAMP   2017-02-07 04:43:08   v 0.1


#include <File.au3>
#include <Array.au3>
#include<_ListFilesByAge.au3>


; #FUNCTION# =======================================================================================================================================================
; Title .........: _ListFilesByAge
; AutoIt Version : 3.3.15.0 (Beta)
; Description ...: Lists files with specific age limits
; Syntax.........: _ListFilesByAge( $sSearchFolder [, $iAge = -1 [, $iAgeAndOlder = 1 [, $iSort = 0 [, $sUnit = "d" [, $iRecursiveSearch = 0 [, $iFullPath = 1 [, $sFileListFullPath = ""]]]]]]] )
; Parameters ....: $iAge			- Name of the service.
;                  $iAgeAndOlder 		- 0 = all files
;                                  	  	  1 = only files older or same old as $iAge
;                                  	  	  2 = only files newer or same old as $iAge
;                                  	  	  3 = only files older than $iAge
;                                  	  	  4 = only files newer than $iAge
;                  $iSort		 	- 0 = no sorting
;                                  	  	  1 = sort in descending order
;                                  	  	  2 = sort in ascending order
;                  $sUnit		 	- time unit. Valid units of _DateDiff (y = years, m = months, w = weeks, d = days, h = hours, n = minutes, s = seconds)
;                  $iTimestampType		- defines which timestamp is used.
;                                  	  	  0 = creation time
;                                  	  	  1 = last modification time
;                                  	  	  2 = last access time
;                  $iRecursiveSearch		- 0 = only files in given folder
;                                  		  1 = lists files in given folder and files in subfolders
;                  $iFullPath		 	- 0 = file name only
;                                  		  1 = full file path
;                  $sFileListFullPath		- full path to a text file, with all found files. If empty, no textfile ist created.
;
; Return values .: Success - array with all found files.
;                  Failure - error message
;                            Sets @error = 1
; Author ........: autoiter
; Link ..........:
; Example .......:
;~ Local $aReturnedFiles = _ListFilesByAge(@DesktopDir, 5, 1, 2, "d", 1, 0, 1)
;~ If @error Then MsgBox(0, @error, $aReturnedFiles)
;~ _ArrayDisplay($aReturnedFiles)
; ==================================================================================================================================================================


Global $aDisplay = ['all files', 'files older or same old as', 'files newer or same old as', 'files older than', 'files newer than']


Global $sSearchFolder = @TempDir, $iAge = 1, $iAgeAndOlder = 2, $iSort = 0, $sUnit = "d", $iRecursiveSearch = 1, $iFullPath = 1, $sFileListFullPath = "m:\FileList.txt"


Global $sDisplay, $aReturnedFiles = _ListFilesByAge($sSearchFolder, $iAge, $iAgeAndOlder, $iSort = 0, $sUnit, $iRecursiveSearch, $iFullPath, $sFileListFullPath)
If @error Then
	ConsoleWrite("!@ " & @TAB & "#Error: " & @error & @CRLF)
Else
	Global $iExtended = @extended, $iUBound = UBound($aReturnedFiles)
	_ArrayAdd($aReturnedFiles, '________________________________________________________________')
	_ArrayDisplay($aReturnedFiles, StringFormat('%i/%i %s %s %s', $iUBound, $iExtended, $aDisplay[$iAgeAndOlder], $iAge, $sUnit))
EndIf

Alles anzeigen

**autoiter**

Hallo @Bitnugger,
Super. Freut mich, dass du dir die Funktion mal genauer angeschaut hast. Danke dir für die Korrekturen

Zitat von autoiter

If Number($iAge) = 0 Then Return SetError(1, "", "Invalid value for $iAge")

Die Prüfung würde ich so lassen. Number() gibt ja u.U. auch bei ("d") eine 0 aus.

Bei $iAgeAndOlder sollte es reichen den gültigen Parameter für alle Dateien auf -1 ändern. Das hatte ich auch so. Als ich aber den Header bearbeitet habe, dachte ich plötzlich, das sieht ja doof aus und habe ohne darüber nachzudenken die -1 in 0 geändert. (extra nur älter und älter und gleich alt usw. ist eher unnötig, oder?)

(EDIT: Das obere habe ich bearbeitet. Da hatte ich mich bei den eigenen Parametern vverhaspelt Mir ist auch gerade aufgefallen, dass bei $iAge noch der Text aus der UDF steht, aus der ich den Header ursprünglich kopiert habe..)

Diskutieren möchte ich aber vor Allem die Kürzung des Codes. Damit habe ich gerechnet, wenn auch nicht von dir.
Da kommen wir nämlich zu meiner Schwäche, dass mir theoretische Grundlagen und Verständnis fehlen.

Ich hatte auch alles in einer Funktion. Dann habe ich mir den Part angeschaut und gedacht, das ist doch ineffizient und habe den schlechten Stil gewählt. In meinem Ansatz frage ich einmal nach dem Wert der Variable $iAgeAndOlder und rufe die entsprechende Funktion auf. Du prüfst 5, 500 oder >50.000 mal den Wert der Variable (gerade bei rekursiver Auflistung).

Stattdessen übergebe ich zwischen den Funktionen aber 2 mal Arrays, wo ich nicht weiß, wie viel Zeit das kostet.

Wolltest du es nur Kürzen, oder sollte man zur besseren Übersicht so kurz halten?
Spielen meine Überlegungen keine praktische Rolle (weil zu kleiner Zeitfaktor)?

**Bitnugger**

Ich habe die Scripts in #Post 2 noch mal stark geändert und noch ein paar Fehler korrigiert...

Zitat von autoiter

Die Prüfung würde ich so lassen und stattdessen den gültigen Parameter für alle Dateien auf -1 ändern.

Die Prüfung hat doch nichts mit dem Parameter für alle Dateien zu tun... $iAge musst du auf 0 setzen, weil 0 Tage ein gülter Wert ist und du sonst ja nicht danach suchen kannst. Die Abfragen habe ich alle noch mal geändert...

Zitat von autoiter

Diskutieren möchte ich aber vor Allem die Kürzung des Codes.

Ja gerne doch...

Zitat von autoiter

Du prüfst 5, 500 oder >50.000 mal den Wert der Variable (gerade bei rekursiver Auflistung).

Jetzt zwar nicht mehr, aber das Abfragen der Variablen geht sicher weitaus schneller, als das Kopieren von großen Arrays... wobei du hier auch wieder das ByRef vergessen hast.

Zitat von autoiter

Wolltest du es nur kürzen, oder sollte man zur besseren Übersicht so kurz halten?

Hihi... nein, nicht nur kürzen... und jetzt nicht lachen, aber ich war auch dabei mir so eine Funktion zu tippern... und dann sehe ich dann dein Script hier.

Seine Programme sollte man nicht nur wegen der besseren Übersicht möglichst kurz halten... denn je größer sie werden, umso zeitraubender wird jede Aktion... das Scrollen im Code, die Fehlersuche, das Starten/Laden... und umso mehr Fehler schleichen sich auch ein. Oft ist es so, dass es mehr Zeit und Hirnschmalz braucht, ein kurzes Programm zu schreiben und man dabei auch schneller in Schräglage geraten kann, da man innerhalb einer kompakten Funktion auf mehr Dinge achten muss, als wenn man für jedes mutierte Problem eine eigene Funktion anlegt. Kurze Programme sind vor allem leichter zu pflegen, lange dafür meist schneller. Ich denke allerdings, dass auch hier die ultimative Grundregel gilt und man den optimalen Punkt in der goldenen Mitte findet.

**autoiter**

Zitat von Bitnugger

Die Prüfung hat doch nichts mit dem Parameter für alle Dateien zu tun... $iAge musst du auf 0 setzen, weil 0 Tage ein gülter Wert ist und du sonst ja nicht danach suchen kannst. Die Abfragen habe alle noch mal geändert...

Ja, ich war heute morgen noch nicht richtig wach. Vor dem ersten Kaffee geht eigentlich nichts. Ich war aber so aufgeregt, dass jemand sich das angesehen hat, dass ich sofort was schreiben wollte
Das war gestern auch ein Schuss aus der Hüfte. Eigentlich hätte ich das erst einmal liegen lassen müssen und mir heute nochmal genau ansehen sollen. Ich bin eindeutig nicht gut genug, dass ich guten, fehlerfreien Code am Stück produziere..

Wirklich witzig, dass du das auch gerade machen wolltest So ist es schön zu sehen, wie du bestimmte Sachen angehen würdest.

Zeitriss

Hi,

AutoIt

$aFileTime = FileGetTime($aFiles[$i], $iTimestampType)
$sFileTime = $aFileTime[0] & "/" & $aFileTime[1] & "/" & $aFileTime[2] & " " & $aFileTime[3] & ":" & $aFileTime[4] & ":" & $aFileTime[5]

Hier sollte besser nochmal überprüft werden ob $aFileTime überhaupt ein Array ist.
Wenn jemand noch am PC Arbeitet, wärend das Script läuft kann es passieren, dass Dateien gelöscht werden [Edit: nur zu verständlichkeit: nicht von deiner Funktion sondern vom Nützer oder anderen Anwendungen] (z.B. wird beim schließen eines Word Dokuments eine versteckte Datei gelöscht).
Da diese zwischenzeitlich gelöschten Dateien immernoch in dem von _FileListToArrayRec() erstellten Array enthalten sind wird trotzdem versucht sie über FileGetTime abzufragen, was dann in Zeile 106/122/141 zu einem Fehler führt.

@Bitnugger:

AutoIt

$aReturnedFiles[$i][0] = DllCall($hDll, 'none', 'PathStripPathW', 'wstr', $aReturnedFiles[$i][0])[1]

Hier würdest du mit RegExpReplace vermutlich deutlich schneller sein, statt ständig DllCall zu benützen.

Beim gesamten Konzept frage ich mich ob eine Funktion, welche Dateien auf einem frei bestimmbaren Zeitraum überprüft nicht deutlich sinnvoller wäre.
Also anstatt den Zeitraum über $iAge und $iAgeAndOlder festzulegen einfach $sStartDate und $sEndDate zu verwenden.
Habe schnell mal hierzu auch mal was zusammen gebastelt, ist allerdings "quick and dirty".

Spoiler anzeigen

AutoIt

Opt("MustDeclareVars", 1)
#include<Array.au3>
#include<Date.au3>
#include<FileConstants.au3>


Global $sFolder = @ScriptDir
Global $sStartDate = "2017/01/01"; Datumformat YYYY/MM/DD[ HH:MM:SS]
Global $sEndDate = _NowCalc(); Datumformat YYYY/MM/DD[ HH:MM:SS]
Global $bRecursive = False
Global $iTimeStep = $FT_MODIFIED ; s. FileGetTime
Global $iSort = 1 ; s. _ArraySort (-1 für keine Sortierung)


Global $aFiles = _FileListBetweenDates($sFolder, $sStartDate, $sEndDate, $bRecursive, $iTimeStep, $iSort)
Switch @error
Case 1
   MsgBox(16, "Fehler", "Die ausgewählte Datei ist kein Ordner oder der Pfad ist fehlerhaft.")
   Exit
Case 2
   MsgBox(16, "Fehler", "Format des Datums fehlerhaft.")
   Exit
Case 3
   MsgBox(16, "Fehler", "Ungültiger Timestamp")
   Exit
EndSwitch
_ArrayDisplay($aFiles, @extended & " Dateien gefunden")


Func _FileListBetweenDates($sFolder, $sStartDate, $sEndDate, $bRec = True, $iTimeStep = 1, $iSort = 0)
   If Not StringInStr(FileGetAttrib($sFolder), "D") Then Return SetError(1)
   If Not StringRegExp($sStartDate, "^\d{4}/\d{2}/\d{2}( \d{2}:\d{2}:\d{2})?$") Then Return SetError(2)
   If Not StringRegExp($sEndDate, "^\d{4}/\d{2}/\d{2}( \d{2}:\d{2}:\d{2})?$") Then Return SetError(2)
   If Not (0 <= $iTimeStep and $iTimeStep <= 2) Then Return SetError(3)
   $sFolder = StringRegExpReplace($sFolder, "\\$", "")
   Local $iDiffRange = _DateDiff("s", $sStartDate, $sEndDate)
   Local $iArraySize = 100000
   Local $aFiles[$iArraySize][2], $iCount, $aSearchFile[256], $sFile, $iDepth, $sTime, $sTime2, $iDiffSec


   $aSearchFile[$iDepth] = FileFindFirstFile($sFolder & "\*")
   While $iDepth >= 0; In dieser Schleife werden alle Dateien/Ordner abgehandelt
	  $sFile = FileFindNextFile($aSearchFile[$iDepth])
	  If @extended and $bRec Then; Wenn es sich um ein Ordner handelt wird in diesem weiter gesucht
		 $iDepth += 1
		 $sFolder &= "\" & $sFile
		 $aSearchFile[$iDepth] = FileFindFirstFile($sFolder & "\*")
	  ElseIf @error Then; Wenn keine Dateien mehr im Ordner vorhanden sind wird das "Handle" Freigegeben
		 FileClose($aSearchFile[$iDepth])
		 $iDepth -= 1
		 $sFolder = StringRegExpReplace($sFolder, "\\[^\\]*$", "")
	  Else; Hier werden die Dateien dem $aFiles hinzugefügt, wenn sie mit den vorgaben übereinstimmen
		 $sTime = FileGetTime($sFolder & "\" & $sFile, $iTimeStep, 1)
		 If @error Then ContinueLoop
		 $sTime2 = StringRegExpReplace($sTime, "(.{4})(.{2})(.{2})(.{2})(.{2})(.{2})", "$1/$2/$3 $4:$5:$6")
		 $iDiffSec = _DateDiff("s", $sStartDate, $sTime2)
		 If $iDiffSec >= 0 and $iDiffSec <= $iDiffRange Then
			If $iCount >= $iArraySize Then
			   $iArraySize += 100000
			   ReDim $aFiles[$iArraySize][2]
			EndIf
			$aFiles[$iCount][0] = $sFolder & "\" & $sFile
			$aFiles[$iCount][1] = $sTime2
			$iCount += 1
		 EndIf
	  EndIf
   Wend


   ReDim $aFiles[$iCount][2]
   If $iSort = 0 or $iSort = 1 Then _ArraySort($aFiles, $iSort, Default, Default, 1)
   Return SetExtended($iCount, $aFiles)
EndFunc

Alles anzeigen

mfg
Zeitriss

**autoiter**

Hey @Bitnugger,
mittlerweile habe ich deine Variante mal genauer angeschaut. Viel cooles Zeug für mich dabei!

StringFormat finde ich sehr schön. Ich benutze das viel zu selten und hatte das nicht auf dem Radar, obwohl ich es bei dir schon oft gesehen habe und auch @Zeitriss mir da auch schon mal damit etwas gezeigt hat. Selbst habe ich das nur auf dem Radar, wenn ich mal führende Nullen möchte

AutoIt

$sFileTime = StringFormat('%s/%s/%s %s:%s', $aFileTime[0], $aFileTime[1], $aFileTime[2], $aFileTime[3], $aFileTime[4], $aFileTime[5])

Die DLL-Variante in der Funktion __ListFilesByAge_DeletePaths($aReturnedFiles) finde ich interessant. Ich habe es mehrfach mit 10.000 Dateien getestet. Die DLL-Variante ist immer etwas schneller gewesen. In dem Fall zwar nicht die Welt, aber dennoch zu bevorzugen. Wie bist du darauf (shlwapi.dll) gekommen?

Am geilsten finde ich aber die Geschichte mit den $iAgeAndOlder Fällen!

AutoIt

Local Static $aFx = [_F0, _F1, _F2, _F3, _F4]
...

Ich hatte keine Ahnung, dass so eine Variante funktionieren kann! Woher hast du das???
Das werde ich mir auf jeden Fall merken.

Bei den Parameter-Prüfungen finde ich neben IsInt das StringReplace interessant.

AutoIt

If StringReplace("dymwhns", $sUnit, '') And @extended <> 1 Then Return SetError(4, "", "Invalid unit")

Streng genommen lässt das noch nicht abgefangene "ym" oder so einen Quatsch zu, aber auch das finde ich im Vergleich zu meiner ewig langen If .. And .. And-Kette eine gewitzte Verbesserung.

Bei den Bedingungen gibt es noch einen Fehler.

AutoIt

If $iTimestampType <> 0 Or $iTimestampType > 2 Then Return SetError(5, "", "Invalid value for $iTimestampType")


; führt immer zu Fehler, wenn $iTimestampType <> 0


If $iTimestampType < 0 Or $iTimestampType > 2 Then Return SetError(5, "", "Invalid value for $iTimestampType")

@Zeitriss
Deine Idee finde ich super. Die Funktion hat sich aus einem Fallbeispiel entwickelt, das @Bitnugger sicher auch vor Augen hatte. Mit frei bestimmbaren Zeiten (und _NowCalc() vllt. als Standardwert) ist es aber definitv besser.
EDIT: Auch cool, dass du _FileListToArrayRec ersetzt hast. Direkt nur aufzunehmen, was hineingehört ist natürlich viel besser.

**Bitnugger**

@Zeitriss

FileGetTime() - ja, stimmt... und wieder ein Fehler weniger!

DllCall() vs StringRegExpReplace() - ja, stimmt... doch mit StringRegExp() geht es sogar noch einen Tacken schneller!

Zitat von Zeitriss

Beim gesamten Konzept frage ich mich ob eine Funktion, welche Dateien auf einem frei bestimmbaren Zeitraum überprüft nicht deutlich sinnvoller wäre.

Ja klar... war auch mein erster Gedanke, als ich das Script von @autoiter sah, dachte ich... oh, super, da hat mir einer die Arbeit abgenommen... aber so ganz dann doch nicht. An meiner Funktion bin ich noch am stricken... dauert noch etwas, bis ich sie fertig habe, was ich hier...

Zitat von Bitnugger

Hihi... nein, nicht nur kürzen... und jetzt nicht lachen, aber ich war auch dabei mir so eine Funktion zu tippern... und dann sehe ich dann dein Script hier.

aber auch schon angedeutet hatte.

Zitat von Zeitriss

Habe schnell mal hierzu auch mal was zusammen gebastelt, ist allerdings "quick and dirty".

Grins... "quick and dirty" - so mag ich es beim Sex... doch was meine Scripte angeht, ist es ein absolutes Tabu...

_FileListBetweenDates() - oh ja, und auch wieder eine gute Idee!

Hm... warum so kompliziert?

Zitat von Zeitriss

If Not (0 <= $iTimeStep and $iTimeStep <= 2) Then Return SetError(3)

If $iTimeStep < 0 Or $iTimeStep > 2 Then Return SetError(3)

Ich werde mir dein "quick and dirty" aber auch noch mal genauer anschauen...

@autoiter

Zitat von autoiter

mittlerweile habe ich deine Variante mal genauer angeschaut. Viel cooles Zeug für mich dabei!

Schön... das freut mich sehr...

Zitat von autoiter

StringFormat finde ich sehr schön. Ich benutze das viel zu selten ...

Das ging mir lange Zeit auch so... bis ich dann den Gedankenblitz bekam, dass sich viele Dinge dramatisch optimieren lassen, wenn man sich die Beschreibungen/Kommentare zu den Funktionen genauer anschaut und diese im Hinterkopf behält!!!

Zitat von autoiter

Die DLL-Variante in der Funktion __ListFilesByAge_DeletePaths($aReturnedFiles) finde ich interessant. Ich habe es mehrfach mit 10.000 Dateien getestet. Die DLL-Variante ist immer etwas schneller gewesen. In dem Fall zwar nicht die Welt, aber dennoch zu bevorzugen. Wie bist du darauf (shlwapi.dll) gekommen?

Durch die Funktion _WinAPI_PathStripPath() ; #include <WinAPIShPath.au3>
Meine Variante...

AutoIt

$aReturnedFiles[$i][0] = DllCall($hDll, 'none', 'PathStripPathW', 'wstr', $aReturnedFiles[$i][0])[1]

ist quasi nur eine verkürzte Form davon... weil in unserem Script ja garantiert ist, dass ein Pfad vorhanden ist, der entfernt werden soll.

AutoIt

; #FUNCTION# ====================================================================================================================
; Author.........: Yashied
; Modified.......: jpm
; ===============================================================================================================================
Func _WinAPI_PathStripPath($sFilePath)
	Local $aRet = DllCall('shlwapi.dll', 'none', 'PathStripPathW', 'wstr', $sFilePath)
	If @error Then Return SetError(@error, @extended, '')


	Return $aRet[1]
EndFunc   ;==>_WinAPI_PathStripPath

Alles anzeigen

Zitat von autoiter

Am geilsten finde ich aber die Geschichte mit den $iAgeAndOlder Fällen!

Darauf gekommen bin ich durch die Funktion FuncName() - womit dann klar war, dass du Funktionsnamen in eine Variable packen kannst... und die Funktion dann mit dieser Variable aufrufen kannst. Der erste User, bei dem ich gesehen habe, das er das auch kennt, war @4ern.

Zitat von autoiter

Streng genommen lässt das noch nicht abgefangene "ym" oder so einen Quatsch zu, ...

AutoIt

If StringReplace("dymwhns", $sUnit, '') And @extended <> 1 Then Return SetError(4, "", "Invalid unit")

Hier hast du einen falschen Gedankengang... StringReplace() liefert in @extended die Anzahl der Ersetzungen... und damit das als Einzeiler funktioniert, mache dann einfach ein If...Then draus... es darf also nur genau 1 Zeichen ersetzt worden sein!

Zitat von autoiter

Bei den Bedingungen gibt es noch einen Fehler.

Oh ja, böder Fehler... <>1... den ich aber schon repariert habe.

Zitat von autoiter

Die Funktion hat sich aus einem Fallbeispiel entwickelt, das @Bitnugger sicher auch vor Augen hatte.

Jeep... stimmt genau!

Meine Funktion hat momentan folgende Parameter...

AutoIt

Func _FileListToArrayRecExt($sFilePath, $sMask = '*', $iReturn = $FLTAR_FILES, $iRecur = $FLTAR_NORECUR, $iSort = $FLTAR_NOSORT, $iReturnPath = $FLTAR_RELPATH, $iDateFlags = $FLTAR_ANY, $sStartDate = '*', $sEndDate = '*', $iDateMode = $FT_MODIFIED)

olfibits

Wie kann ich dieses Format ändern:
C:\Users\***\Desktop\Sia - Never Give Up.mp3|2017/01/15 11:26

also vorallem das mit der pipe in:

2017/01/15 11:26 - C:\Users\***\Desktop\Sia - Never Give Up.mp3

hoffe da bin ich hier jetzt richtig

**Bitnugger**

Zitat von olfibits

Wie kann ich dieses Format ändern:
C:\Users\***\Desktop\Sia - Never Give Up.mp3|2017/01/15 11:26

Zuerst - nein, hier bist du nicht richtig... denn du hast einen fremden Thread gekapert, der mit deiner Frage nichts zu tun hat.

Hier geht es um das Thema "Dateien nach Alter/Bearbeitungszeit/Zugriffszeit auflisten."

Du hättest einen eigenen Thread eröffnen müssen... dazu klickst du einfach auf den Button "Neues Thema".

Zu deiner Frage... das kannst du z. B. so machen:

AutoIt

Local $sString  = 'C:\Users\***\Desktop\Sia - Never Give Up.mp3|2017/01/15 11:26'
Local $sConvert = StringRegExpReplace($sString, '(.+)\|(.+)', '$2 - $1')
ConsoleWrite('$sString  = ' & $sString & @CRLF)
ConsoleWrite('$sConvert = ' & $sConvert & @CRLF)

**Bitnugger**

Zitat von autoiter

; $iTimestampType - defines which timestamp is used.
; 0 = creation time
; 1 = last modification time
; 2 = last access time

Hier hattest du dich übrigens auch vertan...

Richig ist:

$FT_MODIFIED (0) = Last modified (default)
$FT_CREATED (1) = Created
$FT_ACCESSED (2) = Last accessed

**autoiter**

Hi @Bitnugger,

nein, ich hatte das in der Funktion einfach anders umgesetzt. Ich nehme mal an, du hast jetzt nicht nochmal in meinen Code geschaut, sondern schon in deinen gekürzten. Eigentlich ging es ja um das Fallbeispiel, wo jemand wissen wollte welche Dateien sind älter als 14 Tage. Das wollte ich auch als Standardwert und fand es auch schöner wenn ich das nicht nur zum Standardwert mache, sondern es auch als erstes in der Liste steht - reiner Spleen. Dafür war das folgende. Ich hatte die Konstanten benutzt, damit man später noch nachvollziehen kann, was der Quatsch soll

AutoIt

If $iTimestampType = 0 Then
		$iTimestampType = $FT_CREATED
	ElseIf $iTimestampType = 1 Then
		$iTimestampType = $FT_MODIFIED
	ElseIf $iTimestampType = 2 Then
		$iTimestampType = $FT_ACCESSED
	EndIf

**Bitnugger**

So in etwa habe ich mir das vorgestellt...

_FileListToArrayRecExt()

AutoIt

;-- TIME_STAMP   2017-02-09 13:27:52


#include <_FileListToArrayRecExt.au3>


Global $g_sNowCalc = _NowCalc(), $g_sNowDate = _NowDate(), $g_sNowTime = _NowTime()


_Example_1()
_Example_2()
_Example_3()
_Example_4()
_Example_5()
_Example_6()
_Example_7()


Func _Example_1()
	Local $sFolder           = @ScriptDir


	$aFileList = _FileListToArrayRecExt($sFolder)
	_ArrayDisplay($aFileList, '$aFileList - Example_1')
EndFunc


Func _Example_2()
	Local $sFolder           = @ScriptDir
	Local $sStartDate        = _DateAdd('d', -456, $g_sNowCalc)


	$aFileList = _FileListToArrayRecExt($sFolder, $sStartDate)
	_ArrayDisplay($aFileList, '$aFileList - Example_2')
EndFunc


Func _Example_3()
	Local $sFolder           = @ScriptDir
	Local $sStartDate        = '2010/05/03'
	Local $sEndDate          = _DateAdd('d', -123, $g_sNowCalc)


	$aFileList = _FileListToArrayRecExt($sFolder, $sStartDate, $sEndDate)
	_ArrayDisplay($aFileList, '$aFileList - Example_3')
EndFunc


Func _Example_4()
	Local $sFolder           = @SystemDir
	Local $sStartDate        = _DateAdd('d', -456, $g_sNowCalc)
 	Local $sEndDate          = ''
	Local $iDateOpt          = 2
	Local $iTimestampType    = 1
	Local $vMask             = '*.exe;*.dll|*|*'
	Local $iReturn           = $FLTAR_FILES
	Local $iRecur            = -8
	Local $iSort             = BitOR($FLTAR_SORT, $FLTAR_SORTBYTIMESPTAMP, $FLTAR_SORTASCENDING)
	Local $iReturnPath       = $FLTAR_RELPATH


	$aFileList = _FileListToArrayRecExt($sFolder, $sStartDate, $sEndDate, $iDateOpt, $iTimestampType, $vMask, $iReturn, $iRecur, $iSort, $iReturnPath)
	_ArrayDisplay($aFileList, '$aFileList - Example_4')
EndFunc


Func _Example_5()
	Local $sFolder           = @ProgramFilesDir
	Local $sStartDate        = '-6m'
	Local $sEndDate          = '-2d'
	Local $iDateOpt          = 2
	Local $iTimestampType    = 0
	Local $vMask[4][2]       = [[3, ''], [$FLTAR_INCLUDE, '*'], [$FLTAR_EXCLUDE, 'desktop.ini|thumbs.db'], [$FLTAR_EXCLUDE_FOLDERS, 'Microsoft.*|Windows.*|Reference Assemblies']]
	Local $iReturn           = BitOR($FLTAR_FILES, $FLTAR_NOHIDDEN, $FLTAR_NOSYSTEM, $FLTAR_NOLINK)
	Local $iRecur            = $FLTAR_RECUR
	Local $iSort             = BitOR($FLTAR_SORT, $FLTAR_SORTBYTIMESPTAMP)
	Local $iReturnPath       = $FLTAR_RELPATH


	$aFileList = _FileListToArrayRecExt($sFolder, $sStartDate, $sEndDate, $iDateOpt, $iTimestampType, $vMask, $iReturn, $iRecur, $iSort, $iReturnPath)
	_ArrayDisplay($aFileList, '$aFileList - Example_5')
EndFunc


Func _Example_6()
	Local $sFolder           = 'c:\|d:\'
	Local $sStartDate        = _DateAdd('d', -456, $g_sNowCalc)
	Local $sEndDate          = _DateAdd('d', -123, $g_sNowCalc)
	Local $iDateOpt          = 2
	Local $iTimestampType    = 0
	Local $vMask             = '*'
	Local $iReturn           = $FLTAR_FOLDERS
	Local $iRecur            = $FLTAR_NORECUR
	Local $iSort             = $FLTAR_NOSORT
	Local $iReturnPath       = $FLTAR_RELPATH


	$aFileList = _FileListToArrayRecExt($sFolder, $sStartDate, $sEndDate, $iDateOpt, $iTimestampType, $vMask, $iReturn, $iRecur, $iSort, $iReturnPath)
	_ArrayDisplay($aFileList, '$aFileList - Example_6')
EndFunc


Func _Example_7()
	Local $sFolder           = '*'
	Local $sStartDate        = '2000/01/01 00:00:00'
	Local $sEndDate          = ''
	Local $iDateOpt          = 3
	Local $iTimestampType    = 0
	Local $vMask             = '*.exe'
	Local $iReturn           = $FLTAR_FILESFOLDERS
	Local $iRecur            = -1
	Local $iSort             = BitOR($FLTAR_SORT, $FLTAR_SORTBYPATH, $FLTAR_SORTBYFILENAME)
	Local $iReturnPath       = $FLTAR_RELPATH
	Local $sFileListSavePath = _TempFile()


	$aFileList = _FileListToArrayRecExt($sFolder, $sStartDate, $sEndDate, $iDateOpt, $iTimestampType, $vMask, $iReturn, $iRecur, $iSort, $iReturnPath, $sFileListSavePath)
	If UBound($aFileList) Then
		Local $iPID = Run(StringFormat('%s "%s"','notepad.exe', $sFileListSavePath), '', @SW_SHOW)
		ProcessWaitClose($iPID)
		FileDelete($sFileListSavePath)
	EndIf
EndFunc


; #FUNCTION# ====================================================================================================================
; Name ..........: _FileListToArrayRecExt
; Description ...:
; AutoIt Version : 3.3.15.0 (Beta)
; Description ...: Lists files with specific age limits
; Syntax ........: _FileListToArrayRecExt($sFilePath[, $sStartDate = ''[, $sEndDate = ''[, $iDateOpt = 0[, $iTimestamp = 0[, $sMask = '*'[, $iReturn = $FLTAR_FILESFOLDERS[,
;                  $iRecur = $FLTAR_NORECUR[, $iSort = $FLTAR_NOSORT[, $iReturnPath = $FLTAR_RELPATH[, $sFileListSavePath = '']]]]]]]]]])
; Parameters ....: $sFilePath           - Name of the directory to be searched
;                  $sStartDate          - The file is included in the list if $sTimeStamp is equivalent to $sStartDate and/or $sEndDate,
;                  $sEndDate            - where the evaluation is dependent on $iDateOpt
;                                         Format = YYYY/MM/DD[ HH:MM:SS]
;                                         or the relative time in units, which is then subtracted from _NowCalc()
;                                         Valid units of _DateDiff (y = years, m = months, w = weeks, d = days, h = hours, n = minutes, s = seconds)
;                                         Examples: 1y, 27m, 154w, 224d, 1734h, 528295n or 1624736s
;                  $iDateOpt            - [optional] the file is added to the results list if time stamp of the file...
;                                         $DO_ALL .................... ( 0) all files (default)
;                                         $DO_EQU .................... ( 1) =  $sStartDate
;                                         $DO_LSS .................... ( 2) <  $sStartDate
;                                         $DO_GTR .................... ( 3) >  $sStartDate
;                                         $DO_LEQ .................... ( 4) <= $sStartDate
;                                         $DO_GEQ .................... ( 5) >= $sStartDate
;                                         $DO_NEQ .................... ( 6) <> $sStartDate
;                                         The remaining flags are ignored if $sStartDate >= $sEndDate
;                                         $DO_GTR_LSS ................ ( 7) >  $sStartDate And <  $sEndDate
;                                         $DO_GTR_GEQ ................ ( 8) >  $sStartDate And <= $sEndDate
;                                         $DO_GEQ_LEQ ................ ( 9) >= $sStartDate And <= $sEndDate
;                                         $DO_GEQ_LSS ................ (10) >= $sStartDate And <  $sEndDate
;                                         $DO_EQU_EQU ................ (11) =  $sStartDate Or  =  $sEndDate
;                                         $DO_LSS_GTR ................ (12) <  $sStartDate Or  >  $sEndDate
;                                         $DO_???_???
;                  $iTimestampType      - defines which timestamp is used.
;                                         $FT_MODIFIED ............... (  0) = Last modified (default)
;                                         $FT_CREATED ................ (  1) = Created
;                                         $FT_ACCESSED ............... (  2) = Last accessed
;                                         $FT_MODIFIEDANDCREATED ..... (  4) = Last modified and Created
;                                         $FT_MODIFIEDANDACCESSED .... (  8) = Last modified and Last accessed
;                                         $FT_ACCESSEDANDCREATED ..... ( 16) = Last accessed and Created
;                                         $FT_ALLTIMESTAMPS .......... ( 32) = all timestamps
;                  $iReturn             - [optional] Specifies whether to return files, folders or both and omit those with certain attributes
;                                             $FLTAR_FILESFOLDERS .... (  0) - (Default) Return both files and folders
;                                             $FLTAR_FILES ........... (  1) - Return files only
;                                             $FLTAR_FOLDERS ......... (  2) - Return Folders only
;                                         Add one or more of the following to $iReturn to omit files/folders with that attribute
;                                             + $FLTAR_NOHIDDEN ...... (  4) - Hidden files and folders
;                                             + $FLTAR_NOSYSTEM ...... (  8) - System files and folders
;                                             + $FLTAR_NOLINK ........ ( 16) - Link/junction folders
;                                         Add one or more of the following to $iReturn to displayed the attribute and/or size from files/folders
;                                             $FLTAR_FILESIZE ........ ( 32) - Return file size
;                                             $FLTAR_FOLDERSIZE ...... ( 64) - Return folder size
;                                             $FLTAR_FILESFOLDERSIZE . (128) - Return file and folder size
;                                             $FLTAR_TIMESTAMP ....... (256) - Return timestamp
;                                             $FLTAR_COUNT ........... (512) - Return count of files and/or folders
;                  $sMask               - [optional] Filter for result. Multiple filters must be separated by ";"
;                                         Use "|" to separate 3 possible sets of filters: "Include|Exclude|Exclude_Folders"
;                                             Include = Files/Folders to include (default = "*" [all])
;                                             Exclude = Files/Folders to exclude (default = "" [none])
;                                             Exclude_Folders = only used if $iRecur = 1 AND $iReturn <> 2 to exclude defined folders (default = "" [none])
;                                         Alternatively, an array can also be passed...
;                                             $iCount = Number of masks
;                                             $iMask  = $FLTAR_Include = 0, $FLTAR_Exclude = 1, $FLTAR_Exclude_Folders = 2
;                                             $sName  = NAME or PATTERN (*.exe|Microsoft*) of the file or directory to be Include|Exclude
;                                             $aMask[$iCount][0]
;                                             $aMask[$iMask][$sName]
;                                             ...
;                  $iRecur              - [optional] Specifies whether to search recursively in subfolders and to what level
;                                        $FLTAR_NORECUR .............. (  0) - Do not search in subfolders (Default)
;                                        $FLTAR_RECUR ................ (  1) - Search in all subfolders (unlimited recursion)
;                                        Negative integer - Search in subfolders to specified depth
;                  $iSort               - [optional] Sort results in alphabetical and depth order
;                                         $FLTAR_NOSORT .............. (  0) - Not sorted (Default)
;                                         $FLTAR_SORT ................ (  1) - Sorted (by NAME)
;                                         $FLTAR_FASTSORT ............ (  2) - Sorted (by NAME) with faster algorithm (assumes files in folder returned sorted - requires NTFS and not guaranteed)
;                                         $FLTAR_SORTBYPATH .......... (  4) - Sorted (by PATH)
;                                         $FLTAR_SORTBYFILENAME ...... (  8) - Sorted (by PATH)
;                                         $FLTAR_SORTBYTIMESPTAMP .... ( 16) - Sorted (by TIMESPTAMP)
;                                         $FLTAR_SORTDESCENDING ...... (  0) - sort in descending order (Default) / must not be specified (because value = 0)
;                                         $FLTAR_SORTASCENDING ....... ( 32) - sort in ascending order
;
;                  $iReturnPath         - [optional] Specifies displayed path of results
;                                         $FLTAR_NOPATH .............. (  0) - File/folder name only
;                                         $FLTAR_RELPATH ............. (  1) - Relative to initial path (Default)
;                                         $FLTAR_FULLPATH ............ (  2) - Full path included
;                  $sFileListSavePath   - Complete path to a text file in which the search results are to be stored. If it is empty, no text file is created.
;
; Return values .: Success - Depending on the parameters passed, a 1D / 2D array (with 1, 2 or 3 columns) with all found files.
;                            $aArray[[COUNT, ]NAME[, SIZE[, TIMESTAMP]] / COUNT, SIZE and TIMESTAMP are optional
;                            and file count in @extended
;                  Failure - error message
;                            and sets the @error flag to non-zero.
; Related .......: _FileListToArray, _FileListToArrayRec
; Author ........: Bitnugger, ?
; Credits........: autoiter, Zeitriss, Melba23 (for _FileListToArrayRec)
; Link ..........: https://autoit.de/
; Example .......: YES
; ==================================================================================================================================================================

Alles anzeigen

**autoiter**

Hey @Bitnugger,
die Parameter betrachtend, würde ich sagen, da bleiben keine Wünsche offen, wenn du fertig bist

PS: Nur ein Vorschlag für _FileListToArrayRecExt. Wahrscheinlich ist es sauberer, wenn du das ursprüngliche Ausgeben einer Textdatei streichst und wirklich nur die Dateien in ein Array listest (so wie es in den anderen _FileListToArray-Funktionen auch ist).

**Bitnugger**

Zitat von autoiter

PS: Nur ein Vorschlag ...

Stimmt, denn es heißt ja "...ToArray...".

**AspirinJunkie**

Es ist natürlich ein Ansatz für jeden speziellen Suchfall eine spezielle Funktion zu schreiben.
Eine Alternative hierzu wäre es wenn man die Dateisuche einmal komplett schreibt und die speziellen Suchkriterien derart flexibel gestaltet, dass der Nutzer den speziellen Teil selbst schreiben/austauschen kann.

Hier mal als Beispiel wie ich das meine:

AutoIt

#include <Array.au3>
#include <Date.au3>


; Alle Dateien im Windows-Verzeichnis welche jünger als 14 Tage sind:
$a_List = _listFilesFlexible("C:\Windows\System32", cb_MyFunc, 1)
_ArrayDisplay($a_List)




; Callback-Funktion welche True zurückgibt, wenn eine Datei den Anforderungen entspricht und False wenn nicht
; Konkrete Prüfung hier: Test ob Datei jünger als 14 Tage ist:
Func cb_MyFunc(Const $s_Path)
	Local Static $Now = _NowCalc()
	Return _DateDiff("D", StringRegExpReplace(FileGetTime($s_Path, 0, 1), "(\d{4})(\d{2})(\d{2}).+", "$1/$2/$3"), $Now) < 14 _
			 ? True : False
EndFunc   ;==>cb_MyFunc








; #FUNCTION# ======================================================================================
; Name ..........: _listFilesFlexible()
; Description ...: Findet Dateien und/oder Ordner in einem Verzeichnisbaum
; Syntax ........: _listFilesFlexible($sSD, [Const $sPat = '', [Const $iF = 3, [Const $iSSFlag = 2]]])
; Parameters ....: $sSD           - Suchort (mehrere Suchorte durch | trennen)
;                 Const $sPat    - [optional] regulärer Ausdruck für zu findende Datei/Ordnernamen (default:'') oder Verweis auf Funktion für komplexeres Matching
;                  Const $iF      - [optional] 1=nur Dateien, 2=nur Ordner, 3=Dateien+Ordner (default:3)
;                  Const $iSSFlag - [optional] 0=Rückgabearray mit Anzahl Elemente in $Array0, 2=Rückgabearray ohne Anzahl Elemente
; Return values .: Success - Return Array with Matches
;                  Failure - Return "" and set @error
; Author ........: AspirinJunkie
; Remarks .......: Funktionsweise ist iterativ - nicht rekursiv
; Example .......: Yes
;                  #include <Array.au3>
;                  $aTmp = _listFilesFlexible(@WindowsDir & '|' & @ProgramFilesDir, "^Temp$", 2)
;                  _ArrayDisplay($aTmp)
; =================================================================================================
Func _listFilesFlexible($sSD, Const $sPat = '', Const $iF = 3, Const $iSSFlag = 2)
	;by AspirinJunkie
	Local $sRet = "", $sSubD = ""
	For $i In StringSplit($sSD, '|', 2)
		If Not (StringRight($i, 1) == '\') Then $i &= "\"
		If Not FileExists($i) Then Return SetError(2, 0, "")
		$sSubD &= '|' & $i
	Next
	Local $FFFF, $FFNF, $sDir, $iC
	Local $aD, $hDLL = DllOpen('kernel32.dll')
	Local $p_F = DllCall($hDLL, "ptr", "GetProcAddress", "handle", DllCall($hDLL, "handle", "GetModuleHandleW", "wstr", "kernel32.dll")[0], "str", "GetFileAttributesW")[0] ; get the function address of GetModuleHandleW
	If Not ($iF = 3 Or $iF = 1 Or $iF = 2) Then Return SetError(3, 0, "")


	If $sPat = "" Then
		Do
			$iC = StringInStr($sSubD, '|', 2, -1)
			If @error Or $iC = 0 Then ExitLoop
			$iC = StringLen($sSubD) - $iC
			$sDir = StringRight($sSubD, $iC)
			$sSubD = StringTrimRight($sSubD, $iC + 1)
			$FFFF = FileFindFirstFile($sDir & '*')
			If $FFFF <> -1 Then
				Do
					$FFNF = FileFindNextFile($FFFF)
					If @error Then ExitLoop
					If @extended Then
						If BitAND($iF, 2) Then $sRet &= $sDir & $FFNF & '|'
						If Not BitAND(DllCallAddress('dword', $p_F, 'wstr', $sDir & $FFNF)[0], 0x400) Then $sSubD &= '|' & $sDir & $FFNF & "\"
					ElseIf BitAND($iF, 1) Then
						$sRet &= $sDir & $FFNF & '|'
					EndIf
				Until 0
				FileClose($FFFF)
			EndIf
		Until 0
	Else
		Do
			$iC = StringInStr($sSubD, '|', 2, -1)
			If @error Or $iC = 0 Then ExitLoop
			$iC = StringLen($sSubD) - $iC
			$sDir = StringRight($sSubD, $iC)


			$sSubD = StringTrimRight($sSubD, $iC + 1)
			$FFFF = FileFindFirstFile($sDir & '*')
			If $FFFF <> -1 Then
				Do
					$FFNF = FileFindNextFile($FFFF)
					If @error Then ExitLoop
					If @extended Then
						If BitAND($iF, 2) Then
							If IsFunc($sPat) Then
								If $sPat($sDir & $FFNF) Then $sRet &= $sDir & $FFNF & '|'
							ElseIf StringRegExp($FFNF, $sPat) Then
								$sRet &= $sDir & $FFNF & '|'
							EndIf
						EndIf
						If BitAND(DllCallAddress('dword', $p_F, 'wstr', $sDir & $FFNF)[0], 0x400) Then ContinueLoop
						$sSubD &= '|' & $sDir & $FFNF & "\"
					ElseIf BitAND($iF, 1) Then
						If IsFunc($sPat) Then
							If $sPat($sDir & $FFNF) Then $sRet &= $sDir & $FFNF & '|'
						ElseIf StringRegExp($FFNF, $sPat) Then
							$sRet &= $sDir & $FFNF & '|'
						EndIf
					EndIf
				Until 0
				FileClose($FFFF)
			EndIf
		Until 0
	EndIf


	DllClose($hDLL)
	Return StringSplit(StringTrimRight($sRet, 1), '|', $iSSFlag)
EndFunc   ;==>_listFilesFlexible

Alles anzeigen

Die Funktion ist so aufgebaut, dass eine benutzerdefinierte Funktion als Parameter übergeben werden kann welche dann jeweils alle gefundenen Dateien ganz nutzerspezifisch prüft.

**Bitnugger**

Zitat von AspirinJunkie

Hier mal als Beispiel wie ich das meine:

Oh ja, das ist ein sehr interessanter Ansatz... doch leider funktioniert dein Beispiel nicht.

Nachdem ich "#include <Array.au3>" hinzugefügt hatte, lief es zwar, doch das Ergebnis-Array ist leer!

**autoiter**

Irre gutes Design @AspirinJunkie,
das funktioniert hervorragend und ist super schnell angepasst. Sehr schönes Anschauungsmaterial. Das muss ich mir auf jeden Fall merken. Danke dir!
(Auch schon wieder ein Funktionsaufruf in einer Variable. So etwas ist mir ewig nie aufgefallen ).

@Bitnugger ändere einfach mal die Callback-Funktion. Vielleicht hast du da einfach keine Datei jünger als 14 Tage? Such vllt. mal Stringinstring ".dll"

**AspirinJunkie**

Zitat von Bitnugger

doch leider funktioniert dein Beispiel nicht.

Nachdem ich "#include <Array.au3>" hinzugefügt hatte, lief es zwar, doch das Ergebnis-Array ist leer!

Das vergessene Array.au3 hatte ich vergessen und später hinzugefügt.
Bei dem leeren Array vermute ich, wie autoiter, dass keine Datei den Anforderungen entspricht.
Einfach mal z.B. den Zeitraum auf z.B. 100 Tage verlängern.
Hier auch mal mit der rekursiven Schwesterfunktion dazu:

AutoIt

#include <Array.au3>
#include <Date.au3>


; Alle Dateien im Windows-Verzeichnis welche jünger als 14 Tage sind:
$a_List = _listFilesFlexibleRec("C:\Windows\System32", cb_MyFunc, 1)
_ArrayDisplay($a_List)




; Callback-Funktion welche True zurückgibt, wenn eine Datei den Anforderungen entspricht und False wenn nicht
; Konkrete Prüfung hier: Test ob Datei jünger als 100 Tage ist:
Func cb_MyFunc(Const $s_Path)
	Local Static $Now = _NowCalc()
	Return _DateDiff("D", StringRegExpReplace(FileGetTime($s_Path, 0, 1), "(\d{4})(\d{2})(\d{2}).+", "$1/$2/$3"), $Now) < 100
EndFunc   ;==>cb_MyFunc






; #FUNCTION# ====================================================================================================================
; Name...........: _listFilesFlexibleRec
; Description ...: Gibt ein Array mit Dateien bzw. Unterordnern im gesamten Verzeichnisbaum zurück
; Syntax.........: _listFilesFlexibleRec($sSD, [$sPat = '', [$iF = 0, [$flgSS = 2]])
; Parameters ....: $sSD   - Startverzeichnis (mehrere Verzeichnisse durch | trennen)
;                  $sPat  - Optional: Pattern zur Filterung mit regulären Ausdrücken oder Verweis auf Funktion für komplexeres Matching
;                  $iF    - Optional: Flag ob nur Dateien, Ordner oder beides gesucht werden sollen
;                      	|$iF=3(Default) Gibt beides zurück
;                  		|$iF=1 Gibt nur Dateien zurück
;                  		|$iF=2 Gibt nur Ordner zurück
;                  $flgSS - Art der Rückgabe (Siehe StringSplit()-Funktion)
;                  $bS    - interner Rekursionsparameter - nicht verändern!
; Return values .: @Error: 1 = Startverzeichnis existiert nicht.
;                  		|2 = ungültiger Wert für $iF
; Author ........: AspirinJunkie
; Modified.......: 05.07.2016
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; Note ..........: basiert auf einem rekursiven Ansatz
; ===============================================================================================================================
Func _listFilesFlexibleRec($sSD, Const $sPat = '', Const $iF = 3, Const $flgSS = 2, Const $bS = True)
	; By AspirinJunkie
	Local $FFFF, $FFNF, $aD
	Local Static $sRet, $hDLL, $p_F
	If $bS Then
		$hDLL = DllOpen("kernel32.dll")
		$p_F = DllCall($hDLL, "ptr", "GetProcAddress", "handle", DllCall($hDLL, "handle", "GetModuleHandleW", "wstr", "kernel32.dll")[0], "str", "GetFileAttributesW")[0] ; get the function address of GetModuleHandleW
		If Not ($iF = 3 Or $iF = 1 Or $iF = 2) Then Return SetError(1, DllClose($hDLL), "")
	EndIf
	For $i In StringSplit($sSD, "|", 2)
		If Not (StringRight($i, 1) == '\') Then $i &= "\"
		If Not FileExists($i) Then ContinueLoop
		$FFFF = FileFindFirstFile($i & '*')
		If $FFFF <> -1 Then
			If $sPat = "" Then  ; falls keine Filterung gewünscht auf schnelleres Matching ausweichen
				Do
					$FFNF = FileFindNextFile($FFFF)
					If @error Then ExitLoop
					If @extended Then
						If BitAND($iF, 2) Then $sRet &= $i & $FFNF & "|"
						If Not BitAND(DllCallAddress('dword', $p_F, 'wstr', $i & $FFNF)[0], 0x400) Then _listFilesFlexibleRec($i & $FFNF, $sPat, $iF, $flgSS, False)
					ElseIf BitAND($iF, 1) Then
						$sRet &= $i & $FFNF & '|'
					EndIf
				Until 0
			Else
				Do
					$FFNF = FileFindNextFile($FFFF)
					If @error Then ExitLoop
					If @extended Then
						If BitAND($iF, 2) Then
							If IsFunc($sPat) Then
								If $sPat($i & $FFNF) Then $sRet &= $i & $FFNF & "|"
							ElseIf StringRegExp($FFNF, $sPat) Then
								$sRet &= $i & $FFNF & "|"
							EndIf
						EndIf
						If BitAND(DllCallAddress('dword', $p_F, 'wstr', $i & $FFNF)[0], 0x400) Then ContinueLoop
						_listFilesFlexibleRec($i & $FFNF, $sPat, $iF, $flgSS, False)
					ElseIf BitAND($iF, 1) Then
						If IsFunc($sPat) Then
							If $sPat($i & $FFNF) Then $sRet &= $i & $FFNF & '|'
						ElseIf StringRegExp($FFNF, $sPat) Then
							$sRet &= $i & $FFNF & '|'
						EndIf
					EndIf
				Until 0
			EndIf
			FileClose($FFFF)
		EndIf
	Next
	If $bS Then
		DllClose($hDLL)
		Local $aRet = StringSplit(StringTrimRight($sRet, 1), "|", $flgSS)
		$sRet = ""
		Return $aRet
	EndIf
EndFunc   ;==>_listFilesFlexibleRec

Alles anzeigen

Zitat von autoiter

Auch schon wieder ein Funktionsaufruf in einer Variable. So etwas ist mir ewig nie aufgefallen

Seit es das Feature gibt (kam erst relativ spät) nutze ich es exzessiv.
Damit wird deutlich dynamischerer Code ermöglicht und daher gibt es eine Vielzahl von Einsatzzwecken hierfür.
Schau z.B. mal in die DynArray-UDF - die ist voll von Anwendungsfällen für Funktionsvariablen.
Auch für mathematische Kurvendiskussion lässt sich dies ziemlich sinnvoll einsetzen.

**Bitnugger**

Zitat von autoiter

@Bitnugger ändere einfach mal die Callback-Funktion. Vielleicht hast du da einfach keine Datei jünger als 14 Tage? Such vllt. mal Stringinstring ".dll"

Ja danke - stimmt... bin ich vorhin auch selbst drauf gekommen... habe die Funktion cb_MyFunc ein wenig umgestrickt, damit man $iDiff und $s_Path sehen kann.

AutoIt

; Callback-Funktion welche True zurückgibt, wenn eine Datei den Anforderungen entspricht und False wenn nicht
; Konkrete Prüfung hier: Test ob Datei jünger als 100 Tage ist:
Func cb_MyFunc(Const $s_Path)
	Local Static $Now = _NowCalc(), $iDiff, $sColor, $iMin = 100
	$iDiff = _DateDiff("D", StringRegExpReplace(FileGetTime($s_Path, 0, 1), "(\d{4})(\d{2})(\d{2}).+", "$1/$2/$3"), $Now)
	$sColor = ($iDiff < $iMin) ? '+' : '!'
	ConsoleWrite(StringFormat('%s $iDiff = %6i \t %s\r\n', $sColor, $iDiff, _WinAPI_ExpandEnvironmentStrings($s_Path)))
	Return ($iDiff < $iMin) ? True : False
EndFunc   ;==>cb_MyFunc

Doch was ich noch nicht verstehe, warum im erstes Ergebnis die Umgebungsvariable nicht expandiert wurde...
! 147 C:\Windows\System32\%TMP%

TMP.png

Habe dann die Zeile geändert... dann passt es.

AutoIt

;Local $aRet = StringSplit(StringTrimRight($sRet, 1), "|", $flgSS)
Local $aRet = StringSplit(StringTrimRight(_WinAPI_ExpandEnvironmentStrings($sRet), 1), "|", $flgSS)