Globale Variable vermeiden. Methoden?

**autoiter**

Hey Leute,

ich habe mal eine prinzipielle Frage zu den Möglichkeiten globale Variablen zu vermeiden, wenn ich mir UDF erstelle. Bei Variablen, deren Wert dauerhaft verfügbar sein soll, habe ich schon einige Male mit einer Local Static Variable gearbeitet. Dabei wird immer eine Funktion mit Parametern aufgerufen, in der dann die jeweilige Routine für den Parameter ausgeführt wird. Ich habe gerade wieder darüber nachgedacht einige Skripte anzupassen und möchte nun aber vorher klären, ob das so überhaupt sinnvoll ist.
Hier mal ein Bsp. dass ich auch verwende.

Das HotKeySet-Beispiel aus der Hilfe zum Pausieren eines Programmablaufs

Spoiler anzeigen

AutoIt

#include <MsgBoxConstants.au3>


; Press Esc to terminate script, Pause/Break to "pause"


Global $g_bPaused = False


HotKeySet("{PAUSE}", "TogglePause")
HotKeySet("{ESC}", "Terminate")
HotKeySet("+!d", "ShowMessage") ; Shift-Alt-d


While 1
    Sleep(100)
WEnd


Func TogglePause()
    $g_bPaused = Not $g_bPaused
    While $g_bPaused
        Sleep(100)
        ToolTip('Script is "Paused"', 0, 0)
    WEnd
    ToolTip("")
EndFunc   ;==>TogglePause


Func Terminate()
    Exit
EndFunc   ;==>Terminate


Func ShowMessage()
    MsgBox($MB_SYSTEMMODAL, "", "This is a message.")
EndFunc   ;==>ShowMessage

Alles anzeigen

Hier die Variante mit Local Static $g_bPaused statt Global $g_bPaused

Spoiler anzeigen

AutoIt

HotKeySet("{PAUSE}", "_PauseToggle") ; Pause zum Pausieren.
HotKeySet("{ESC}", "Terminate") ; Escape zum Beenden.


While 1
    Sleep(100)
WEnd


; das Äquivalent der Funktion aus dem Hilfe-Beispiel.
Func _PauseToggle($sTooltip = "*", $iX = 0, $iY = 0)
	Local $g_bPaused = _PauseSetState(0)
	If $g_bPaused Then
		$g_bPaused = _PauseSetState(-1)
		Return
	Else
		$g_bPaused = _PauseSetState(1)
	EndIf
	Do
		If IsDeclared("sTooltip") Then
			ToolTip($sTooltip, $iX, $iY)
		Else
			ToolTip("*", 0, 0)
		EndIf
		Sleep(300)
	Until Not _PauseSetState(0)
	ToolTip("")
EndFunc   ;==>_PauseToggle


; hier wird die Variable $g_bPaused verwaltet.
Func _PauseSetState($bStatus)
	Local Static $g_bPaused = False
	If $bStatus = 1 Then
		$g_bPaused = True
		Return $g_bPaused
	ElseIf $bStatus = -1 Then
		$g_bPaused = False
		Return $g_bPaused
	Else
		Return $g_bPaused
	EndIf
EndFunc   ;==>_PauseSetState


; zum Setzen einer Pause im Quelltext
Func _PauseSet($sTooltip = "*", $iX = 0, $iY = 0)
	_PauseSetState(-1)
	_PauseToggle($sTooltip)
EndFunc   ;==>_PauseSet


; aus der Hilfe
Func Terminate()
    Exit
EndFunc   ;==>Terminate

Alles anzeigen

Hat diese Methode neben dem erhöhten Aufwand größere Nachteile oder ist gar falsch?
Kennt ihr bessere Alternativen?

**Oscar**

Zu umständlich!
Einfach das Beispiel aus der Hilfe auf Local static umbauen:

AutoIt

#include <MsgBoxConstants.au3>


; Press Esc to terminate script, Pause/Break to "pause"


HotKeySet("{Pause}", "TogglePause")
HotKeySet("{ESC}", "Terminate")
HotKeySet("+!d", "ShowMessage") ; Shift-Alt-d


While 1
	Sleep(100)
WEnd


Func TogglePause()
	Local Static $bPaused = False
	$bPaused = Not $bPaused
	While $bPaused
		Sleep(100)
		ToolTip('Script is "Paused"', 0, 0)
	WEnd
	ToolTip("")
EndFunc   ;==>TogglePause


Func Terminate()
	Exit
EndFunc   ;==>Terminate


Func ShowMessage()
	MsgBox($MB_SYSTEMMODAL, "", "This is a message.")
EndFunc   ;==>ShowMessage

Alles anzeigen

**autoiter**

Hihi, ja das ist deutlich eleganter
Ich habe das einfach nach meinem Schema F gemacht, wenn ich aus verschiedenen Funktionen einen Status einer Variable oder Arraywertes auslesen will.
Aber prinzipiell Ok?

**Oscar**

Prinzipiell ist das ok, vor allem, wenn Du noch Parameter uebergeben willst (geht ja mit HotKeySet nicht).

Wobei ich persönlich finde, dass man es mit dem vermeiden von globalen Variablen auch übertreiben kann.
Natürlich sollten globale Variablen in UDFs nicht $i, $x, $y oder auch $iWidth oder so heißen, das führt zwangsläufig zu Problemen, aber wenn man die globalen Variablen zum Beispiel $g_iUDFnameWidth nennt, dann dürfte das kaum zu Namenskollisionen führen.
Und wenn man dann die globalen Variablen oben in der UDF gut sichtbar deklariert und kommentiert, dann kann man sich beim verwenden der UDF auch gut darauf einstellen.
Mir ist das lieber, als "wilde" Konstruktionen, die versuchen globale Variablen zu umgehen und damit den Code unleserlicher machen.
Wie gesagt, ist das meine persönliche Meinung dazu.

**autoiter**

Danke dir @Oscar für die Einschätzung. Ja, muss ich mir überlegen, ob ich meinem Spleen nachgebe und auf Teufel komm raus globale Variablen vermeide, oder ob ich mich an deine geschilderte Strategie halte. Schneller umgesetzt ist das allemal.

**BugFix**

Wenn man denn wirklich Globale Variablen vermeiden will, kann man das über ein Variablenmanagement tun.

**autoiter**

Hey vielen Dank @BugFix,
das finde ich super. Vor allem bei mehreren Variablen wird das sicher viel kompakter. So etwas habe ich bisher mit unterschiedlichen Funktionen und jeweils einem Array gemacht. Da kam dann so etwas heraus:

Spoiler anzeigen

AutoIt

Func __HintBoxes_HandlesArray($hGui = "", $iMode = 1)
	Local Static $aHandles[0]
	If $iMode Then
		_ArrayAdd($aHandles, $hGui)
	ElseIf $iMode = 2 Then
		If $hGui = "" Then
			Local $aDeleteHandles = $aHandles
			ReDim $aHandles[0]
			Return $aDeleteHandles
		Else
			$iIndex = _ArraySearch($aHandles, $hGui)
			If Not @error Then
				Local $aDeleteHandles[1] = [$aHandles[$iIndex]]
				_ArrayDelete($aHandles, $iIndex)
				Return $aDeleteHandles
			Else
				Return SetError(1)
			EndIf
		EndIf
	Else
		Return $aHandles
	EndIf
EndFunc   ;==>__HintBoxes_HandlesArray

Alles anzeigen

Ich werde deine Variante mal anwenden und sehen, wie mir das praktisch gefällt. Scripting.Dictionary gehört zu meinem passiven Wortschatz. Selbst aktiv angelegt und benutzt, habe ich noch keines..