Wenn ordner nicht vorhanden, zum nächstern springen

DerSchatten

Folgendes Script:

Code

Func zurueck()


	Local $knummer = GUICtrlRead($input_sknummer)
	$knummer = $knummer - 1
	Local $ordnerpfad = "\\Brzg.local\shares\PIV\KONF\BRZ\PAR\" & $knummer


	GUICtrlSetData($input_sknummer,$knummer)
	If FileExists($ordnerpfad) Then read()


EndFunc

Alles anzeigen

Auf einem netzlaufwerk existieren Ordner die aus Nummern bestehen.
Mittels eines Button möchte ich nun einen Ordner vorwärts bzw. Rückwerts blättern.
Es sollen jedoch nur die Ordner angezeigt werden die auch wirklich existieren. Alle anderen Nummern sollen übersprungen werden.

Das Script funktioniert soweit, jedoch springt er nicht direkt zu dem existierenden Ordner.

Kann mir da jemand helfen?

**Oscar**

Zitat von DerSchatten

Das Script funktioniert soweit, jedoch springt er nicht direkt zu dem existierenden Ordner.

Das Script funktioniert garantiert nicht! Also bitte das ganze Script posten.
Und "jedoch springt er nicht direkt zu dem existierenden Ordner" ist keine Fehlerbeschreibung! Wer springt da wohin und warum?

DerSchatten

C

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <EditConstants.au3>
#include <ColorConstants.au3>


FileInstall(@ScriptDir&"\logo.jpg", @TempDir & "\logo.jpg") ; Datei wird mit eingebunden, und in das Temp verzeichnis kopiert.


GUICreate("Konfigurationsdaten anzeigen", 630, 544)
GUICtrlCreatePic(@ScriptDir&"\logo.jpg", 160, 16, 463, 48)


HotKeySet("{-}", "zurueck")
HotKeySet("{+}", "vor")
HotKeySet("{RETURN}", "read")


GUISetFont (20,700)
GUICtrlCreateLabel("Konfigurationsübersicht", 120, 20, 350, 30, $SS_RIGHT)
GUISetFont (10,0)


;Links
GUICtrlCreateLabel("Konfigurationsnummer:", 10, 80, 150, 16, $SS_RIGHT)
$input_knummer = GUICtrlCreateInput("", 166, 77, 160, 22, $ES_READONLY)
GUICtrlSetColor(-1, $COLOR_RED)
GUICtrlCreateLabel("letzte Generierung:", 10, 105, 150, 16, $SS_RIGHT)
$input_generierung = GUICtrlCreateInput("", 166, 102, 160, 22, $ES_READONLY)
GUICtrlCreateLabel("Verantwortlicher:", 10, 130, 150, 16, $SS_RIGHT)
$input_verantwortlicher = GUICtrlCreateInput("", 166, 127, 160, 22, $ES_READONLY)
GUICtrlSetColor(-1, $COLOR_BLUE)
GUICtrlCreateLabel("Dienststellenkennz. / EB:", 10, 155, 150, 16, $SS_RIGHT)
$input_dienststelle = GUICtrlCreateInput("", 166, 152, 160, 22, $ES_READONLY)
GUICtrlCreateLabel("Zimmer:", 10, 180, 150, 16, $SS_RIGHT)
$input_zimmer = GUICtrlCreateInput("", 166, 177, 160, 22, $ES_READONLY)


;Rechts
GUICtrlCreateLabel("Home-Server:", 334, 80, 120, 16, $SS_RIGHT)
$input_home = GUICtrlCreateInput("", 460, 77, 160, 22, $ES_READONLY)
GUICtrlCreateLabel("DHCP:", 334, 105, 120, 16, $SS_RIGHT)
$check_dhcp = GUICtrlCreateCheckbox("", 460, 105, 16, 16)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreateLabel("TCP/IP-Adresse:", 334, 130, 120, 16, $SS_RIGHT)
$input_ip = GUICtrlCreateInput("", 460, 127, 160, 22, $ES_READONLY)
GUICtrlCreateLabel("Gateway:", 334, 155, 120, 16, $SS_RIGHT)
$input_gateway = GUICtrlCreateInput("", 460, 152, 160, 22, $ES_READONLY)
GUICtrlCreateLabel("SubNetz:", 334, 180, 120, 16, $SS_RIGHT)
$input_subnetz = GUICtrlCreateInput("", 460, 177, 160, 22, $ES_READONLY)


