Excel, Mehrere Dateinamen einlesen und auflisten

Mikki

Guten Morgen zusammen,

ich habe ein kleines Problem. Und zwar möchte ich für die Arbeit ein Tool schreiben, was mir von den markierten Dateien im Explorerfenster die Dateinamen in eine Excelliste schreibt. Für jede Datei soll eine neue Zeile + Spalte angelegt werden. Außerdem soll es von den Benennungen die ersten 7 Zeichen löschen. Soweit funktioniert mein Tool auch. Aber nur für eine Datei :-D. Wenn ich mehrere auswähle kommt Quatsch bei raus.

Probier´s mal aus dann wisst Ihr worauf ich hinaus will.
Ich weiss dass ich noch eine Funktion einbauen muss, also so eine Art Zähler. Hab aber leider absolut keine Idee wie ich das realisieren soll.

Hier mal der Code:

AutoIt

#include <GUIConstantsEx.au3>
#include <StringConstants.au3>
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>
#include <Excel.au3>
#include <File.au3>
#include <Date.au3>
#include <data\decl.au3>


Opt("GUIOnEventMode", 1) ; Wechsle in den OnEvent Modus


$Window_Main = GUICreate("Pyron - Daten smarter verwalten", 140, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSE_clicked_Window_Main")


$Button_Dateien_waehlen = GUICtrlCreateButton("1.Pläne waehlen", 10, 30, 120, 25 )
GUICtrlSetOnEvent($Button_Dateien_waehlen, "Plaene_waehlen")




$Button_Daten_uebernehmen = GUICtrlCreateButton("2.Daten übernehmen", 10, 70, 120, 25)
GUICtrlSetOnEvent($Button_Daten_uebernehmen, "Daten_uebernehmen")


GUISetState(@SW_SHOW)


While 1
	Sleep(1000)
WEnd




Func Plaene_waehlen()


	; Create a constant variable in Local scope of the message to display in FileOpenDialog.
	$sMessage = "Hold down Ctrl or Shift to choose multiple files."


    ; Display an open dialog to select a list of file(s).
	$sFileOpenDialog_Plaene = FileOpenDialog($sMessage, @WindowsDir & "", "Pläne (*.bmf_)", $FD_FILEMUSTEXIST + $FD_MULTISELECT)


    If @error Then
        ; Display the error message.
        MsgBox($MB_SYSTEMMODAL, "", "Keine Datei gewählt!")


        ; Change the working directory (@WorkingDir) back to the location of the script directory as FileOpenDialog sets it to the last accessed folder.
        FileChangeDir(@ScriptDir)


	EndIf


EndFunc






Func Daten_uebernehmen()


	$File_search = FileFindFirstFile($sFileOpenDialog_Plaene & '*.bmf')


	_PathSplit($sFileOpenDialog_Plaene & $File_search, $sDrive, $sDir, $sFileName, $sExtension)


	$String_Replace_Plannummer_1 = StringLeft($sFileName, 6)
	$String_Replace_Benennung_1 = StringTrimLeft($sFileName, 7)
	$Date = _NowDate()
	$Index = 0


	$oExcel = _Excel_Open(Default, Default, Default, Default, True)


	$oWorkbook = _Excel_BookNew($oExcel, 1)


	_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $String_Replace_Plannummer_1, "A1")
	_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $String_Replace_Benennung_1, "B1")
	_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $Date, "C1")
	_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $Index, "D1")


EndFunc






Func CLOSE_clicked_Window_Main()
	Exit
EndFunc

Alles anzeigen

Variablen sind in einer extra Datei deklariert.

Wär nett wenn Ihr mir da helfen könntet. Das würde mir eine Menge Arbeit ersparen.

Danke im Voraus.

LG Mikki

**alpines**

Dein Script ist so nicht lauffähig, da fehlen etliche Variablen die nicht deklariert sind.

