brauche Hilfe bei _ArraySearch

qwerti

Hallo zusammen ich hoffe jemand kann mir weiterhelfen.

Ich möchte via _ArraySearch bestimmte Verzeichnisinhalte vergleichen, nur leider bekomme ich nicht das erwünschte Ergebnis.

In dem Verzeichnis befinden sich teilweise bis zu 1800 Dateien immer ein Dateiname und 3 verschiedene Dateiendungen. Ich möchte über ein Skript raus bekommen wenn irgendwo eine Datei fehlt, es also nur 2 Dateien sind mit dem Namen.

Nur klappt es bei mir nicht so richtig.

Mein Ansatz:

AutoIt: Vergleich

Func Vergleich()


Local $FileListCAD = _FileListToArray($verzeichniss,'*.cad')
Local $FileListINI = _FileListToArray($verzeichniss,'*.ini')
Local $FileListSLP = _FileListToArray($verzeichniss,'*.slp')




For $i = 2 To UBound($FileListCAD) -1

	$temp = StringSplit($FileListCAD[$i],".",2)

	$index = _ArraySearch ($FileListSLP, $FileListCAD[0],0,0,0,1)

	If $index > 1 Then
		    MsgBox(0, 'Eintrag wurde nicht gefunden', ' Index: ' & $index)


EndIf
Next






EndFunc ;==>Vergleich

Alles anzeigen

Mein Problem selbst wenn ich mit Absicht eine Datei lösche kommt hier keine Meldung.

Wenn mir jemand helfen könnte wäre ich darüber sehr froh.

mit freundlichen Grüßen

**alpines**

Vielleicht hilft dir das ja weiter:

AutoIt

#include <Array.au3>


Local $a1[2] = ["Datei.txt", "File.msg"]
Local $a2[2] = ["Datei.msc", "File.mmm"]
Local $a3[3] = ["Datei.fgj", "Nein.msg"]


For $i = 0 To UBound($a1) - 1
	$sDateiName = StringTrimRight($a1[$i], 4)


	ConsoleWrite("1. ArraySearch = " & _ArraySearch($a2, $sDateiName, 0, 0, 0, 1) & @CRLF)
	ConsoleWrite("2. ArraySearch = " & _ArraySearch($a3, $sDateiName, 0, 0, 0, 1) & @CRLF & @CRLF)
Next

Alles anzeigen

**AspirinJunkie**

Und wenn du statt 3 Arrays alle Dateien in das ARray packst und beim durchgehen schaust ob 3 aufeinander folgende Dateien den selben Namen haben?

Edit: Und als weiterer Vorschlag unter Einsatz eines Dictionaries:

AutoIt

Global Const $s_SearchPath = "D:\Temp\Test"


Global $o_Files = ObjCreate("Scripting.Dictionary")
Global $h_FFFF, $s_FFNF, $s_FileName, $s_FileExt, $a_Ext


; Dictionary der Form dic(Dateiname) = [Endung1,Endung2...] anhand der Dateien aufbauen
$h_FFFF = FileFindFirstFile($s_SearchPath & "\*")
If $h_FFFF <> -1 Then
	Do
		$s_FFNF = FileFindNextFile($h_FFFF)
		If @error Then ExitLoop
		If @extended Then ContinueLoop ; Ordner überspringen


		$s_FileName = StringLeft($s_FFNF, StringInStr($s_FFNF, ".", 1, -1)-1)
		$s_FileExt = StringTrimLeft($s_FFNF, StringInStr($s_FFNF, ".", 1, -1))


		; temporäres Array für die Dateiendungen anlegen bzw. erweitern, falls vorhanden
		If $o_Files.Exists($s_FileName) Then
			$a_Ext = $o_Files($s_FileName)
			ReDim $a_Ext[UBound($a_Ext) + 1]
			$a_Ext[UBound($a_Ext)-1] = $s_FileExt
		Else
			Local $a_Ext[] = [$s_FileExt]
		EndIf


		$o_Files($s_FileName) = $a_Ext
	Until 0
EndIf


; Ergebnis auf solche Dateinamen auswerten welche weniger als 3 Dateiendungen im Verzeichnis besitzen
ConsoleWrite("Von folgenden Dateinamen existieren weniger als 3 Exemplare mit unterschiedlicher Endung:" & @CRLF)
For $s_FileName in $o_Files.Keys()
	$a_Ext = $o_Files($s_FileName)


	If UBound($a_Ext) < 3 Then
		ConsoleWrite($s_FileName & " (")
		For $s_FileExt In $a_Ext
			ConsoleWrite($s_FileExt & ($a_Ext[UBound($a_Ext)-1] = $s_FileExt ? "" : ", "))
		Next
		ConsoleWrite(")" & @CRLF)
	EndIf
Next

Alles anzeigen

qwerti

oh wow das ging aber Fix!

Vielen dank für die schnelle Hilfe. Ich werde mir das gleich mal genauer Angucken aber ich denke damit kann ich etwas anfangen. Vielen dank!!

qwerti

Zitat von alpines

Vielleicht hilft dir das ja weiter:

AutoIt

#include <Array.au3>