GUICtrlCreateGraphic(10, 220, 610, 2, $SS_SUNKEN)


;Links
GUICtrlCreateLabel("APC-Typ:", 10, 240, 150, 16, $SS_RIGHT)
$input_apctyp = GUICtrlCreateInput("", 166, 237, 160, 22, $ES_READONLY)


;Rechts
GUICtrlCreateLabel("APC-Subtyp:", 334, 240, 120, 16, $SS_RIGHT)
$input_apcsubtyp = GUICtrlCreateInput("", 460, 237, 160, 22, $ES_READONLY)
GUICtrlCreateLabel("Gerätetyp:", 334, 265, 120, 16, $SS_RIGHT)
$input_hardware = GUICtrlCreateInput("", 460, 262, 160, 22, $ES_READONLY)


GUICtrlCreateGraphic(10, 305, 610, 2, $SS_SUNKEN)


;Links
GUICtrlCreateLabel("Betriebssystem:", 10, 325, 150, 16, $SS_RIGHT)
$input_betriebssystem = GUICtrlCreateInput("", 166, 322, 160, 22, $ES_READONLY)
GUICtrlCreateLabel("PIV Install-Test:", 10, 350, 150, 16, $SS_RIGHT)
$check_testinstall = GUICtrlCreateCheckbox("", 166, 350, 16, 16)
GUICtrlSetState(-1, $GUI_DISABLE)


;Rechts
GUICtrlCreateLabel("UID-PW:", 334, 325, 120, 16, $SS_RIGHT)
$check_uidpw = GUICtrlCreateCheckbox("", 460, 325, 16, 16)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlCreateLabel("Verschlüsselt:", 334, 350, 120, 16, $SS_RIGHT)
$check_pba = GUICtrlCreateCheckbox("", 460, 350, 16, 16)
GUICtrlSetState(-1, $GUI_DISABLE)


GUICtrlCreateGraphic(10, 390, 610, 2, $SS_SUNKEN)


GUICtrlCreateLabel("Konfignummer:", 10, 481, 150, 16, $SS_RIGHT)
$input_sknummer = GUICtrlCreateInput("42292", 166, 480, 50, 21, $ES_NUMBER)
GUICtrlSetLimit(-1, 5)


Local $button_ok = GUICtrlCreateButton("Suchen", 220, 479, 80, 23)


Local $button_zurueck = GUICtrlCreateButton("<", 320, 479, 20, 23)
Local $button_vor = GUICtrlCreateButton(">", 350, 479, 20, 23)


Local $button_beenden = GUICtrlCreateButton("Beenden", 500, 480, 96, 23)


GUISetState(@SW_SHOW)


While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
			Case $button_ok
				read()
			Case $button_zurueck
				zurueck()
			Case $button_vor
				vor()
			Case $button_beenden
				Exit
        EndSwitch
WEnd


Func zurueck()


	Local $knummer = GUICtrlRead($input_sknummer)
	$knummer = $knummer - 1
	Local $ordnerpfad = "\\Brzg.local\shares\PIV\KONF\BRZ\PAR\" & $knummer


	GUICtrlSetData($input_sknummer,$knummer)
	If FileExists($ordnerpfad) Then
		read()
	Else
		$knummer = $knummer - 1
	EndIf


EndFunc	


Func vor()


EndFunc