FileOpenDialog returnt im folgenden Muster: Pfad zum Ordner|Datei1|Datei2.
Jetzt brauchst du nur noch StringSplit zu verwenden mit dem Delimeter "|". Dann hast du auch schon ein Array mit [0] Pfad zum Ordner [1] Datei1 usw.
Nun noch eine For-Schleife dazu und du kannst das Array in die Exceltabelle schreiben.

Mikki

Hallo alpines,

sorry so ganz verstehe ich das nicht. Kannst mir das anhand eines Beispiels zeigen?

Ja ich weiss dass die Deklarationen fehlen, da ich sie, wie oben schon geschrieben, in einer extra Datei habe. Aber ich pack´ sie dir noch mal hier rein.

Code

;Datei für Deklaration der Daten


Global $Window_Main, $Window_Ordner1


Global $Button_Liste_waehlen, $Button_Dateien_waehlen, $Button_Daten_uebernehmen


Global $sFileOpenDialog_Plaene, $sMessage


Global $sDrive, $sDir, $sFileName, $sExtension, $aPathSplit, $File_search


Global $oExcel, $Excel_open, $oWorkbook


Global $String_Replace_Plannummer_1
Global $String_Replace_Benennung_1


Global $Date, $Index, $i

Alles anzeigen

**alpines**

Hier mal ein Beispiel wie man das machen kann (musst du logischerweise auf deins anpassen und Errorhandling einbauen):

Erstell dir einen neuen Ordner mit mehreren Textdateien mit dem Schema "Plannummer Benennung.txt".

AutoIt

#include <File.au3>


$sFiles = FileOpenDialog("Select Files", @ScriptDir, "Test-Dateien (*.txt)", $FD_FILEMUSTEXIST + $FD_MULTISELECT)


MsgBox(64, "Return", $sFiles)


If StringInStr($sFiles, "|") Then ;Multiple Files
	$aFiles = StringSplit($sFiles, "|", 3)


	For $i = 1 To UBound($aFiles) - 1
		$sPlannummer = StringLeft($aFiles[$i], 6)
		$sBenennung = StringTrimLeft($aFiles[$i], 7)


		ConsoleWrite("Nr: " & $sPlannummer & @TAB & "Benennung: " & $sBenennung & @TAB & "Absoluter Pfad: " & $aFiles[0] & "\" & $aFiles[$i] & @CRLF)
	Next
Else
	$sPlannummer = StringLeft($sFiles, 6)
	$sBenennung = StringTrimLeft($sFiles, 7)


	ConsoleWrite("Nr: " & $sPlannummer & " - Benennung: " & $sBenennung & @CRLF)
EndIf

Alles anzeigen

Mikki

Hallo alpines,

danke für das Beispiel. Ich schau mal wie ich das auf mein Tool anwenden kann ansonsten melde ich mich noch mal

LG Mikki

Mikki

Hallo,

ich bekomme es nicht auf die Excel Tabelle übertragen. Das einzige was er bei mir macht, ist, dass er zur letzten Nummer springt und diese dann anzeigt.

**alpines**

Sicher, dass _RangeWrite die richtige Funktion dafür ist?

Mikki

Ja schon. Zumindest ist es die einzige Funktion die ich kenne, mit der ich Daten in die Zellen schreiben kann.

Mikki

Hat denn sonst keiner eine Idee wie das funktioniert?

NO1 :-)

Schau dir mal _ExcelWriteCell an...

Lg NO1

**autoiter**

Hallo @Mikki,
ich habe es mal ausprobiert. Dir hat natürlich noch komplett die Schleife gefehlt - das weißt du ja aber selbst. Hattest du außerdem Probleme mit der Ausgabe von FileOpenDialog? Ich meine vielleicht hast du es in der Hilfe übersehen und dir die Ausgabe von mehreren Dateien nie angeschaut?

Zitat von Success von FileOpenDialog

the full path of the file(s) chosen. Results for multiple selections are "Directory|file1|file2|...".

