Ich finde keinen Fehler:

pltnpcs

In meinem Programm soll eigentlich in Zeile 78 geguckt werden ob ich einen Text im Input habe, und daraufhin zurückgeschrieben werden aber das funktioniert einfach nicht. Ich bin jetzt seit ca 4 Stunden an diesem kleinen Problem und mit den Nerven am Ende. Kann mir jemand sagen was ich falsch gemacht habe?

AutoIt

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <File.au3>
#include <WindowsConstants.au3>
#include <FileConstants.au3>
#include <WinAPIFiles.au3>
#include <Misc.au3>
#include <IE.au3>
#include <String.au3>


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
If Not FileExists("documents\p19data\input\01.txt") Then
   DirCreate("documents\p19data")
   DirCreate("documents\p19data\input")
   _FileCreate("documents\p19data\input\01.txt")
   FileOpen("documents\p19data\input\01.txt")
   FileWriteLine("documents\p19data\input\01.txt","Hallo;Hi;Hey;")
   FileClose("documents\p19data\input\01.txt")
EndIf
$i01plt = FileRead("documents\p19data\output\begruessung.txt")
$i01 = StringSplit($i01plt,";")
;;;
If Not FileExists("documents\p19data\output\01.txt") Then
   DirCreate("documents\p19data")
   DirCreate("documents\p19data\output")
   _FileCreate("documents\p19data\output\01.txt")
   FileOpen("documents\p19data\output\01.txt")
   FileWriteLine("documents\p19data\output\01.txt","Hallo;Hi;Hey;")
   FileClose("documents\p19data\output\01.txt")
EndIf
$o01plt = FileRead("documents\p19data\output\begruessung.txt")
$o01 = StringSplit($o01plt,";")
;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
HotKeySet("{ENTER}","antwort")
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
#Region ### START Koda GUI section ### Form=
$formp19 = GUICreate("P19", 480, 270, 694, 228)
$pic = GUICtrlCreatePic("C:\Users\plati\Desktop\viv\wallpaper.jpg", 0, 0, 480, 270)
GUICtrlSetState($pic,$GUI_DISABLE)
$iE = _IECreateEmbedded()
$obj = GUICtrlCreateObj($iE, -5, -5, 1, 1)
_IENavigate($iE, "https://translate.google.com/?hl=de#de/en/")
GUISetFont(14, 400, 0, "MS Sans Serif")
GUISetBkColor(0xFFFFDF)
GUICtrlSetFont(-1, 12, 400, 0, "Segoe UI Semilight")
$input = GUICtrlCreateInput("", 30, 24, 425, 28)
GUICtrlSetFont(-1, 11, 400, 0, "Segoe UI Semilight")
GUICtrlSetBkColor(-1, 0xAEFFFF)
$output = GUICtrlCreateLabel("", 42, 75, 398, 148, $WS_BORDER)
GUICtrlSetFont(-1, 14, 400, 0, "Segoe UI Semilight")
GUICtrlSetBkColor(-1, 0xAEFFFF)
$antwort = GUICtrlCreateButton("Answer", -20, -20, 1, 1)
GUICtrlSetFont(-1, 14, 400, 0, "Segoe UI Semilight")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		 Case $GUI_EVENT_CLOSE
		 Case $antwort
			   Func antwort()
				  $data = GUICtrlRead($input)
				  $outputline1 = FileReadLine("documents\P19outputdata.txt",1)
				  $r2 = Random(1,2,1)
				  $r3 = Random(1,3,1)
				  $r4 = Random(1,4,1)
				  $r5 = Random(1,5,1)
				  $r6 = Random(1,6,1)
				  $r7 = Random(1,7,1)


				  If StringInStr($data,$i01) Then
					 GUICtrlSetData($output,$o01plt)
					 ConsoleWrite("hat funktioniert")
				  EndIf
			   EndFunc
   EndSwitch
WEnd

Alles anzeigen

**Stilgar**

Hallo,

Das Auffälligste ist schon mal: die Funktion "antwort" gehört nicht in die Schleife, sondern nur deren Aufruf.

Friesel

Zitat von pltnpcs

Ich finde keinen Fehler

Guter Witz...die einzigen Zeilen, die keinen Fehler enthalten, sind von Koda generiert
Ich werde jetzt bewußt nicht auf die einzelnen Fehler eingehen, weil dir ganz offensichtlich die einfachsten Grundlagen fehlen.

Bevor du dich an sowas wagst, solltest du viel, viel lesen, Tutorials durcharbeiten UND verstehen.
Vor allem solltest du die Hilfe zu den von dir verwendeten Befehlen und hier besonders die Anmerkungen durchlesen ("Remarks", falls du die englische Hilfe hast)
Hättest du das getan, wären dir viele Fehler sicherlich nicht unterlaufen.