Func read()


	Global $datei = "\\Brzg.local\shares\PIV\KONF\BRZ\PAR\" & GUICtrlRead($input_sknummer) & "\CONFIG.VRS"


	Global $s_knummer = IniRead($datei, "Konfiguration", "PC#", '')
	Global $s_verantwortlicher = IniRead($datei, "Konfiguration", "Benutzer", '')
	Global $s_dienststelle = IniRead($datei, "Konfiguration", "DstTyp", '')
	Global $s_abteilung = IniRead($datei, "Konfiguration", "Eb", '')
	Global $s_zimmer = IniRead($datei, "Konfiguration", "Raum", '')


	GUICtrlSetData($input_knummer, $s_knummer)
	GUICtrlSetData($input_verantwortlicher, $s_verantwortlicher)
	GUICtrlSetData($input_dienststelle, $s_dienststelle & " / " & $s_abteilung)
	GUICtrlSetData($input_zimmer, $s_zimmer)


	Global $s_generierung = IniRead($datei, "Konfiguration", "DatConfig", '')
	Global $s_home = IniRead($datei, "Novell", "NHS", '')
	Global $s_dhcp = IniRead($datei, "Konfiguration", "DHCP", '')
	Global $s_ip = IniRead($datei, "Konfiguration", "Tcpip", '')
	Global $s_gateway = IniRead($datei, "Konfiguration", "TcpipGw", '')
	Global $s_subnetz = IniRead($datei, "Konfiguration", "TcpipMask", '')


	GUICtrlSetData($input_generierung, $s_generierung)
	GUICtrlSetData($input_home, $s_home)
	GUICtrlSetState($check_dhcp, BitOr($GUI_UNCHECKED, $GUI_DISABLE)) 
	If $s_dhcp = "J" Then GUICtrlSetState($check_dhcp, BitOr($GUI_CHECKED, $GUI_DISABLE)) 
	GUICtrlSetData($input_ip, $s_ip)
	GUICtrlSetData($input_gateway, $s_gateway)
	GUICtrlSetData($input_subnetz, $s_subnetz)


	Global $s_apctyp = IniRead($datei, "Konfiguration", "PcTyp", '')
	Global $s_apcsubtyp = IniRead($datei, "Konfiguration", "PcSubTyp", '')


	GUICtrlSetData($input_apctyp, $s_apctyp)
	GUICtrlSetData($input_apcsubtyp, $s_apcsubtyp)


	Global $s_betriebssystem = IniRead($datei, "Konfiguration", "OS", '')
	Global $s_testinstall = IniRead($datei, "Konfiguration", "TestInstall", '')


	GUICtrlSetData($input_betriebssystem, $s_betriebssystem)
	GUICtrlSetState($check_testinstall, BitOr($GUI_UNCHECKED, $GUI_DISABLE)) 
	If $s_testinstall = "J" Then GUICtrlSetState($check_testinstall, BitOr($GUI_CHECKED, $GUI_DISABLE)) 


	Global $s_uidpw = IniRead($datei, "Konfiguration", "UID-PW", '')
	Global $s_pba = IniRead($datei, "Konfiguration", "VERSCHL", '')


	GUICtrlSetState($check_uidpw, BitOr($GUI_UNCHECKED, $GUI_DISABLE)) 
	If $s_uidpw = "J" Then GUICtrlSetState($check_uidpw, BitOr($GUI_CHECKED, $GUI_DISABLE)) 
	GUICtrlSetState($check_pba, BitOr($GUI_UNCHECKED, $GUI_DISABLE)) 
	If $s_pba = "J" Then GUICtrlSetState($check_pba, BitOr($GUI_CHECKED, $GUI_DISABLE)) 


	subtyp_tabelle(GUICtrlRead($input_apcsubtyp))


EndFunc