Das heißt, deine gewählte Methode funktioniert nicht immer, da die Datengrundlage jeweils eine andere ist. Ich habe mal deine Daten_uebernehmen() etwas abgewandelt. In den ersten Zeilen gibt es eine MsgBox und ein _ArraySearch. Schau dir beides mit einer Datei und dann mit mehreren Dateien an. Da sollte es klar werden. Gut ist das wohl nicht, was ich da geändert habe, aber ich hoffe mal, es ist für dich verständlich.

Spoiler anzeigen

AutoIt

Func Daten_uebernehmen()


	$oExcel = _Excel_Open(Default, Default, Default, Default, True)


	$oWorkbook = _Excel_BookNew($oExcel, 1)


	MsgBox(0,"$sFileOpenDialog_Plaene Ausgabe", $sFileOpenDialog_Plaene)
	Local $aSplit = StringSplit($sFileOpenDialog_Plaene, "|") ; Am Pipezeichen trennen
	_ArrayDisplay($aSplit, "$sFileOpenDialog_Plaene nach Split")


	Local $iMaxSize ; Dient als Zähler für die max. Schleifendurchläufe.


	If $aSplit[0] = 1 Then ; In $aSplit[0] siehst du die Anzahl, der Elemente. Wenn nur eine Datei, dann soll die Schleife dennoch laufen..
		$iMaxSize = 2 ; .. Also setzen ich den Inhalt auf zwei.
	Else
		$iMaxSize = $aSplit[0] ; Ansonsten auf den Wert $aSplit[0] (denn in Element 0 steht ja Anzahl, in 1 Dateipfad, in 2 die erste Datei, ..)
	EndIf


	For $i = 2 To $iMaxSize ; Schleife von 2 bis maximaler Anzahl. (Zwei, weil bei mehreren Dateien, die erste Datei in Element 2 steht. Siehe _ArrayDisplay).


		If $aSplit[0] = 1 Then
			$sFileFullname = StringTrimLeft($aSplit[1], StringInStr($aSplit[1], "\", 0, -1)) ; Schnippelt den Dateipfad weg. Etwas obskur, aber schau mal in die Hilfe zu beiden Befehlen.
			$sFileName = StringLeft($sFileFullname, StringInStr($sFileFullname, ".", 0, -1) - 1) ; Schnippelt die Dateiendung ab.
		Else
			$sFileName = StringLeft($aSplit[$i], StringInStr($aSplit[$i], ".", 0, -1) - 1) ; Wenn mehr als eine Datei, dann muss ja nur die Endung abgeschnippelt werden.
		EndIf


		$String_Replace_Plannummer_1 = StringLeft($sFileName, 6)
		$String_Replace_Benennung_1 = StringTrimLeft($sFileName, 7)
		$Date = _NowDate()
		$Index = 0


		_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $String_Replace_Plannummer_1, "A" & $i - 1) ; $i-1, weil $i ja schon zu Beginn 2 ist, der Start aber in Zeile 1 stattfinden soll.
		_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $String_Replace_Benennung_1, "B" & $i - 1)
		_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $Date, "C" & $i - 1)
		_Excel_RangeWrite($oWorkbook, $oWorkbook.Activesheet, $Index, "D" & $i - 1)
	Next


EndFunc   ;==>Daten_uebernehmen

Alles anzeigen

Mikki

Hallo @autoiter

vieeeelen lieben Dank dafür. Genau das was ich gesucht habe.

Genau, ich hatte das Problem, dass ich die Schleife nicht hinbekommen habe.

Ich habe in Zeile 7 die MsgBox entfernt und in Zeile 9 _ArrayDisplay entfernt.

So schreibt er mir die Daten ohne Umweg direkt in die Exceltabelle.

Danke schön

LG Mikki

**autoiter**

Kein Thema @Mikki,

Zitat von Mikki

Ich habe in Zeile 7 die MsgBox entfernt und in Zeile 9 _ArrayDisplay entfernt.

Gut so! Die beiden Zeilen sollten dich ja auch nicht dauerhaft gängeln, sondern den Unterschied zwischen einem und mehreren Elementen aufzeigen