Nichtsdestotrotz, weils dafür keine Standard Lösung gibt, hier mein Vorschlag, um das Input Feld auszulesen, wenn die Enter Taste gedrückt wird.
Eins noch vorweg: NIEMALS HotKeySet für die eigene Gui verwenden, wenn es sich vermeiden läßt. So wie du es "programmiert" hast, wird die Enter Taste im ganzen System blockiert.
Um das Input Feld so zu verwenden wie du es planst, kannst du z.B. sogenannte "Accelerator keys" verwenden:

Spoiler anzeigen

AutoIt

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>


;"Global" ist hier eigendlich überfüssig, weil ALLE Variablen auf der "untersten Ebene" Global sind, egal wie sie deklariert werden
Global $hGui = GUICreate("Demo", 400, 100)
;Controls
Global $idInput = GUICtrlCreateInput("", 10, 10, 380, Default)
Global $hInput = GUICtrlGetHandle($idInput) ;die Funktion "_WinAPI_GetFocus" benötigt ein Handle, keine ID
Global $idLabelOutput = GUICtrlCreateLabel("", 10, 40, 380, 50, BitOR($SS_CENTERIMAGE, $SS_CENTER))
;Accelerator key
Global $idDummy = GUICtrlCreateDummy()
Global $aAccelKeys[1][2] = [["{ENTER}", $idDummy]]
GUISetAccelerators($aAccelKeys, $hGui)


GUISetState(@SW_SHOW, $hGui)


While True
	$idMsg = GUIGetMsg()
	Switch $idMsg
		Case $GUI_EVENT_CLOSE
			;beendet nicht das Skript, sondern springt nur aus der While/WEnd Schleife.
			;Exit (Zeile 37) ist eigendlich überflüssig, weil keine weiteren Befehle folgen.
			;Die Funktion wird nur ausgeführt, wenn sie aufgerufen wird
			ExitLoop
		Case $idDummy
			;Befehle können auch hier ausgeführt werden. Nicht nötig eine Funktion aufzurufen, ist aber übersichtlicher


			;==> reagiert nur, wenn die Input Box Fokus hat.
			;==> Die Fokus Abfrage man auch weglassen, wenn Input immer ausgelesen werden soll (solange die Gui Fokus hat)
			If _WinAPI_GetFocus() = $hInput Then
				_BeliebigeFunktion()
			EndIf
	EndSwitch
WEnd


Exit


Func _BeliebigeFunktion()
	GUICtrlSetData($idLabelOutput, GUICtrlRead($idInput))
	GUICtrlSetData($idInput, "")
EndFunc

Alles anzeigen

Viel Erfolg beim Lernen, Friesel

**alpines**

Zitat von Friesel

;"Global" ist hier eigendlich überfüssig, weil ALLE Variablen auf der "untersten Ebene" Global sind, egal wie sie deklariert werden

Die "unterste Ebene" von der du sprichst nennt sich das globale Scope.

Es ist nicht verkehrt vor der Variable global zu schreiben, wenn es einem dabei hilft den Code leserlicher zu gestalten.
Es ist einfach nur überflüssig aber der Code wird dadurch kaum an Geschwindigkeit im Interpreter verlieren.

Bei Arrays ist es sowieso notwendig (wenn man kein Dim) verwendet um sie überhaupt erstellt zu kriegen.
Außerdem kann man dazu noch die Variablen deklarieren ohne ihnen einen Inhalt zu geben.

Friesel

Zitat von alpines

Die "unterste Ebene" von der du sprichst nennt sich das globale Scope.
Es ist nicht verkehrt vor der Variable global zu schreiben, wenn es einem dabei hilft den Code leserlicher zu gestalten.
Es ist einfach nur überflüssig aber der Code wird dadurch kaum an Geschwindigkeit im Interpreter verlieren.

Bei Arrays ist es sowieso notwendig (wenn man kein Dim) verwendet um sie überhaupt erstellt zu kriegen.
Außerdem kann man dazu noch die Variablen deklarieren ohne ihnen einen Inhalt zu geben.

Dessen bin ich mir natürlich in allen Punkten bewußt.
Ich wollte das nur nochmal herausstellen, weil man gerade bei Anfängern immer wieder sieht, dass sie "auf der untersten Ebene" (ja, ich weiß wie das richtig heißt, wollte es aber Anfängerfreundlich formulieren ) Variablen lokal deklarieren und denken, es hätte eine Auswirkung.
Trotz allem gebe ich dir recht, das hätte ich besser formulieren können

pltnpcs

Danke @Friesel Ich habe mir deinen Skript jetzt lange genau angeschaut und studiert, dadurch habe ich wieder etwas sehr wichtiges dazu gelernt

**alpines**

Wenn es klappt, dann immer schön den Haken setzen!