Func subtyp_tabelle($wert)
	$o_Typ = ObjCreate("Scripting.Dictionary")
	$o_Typ("11") = "Dell Latitude E6530"
	$o_Typ("12") = "Lenovo ThinkCentre M92"
	$o_Typ("13") = "Dell Latitude E7240"
	$o_Typ("14") = "Lenovo ThinkPad T440"
	$o_Typ("15") = "Lenovo ThinkCentre M83"
	$o_Typ("16") = "Lenovo ThinkPad T540p"
	$o_Typ("17") = "Lenovo Thinkpad T450"
	$o_Typ("18") = "Dell Latitude E7250"
	$o_Typ("19") = "HP EliteBook 820 G3"
	$o_Typ("20") = "HP EliteBook 850 G3"
	$o_Typ("21") = "Lenovo Thinkpad T560"
	$o_Typ("22") = "Lenovo Ultrabook T460"
	$o_Typ("23") = "IBM Thinkpad 360CSE"
	$o_Typ("24") = "IBM Thinkpad 370C"
	$o_Typ("26") = "IBM Thinkpad 560E"
	$o_Typ("27") = "IBM Thinkpad 600E"
	$o_Typ("38") = "IBM Thinkpad T40"
	$o_Typ("55") = "HP D530 CMT"
	$o_Typ("56") = "HP D530 CMT"
	$o_Typ("57") = "HP DC7100"
	$o_Typ("58") = "HP DC7100CMT"
	$o_Typ("60") = "HP DC7600CMT"
	$o_Typ("61") = "HP DC7700 CMT"
	$o_Typ("62") = "HP DC7800CMT"
	$o_Typ("64") = "HP DC7800CMT"
	$o_Typ("66") = "Acer Veriton MT661"
	$o_Typ("67") = "HP DC8100 Elite"
	$o_Typ("68") = "HP DC8100 Elite"
	$o_Typ("69") = "Lenovo ThinkCentre M91p"
	$o_Typ("70") = "IBM Thinkpad R40"
	$o_Typ("71") = "IBM Thinkpad T41"
	$o_Typ("72") = "IBM Thinkpad T42"
	$o_Typ("73") = "IBM Thinkpad X40"
	$o_Typ("74") = "IBM Thinkpad X41"
	$o_Typ("75") = "IBM Thinkpad X60"
	$o_Typ("76") = "HP nc6400"
	$o_Typ("77") = "IBM X41 Tablet"
	$o_Typ("78") = "IBM Thinkpad X60s"
	$o_Typ("79") = "IBM Thinkpad T60"
	$o_Typ("80") = "Fujitsu Siemens Lifebook Q2010"
	$o_Typ("81") = "IBM Thinkpad T60-15"
	$o_Typ("82") = "IBM Thinkpad T61"
	$o_Typ("83") = "Lenovo Thinkpad T400"
	$o_Typ("84") = "Lenovo Thinkpad X200"
	$o_Typ("85") = "HP Compaq 6530b"
	$o_Typ("86") = "HP EliteBook 2530p"
	$o_Typ("87") = "Lenovo Thinkpad X200"
	$o_Typ("88") = "Lenovo Thinkpad X201"
	$o_Typ("89") = "Lenovo Thinkpad T410"
	$o_Typ("90") = "Dell Latitude E6510"
	$o_Typ("91") = "Dell Latitude E6520"
	$o_Typ("92") = "Acer Travelmate 8372"
	$o_Typ("93") = "Dell Latitude E6320"
	$o_Typ("94") = "Dell Latitude E6220"
	$o_Typ("95") = "Acer Veriton S6610G"
	$o_Typ("96") = "Acer Veriton M6610G"
	$o_Typ("97") = "Lenovo Thinkpad X220"
	$o_Typ("98") = "Acer Veriton M6620G"
	$o_Typ("99") = "Virtueller PC (VM-Ware)"


	GUICtrlSetData($input_hardware, $o_Typ(String($wert)))
EndFunc

Alles anzeigen

Wenn ich Funktion zurueck aufrufe, dann möchte ich gerne zum existierenden Ordner wechseln.

**Oscar**

Du musst die Funktion etwas abändern:

AutoIt

Func zurueck()
	Local $knummer = GUICtrlRead($input_sknummer)
	Local $ordnerpfad
	Do
		$knummer -= 1
		$ordnerpfad = "\\Brzg.local\shares\PIV\KONF\BRZ\PAR\" & $knummer
	Until FileExists($ordnerpfad)
	GUICtrlSetData($input_sknummer,$knummer)
	read()
EndFunc

Edit: Eventuell noch eine Abbruchbedingung, wenn es kein weiteres Zurück mehr gibt. Die hängt dann von der Ordnerstruktur ab.

DerSchatten

danke, das funktioniert grundsätzlich, aber recht langsam wenn größere Ordnersprünge sind.
Könnte man das irgendwie beschleunigen?

Eventuell die komplette Verzeichnisstruktur ein mal einlesen und dann die vorhandenen Ordnerzahlen durchgehen?

**BugFix**

Zitat von DerSchatten

Eventuell die komplette Verzeichnisstruktur ein mal einlesen und dann die vorhandenen Ordnerzahlen durchgehen?