Local $a1[2] = ["Datei.txt", "File.msg"]
Local $a2[2] = ["Datei.msc", "File.mmm"]
Local $a3[3] = ["Datei.fgj", "Nein.msg"]


For $i = 0 To UBound($a1) - 1
	$sDateiName = StringTrimRight($a1[$i], 4)


	ConsoleWrite("1. ArraySearch = " & _ArraySearch($a2, $sDateiName, 0, 0, 0, 1) & @CRLF)
	ConsoleWrite("2. ArraySearch = " & _ArraySearch($a3, $sDateiName, 0, 0, 0, 1) & @CRLF & @CRLF)
Next

Alles anzeigen

@alpines Also das hab so jetzt gut umgesetzt bekommen! Danke

Zitat von AspirinJunkie

Und wenn du statt 3 Arrays alle Dateien in das ARray packst und beim durchgehen schaust ob 3 aufeinander folgende Dateien den selben Namen haben?

@AspirinJunkie Ich kann mich auch irren aber ich könnte mir vorstellen das dass recht fehleranfällig ist und ich kann bei der Methode schlecht sagen welcher der 3 Dateien fehlt oder? Die Variante mit dem Dictionarie ist schon zimlich cool aber vielleicht am Ende doch etwas zu umfangreich für mich und meine bescheidenen Zwecke aber trotzdem vielen lieben dank!

**AspirinJunkie**

Zitat von qwerti

Ich kann mich auch irren aber ich könnte mir vorstellen das dass recht fehleranfällig ist und ich kann bei der Methode schlecht sagen welcher der 3 Dateien fehlt oder?

Da FileFindNextFile immer alphabetisch sortiert ausgibt sollte es da wenig Fehlerquellen geben.
Auch die Frage andersherum zu stellen und zu sagen welche der 3 Dateien genau fehlt wäre mit der Methode problemlos machbar:

AutoIt

Global Const $s_SearchPath = "D:\Temp\Test"
Global $s_FFNF, $s_FileName, $s_FileExt, $a_Temp


Global $h_FFFF = FileFindFirstFile($s_SearchPath & "\*")
If $h_FFFF <> -1 Then
	Do
		$s_FFNF = FileFindNextFile($h_FFFF)
		If @error Then ExitLoop
		If @extended Then ContinueLoop ; Ordner überspringen


		$s_FileName = StringLeft($s_FFNF, StringInStr($s_FFNF, ".", 1, -1) - 1)
		$s_FileExt = StringTrimLeft($s_FFNF, StringInStr($s_FFNF, ".", 1, -1))


		$a_Temp = processExts($s_FileName, $s_FileExt)
		If @extended Then ConsoleWrite($a_Temp[0] & @TAB & "(" & $a_Temp[1] & ")" & @CRLF)
	Until 0
EndIf
FileClose($h_FFFF)
$a_Temp = processExts("", "")
If @extended Then ConsoleWrite($a_Temp[0] & @TAB & "(" & $a_Temp[1] & ")" & @CRLF)




Func processExts($s_FileName, $s_FileExt)
	Local Static $s_FNameCurr = "", $a_Endings[3] = ["cad", "ini", "slp"], $s_MatchedExt
	Local $a_Ret[2], $s_MissingExt = ""


	If $s_FileName <> $s_FNameCurr Then
		If $s_FNameCurr <> "" Then
			For $i In $a_Endings
				If Not StringInStr($s_MatchedExt, $i, 2) Then $a_Ret[1] &= $i & ", "
			Next
			$a_Ret[0] = $s_FNameCurr
		EndIf
		$s_FNameCurr = $s_FileName
		$s_MatchedExt = ""
	EndIf
	$s_MatchedExt &= $s_FileExt & ";"
	$a_Ret[1] = StringTrimRight($a_Ret[1], 2)
	Return SetExtended($a_Ret[1] ? 1 : 0, $a_Ret)
EndFunc   ;==>processExts

Alles anzeigen

Bei 1800 Dateien bei jeder einzelnen jeweils drei Arrays zu durchsuchen finde ich halt ziemlich ineffizient.
Deshalb mein Hinweis auf die entsprechenden Alternativen.

Edit: Ehrlicherweise muss man "effizient" auch mal im Sinne von Codeeffizienz betrachten. Und da fallen meine beiden Methoden im Vergleich der ArraySearch-Lösung natürlich vollkommen durch.

qwerti

@AspirinJunkie Es ist auf jeden Fall eine sehr interessante Methode, ich gebe zu das sie etwas über meinen Fähigkeiten liegt dafür bin ich einfach zu schlecht im programmieren btw.: mein persönlicher Anspruch nach Codeeffizienz hält sich in Grenzen mir ist wichtig das ich meinen eigenen Code verstehe und er am ende gut funktioniert.

vielen Dank für deine Mühe!

**AspirinJunkie**

Deine Herangehensweise ist auch vollkommen richtig.
Gerade AutoIt ist darauf ausgelegt schnell und einfach zum Ziel zu kommen.

Wenn es den Zweck erfüllt und nicht zu langsam ist, gibt es keinen Grund das Skript weiter auf Effizienz zu trimmen.