Genau, mach das. Und beim Bewegen zwischen den Ordnern nutzt du dann den Array-Index des Arrays mit allen Pfaden. Vereinfacht auch die Fehlerabfragen: kein If FileExists notwendig, Anfang und Ende sagen dir Index=0 (oder 1, je nachdem, ob du die Pfadanzahl an [0] führst oder nicht) und Ubound.

**Bitnugger**

So meinte @BugFix das...

Prev-Next Dir

AutoIt

;-- TIME_STAMP   2017-03-20 14:46:28   v 0.1


;-- TIME_STAMP   2017-03-20 11:28:01   v 0.1


#Region    ;************ Includes ************
#Include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <File.au3>
#EndRegion ;************ Includes ************


Opt('MustDeclareVars', 1)


Global $g_sFilePath = "\\Brzg.local\shares\PIV\KONF\BRZ\PAR\"
Global $g_iCurrentDir = 1, $g_hGUI, $g_idInput_Dir, $g_idInput_skNr, $g_idButton_Prev, $g_idButton_Next
Global $g_aDirList = _FileListToArray($g_sFilePath, "*", $FLTA_FOLDERS, False)
Switch @error
	Case 1
		Exit 1 + MsgBox(262160, 'Prev-Next Dir', 'Folder not found or invalid')
	Case 2
		Exit 2 + MsgBox(262160, 'Prev-Next Dir', 'Invalid $sFilter')
	Case 3
		Exit 3 + MsgBox(262160, 'Prev-Next Dir', 'Invalid $iFlag')
	Case 4
		Exit 4 + MsgBox(262160, 'Prev-Next Dir', 'No File(s) Found')
EndSwitch


#region - GUI Create
$g_hGUI = GUICreate('Prev-Next Dir', 640, 65)
$g_idInput_Dir   = GUICtrlCreateInput('', 10, 5, 100, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_CENTER, $ES_READONLY))
$g_idInput_skNr  = GUICtrlCreateInput('', 120, 5, 510, 21)
$g_idButton_Prev = GUICtrlCreateButton('Vorheriges Verzeichnis', 10, 35, 305, 24)
$g_idButton_Next = GUICtrlCreateButton('Nächstes Verzeichnis', 325, 35, 305, 24)
_SetDir(1)
GUISetState()
#endregion


#region - GUI SelectLoop
Local $msg
While 1
	$msg = GUIGetMsg()
	Select
		Case $msg = $GUI_EVENT_CLOSE
			Exit
		Case $msg = $g_idButton_Prev
			_SetDir($g_iCurrentDir -1)
		Case $msg = $g_idButton_Next
			_SetDir($g_iCurrentDir +1)
	EndSelect
WEnd
#endregion


Func _SetDir($iDir)
	If $iDir < 1 Or $iDir > $g_aDirList[0] Then Return
	$g_iCurrentDir = $iDir
	GUICtrlSetData($g_idInput_skNr, $g_sFilePath & $g_aDirList[$g_iCurrentDir])
	GUICtrlSetData($g_idInput_Dir, StringFormat('[%i/%i]', $g_iCurrentDir, $g_aDirList[0]))
EndFunc

Alles anzeigen

DerSchatten

danke!

ich versuche das gerade in mein Programm einzupflanzen.

Wozu genau benötigt man diese Variable:
Global $g_iCurrentDir = 1, $g_hGUI, $input_sknummer, $button_zurueck, $button_vor

Die setzt sich aus dem GUI-fenster, dem Nummernfeld und Vor und Zurück Button zusammen.
Oder was genau macht die?

ist da ein Schreibfehler drinn, weil die Variable $g_idInput_skNummer gibt es ja sonst nicht.

**Bitnugger**

Zitat von DerSchatten

Wozu genau benötigt man diese Variable:
Global $g_iCurrentDir = 1, $g_hGUI, $input_sknummer, $button_zurueck, $button_vor

In dieser Zeile habe ich 5 Variablen deklariert...
Das GUI-Handle benötigst du, wenn du deine GUI z. B. minimieren willst. Z. B.: GUISetState($g_hGUI, @SW_MINIMIZE)
Die Control-IDs benötigst du, damit du in der Select-Loop-Schleife auswerten kannst, ob eines der Controls (einer der Buttons) angeklickt wurde.
$g_iCurrentDir = In dieser Variablen steht immer der Index des aktuell angezeigten Verzeichnisses in dem Array $g_aDirList
$g_hGUI = Handle der GUI ; wird hier nicht verwendet, ist bei mir aber Usus.
$g_idInput_skNr = ID des Input-Controls für die Anzeige des Index: [Index des angezeigten Verzeichnisses in $g_aDirList / Anzahl der Verzeichnisse in $g_aDirList]
$g_idButton_Prev = ID des Button-Controls (Vorheriges Verzeichnis), mit dem du den Index des Verzeichnisses um 1 veringern kannst.
$g_idButton_Next = ID des Button-Controls (Nächstes Verzeichnis), mit dem du den Index des Verzeichnisses um 1 erhöhen kannst.

Zitat von DerSchatten

ist da ein Schreibfehler drinn, weil die Variable $g_idInput_skNummer gibt es ja sonst nicht.

Jeep, das ist ein Dummfehler... und $g_idInput_Dir habe ich gar nicht deklariert...

Wenn du folgende Zeile an den Anfang deiner Scripte setzt, passiert dir sowas nicht:

AutoIt

Opt('MustDeclareVars', 1)

Ich hab das Script nun aktualisiert und diese marginalen Fehler behoben.

DerSchatten

ok, danke.

jetzt hätte ich noch einen Wunsch:

Wenn ich die Ordnernummer im Feld $g_idInput_skNr manuell eingebe, soll der Ordner-Zähler auch gleich dort hin springen und mit VOR und ZURÜCK ab dieser Zahl zählen.

**Bitnugger**

Zitat von DerSchatten

jetzt hätte ich noch einen Wunsch:

Wenn ich die Ordnernummer im Feld $g_idInput_skNr manuell eingebe, soll der Ordner-Zähler auch gleich dort hin springen und mit VOR und ZURÜCK ab dieser Zahl zählen.

Ok...

F2 = Fokus auf $g_idInput_skNr setzen
F5 = Index auf 1 setzen
F6 = Index auf $g_aDirList[0] setzen (letztes Verzeichnis)

Edit: Habe noch ein paar kleine Änderungen gemacht...

Prev-Next Dir 2

AutoIt

;-- TIME_STAMP   2017-03-20 16:27:39   v 0.1


#Region    ;************ Includes ************
#Include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <File.au3>
#include <WinAPI.au3>
#EndRegion ;************ Includes ************


Opt('MustDeclareVars', 1)


Global $g_sFilePath = "\\Brzg.local\shares\PIV\KONF\BRZ\PAR\"
Global $g_iCurrentDir = 1, $g_hGUI, $g_idInput_Dir, $g_idInput_skNr, $g_idButton_Prev, $g_idButton_Next, $g_idDummyF2, $g_idDummyF5, $g_idDummyF6
Global $g_aDirList = _GetDirList($g_sFilePath)


#region - GUI Create
$g_hGUI = GUICreate('Prev-Next Dir', 640, 65)
$g_idInput_Dir   = GUICtrlCreateInput('', 10, 5, 100, 21, BitOR($GUI_SS_DEFAULT_INPUT, $ES_CENTER, $ES_READONLY))
$g_idInput_skNr  = GUICtrlCreateInput('', 120, 5, 510, 21)
$g_idButton_Prev = GUICtrlCreateButton('Vorheriges Verzeichnis', 10, 35, 305, 24)
$g_idButton_Next = GUICtrlCreateButton('Nächstes Verzeichnis', 325, 35, 305, 24)
$g_idDummyF2 = GUICtrlCreateDummy()
$g_idDummyF5 = GUICtrlCreateDummy()
$g_idDummyF6 = GUICtrlCreateDummy()


_Main()


Func _Main()
	Local $aAccelKeys[3][2] = [["{F2}", $g_idDummyF2], ["{F5}", $g_idDummyF5], ["{F6}", $g_idDummyF6]]
	GUISetAccelerators($aAccelKeys)


	GUISetState()
	#endregion


	_SetDir(1)
	ControlFocus($g_hGUI, '', $g_idInput_Dir)


	#region - GUI SelectLoop
	Local $msg, $iChangeIndex, $iFokus, $vText
	While 1
		$msg = GUIGetMsg()


		$iFokus = _WinAPI_GetDlgCtrlID(ControlGetHandle($g_hGui, '', ControlGetFocus($g_hGui)))
		$vText = GUICtrlRead($g_idInput_skNr)
		If $iFokus = $g_idInput_skNr Then
			If $vText <> '' And Int($vText) = 0 Then GUICtrlSetData($g_idInput_skNr, '')
		ElseIf $msg <> $g_idButton_Prev And $msg <> $g_idButton_Next Then
			If $vText = '' Or $vText <> $g_aDirList[$g_iCurrentDir] Then GUICtrlSetData($g_idInput_skNr, $g_sFilePath & $g_aDirList[$g_iCurrentDir])
		EndIf


		Select
			Case $msg = $GUI_EVENT_CLOSE
				Exit
			Case $msg = $g_idInput_skNr
				ConsoleWrite('$g_idInput_skNr' & @CRLF)
				$iChangeIndex = GUICtrlRead($g_idInput_skNr)
				If Int($iChangeIndex) > 0 And Int($iChangeIndex) < $g_aDirList[0] Then
					_SetDir($iChangeIndex)
					ControlFocus($g_hGUI, '', $g_idInput_Dir)
				EndIf
			Case $msg = $g_idButton_Prev
				_SetDir($g_iCurrentDir -1)
			Case $msg = $g_idButton_Next
				_SetDir($g_iCurrentDir +1)
			Case $msg = $g_idDummyF2
					If $iFokus <> $g_idInput_skNr Then ControlFocus($g_hGUI, '', $g_idInput_skNr)
			Case $msg = $g_idDummyF5
				_SetDir(1)
			Case $msg = $g_idDummyF6
				_SetDir($g_aDirList[0])
		EndSelect
	WEnd
	#endregion
EndFunc


Func _SetDir($iDir)
	If $iDir < 1 Or $iDir > $g_aDirList[0] Then Return
	$g_iCurrentDir = $iDir
	GUICtrlSetData($g_idInput_skNr, $g_sFilePath & $g_aDirList[$g_iCurrentDir])
	GUICtrlSetData($g_idInput_Dir, StringFormat('[%i/%i]', $g_iCurrentDir, $g_aDirList[0]))
	ControlFocus($g_hGUI, '', $g_idInput_Dir)
EndFunc


Func _GetDirList($sFilePath)
	Local $aDirList = _FileListToArray($g_sFilePath, "*", $FLTA_FOLDERS, False)
	Switch @error
		Case 1
			Exit 1 + MsgBox(262160, 'Prev-Next Dir', 'Folder not found or invalid')
		Case 2
			Exit 2 + MsgBox(262160, 'Prev-Next Dir', 'Invalid $sFilter')
		Case 3
			Exit 3 + MsgBox(262160, 'Prev-Next Dir', 'Invalid $iFlag')
		Case 4
			Exit 4 + MsgBox(262160, 'Prev-Next Dir', 'No File(s) Found')
	EndSwitch
	Return $aDirList
EndFunc

Alles anzeigen

DerSchatten

danke!
Hast du das da schon implementiert?
Denn in dem Feld kann ich zwar eine Nummer eingeben, die wird aber nicht berücksichtigt.

**Bitnugger**

Zitat von DerSchatten

Hast du das da schon implementiert?

Ja, habe ich... dann hast du wohl noch die alte Version...

DerSchatten

ok, jetzt versteh ich.
Ich würde aber gerne die Nummer des eigentlichen Ordners suchen können also nicht Nummer der ordnerzahl.
Wenn du weißt was ich meine.

**Bitnugger**

Zitat von DerSchatten

Ich würde aber gerne die Nummer des eigentlichen Ordners suchen können also nicht Nummer der ordnerzahl.
Wenn du weißt was ich meine.

Ja, weiß ich. Ich werde dir das noch einbauen... dafür muss ich den Code aber komplett umbauen... in ca. 1-3 Stunden werde ich es wohl fertig haben.

DerSchatten

super, danke!