Tooltip - Inhalt von Eingabefeld

DerSchatten

Kann mir jemand einen Tip geben wie ich als Tooltip den Inhalt eines Eingabefeldes anzeigen lassen kann?
Also das Teil wenn man mit dem Mauszeiger über ein Eingabefeld geht.

Ich habe es mal so probiert:

Code

GUICtrlCreateLabel("Verantwortlicher:", 10, 130, 150, 16, $SS_RIGHT)
$input_verantwortlicher = GUICtrlCreateInput("", 166, 127, 160, 22, $ES_READONLY)
GUICtrlSetColor(-1, $COLOR_BLUE)
GUICtrlSetTip(-1, GUICtrlRead($input_verantwortlicher))

Das funkt allerdings nicht.

**Oscar**

Doch, das geht schon! Du musst das nur jedes Mal als Tip eintragen, wenn sich im Inputfeld etwas ändert.

Meine Frage lautet hingegen: Warum als Tooltip genau das Gleiche eintragen, wie im Inputfeld? Was ergibt das für einen Sinn?

DerSchatten

Und wie setz ich das?
GUICtrlSetTip muß ja immer unter dem Inputfeld stehen, oder?
Oder kann man das auch aus einer anderen Stelle einem bestimmten Feld zuordnen?

Der Grund ist da das Eingabefeld zu kurz ist um manche Einträge komplett anzuzeigen. Kann es auch aus bestimmten Gründen nicht größer machen.
Der Tooltip sollte dann als Hilfe dienen den kompletten Inhalt anzuzeigen.

**Oscar**

Ok, das ist in der Tat ein Anwendungsfall.

Und nein, GuiCtrlSetTip muss nicht immer unter dem Inputfeld stehen. Der erste Parameter, den man dort übergibt, ist die Control-ID (die Rückgabe von GuiCtrlCreateInput) und somit kann man von überall aus dem Programm den ToolTip ändern.
Um dynamisch auf Benutzereingaben in dem Inputfeld reagieren zu können, kann man GuiRegisterMsg verwenden:

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $sMsg = 'Das ist ein ganz ganz langer Text, der garantiert nicht in das kleine Feld passt.'
GUICreate('Test', 400, 300)
Global $idInput = GUICtrlCreateInput($sMsg, 10, 10, 120, 20)
GUICtrlSetTip($idInput, GUICtrlRead($idInput))
GUISetState()
GUIRegisterMsg($WM_COMMAND, '_WM_COMMAND')


Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE


Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
	Local $nID = BitAND($wParam, 0x0000FFFF)
	If $nID = $idInput Then GUICtrlSetTip($idInput, GUICtrlRead($idInput))
	Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_COMMAND

Alles anzeigen

**BugFix**

Alternativ könntest du auch den Rechtsklick auf das Input auswerten und dann den Inhalt per MsgBox ausgeben.

**Bitnugger**

Oder so...

StatusBar

AutoIt

;-- TIME_STAMP   2017-06-21 06:48:49   v 0.1


#Region    ;************ Includes ************
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiStatusBar.au3>
#include <EditConstants.au3>
;~ #include <WinAPI.au3>
#EndRegion ;************ Includes ************


Global $g_hStatus, $g_tStruct = DllStructCreate($tagPOINT) ; Create a structure that defines the point to be checked.
Global $aParts[3] = [150, 220, -1]


Global $sMsg1 = 'Das ist ein ganz ganz langer Text, der garantiert nicht in das kleine Feld passt.'
Global $sMsg2 = 'Dieser Text ist noch viel länger, aber auch das ist nicht wirklich tragisch, solange er denn in die Statusbar passt... und falls dass auch nicht reicht, kann man den Text ja scrollen! ;-)'
Global $sMsg3 = 'Dieser Text wird nicht in der Statusbar angezeigt! /-('
Global $hGUI = GUICreate('Test', 1200, 100)
Global $idInput1 = GUICtrlCreateInput($sMsg1,  10, 10, 220, 20)
Global $hInput1  = ControlGetHandle($hGUI, '', $idInput1)
Global $idInput2 = GUICtrlCreateInput($sMsg2, 240, 10, 260, 20)
Global $hInput2  = ControlGetHandle($hGUI, '', $idInput2)
Global $idInput3 = GUICtrlCreateInput($sMsg3, 510, 10, 320, 20)
Global $idLabel = GUICtrlCreateLabel('Bewege die Maus über die Input-Controls oder aktiviere eines und ändere den Text...', 10, 50, 1180, 22)
GUICtrlSetFont(-1, 12)
GUISetState()
GUIRegisterMsg($WM_COMMAND, '_WM_COMMAND')


$g_hStatus = _GUICtrlStatusBar_Create($hGUI)
_GUICtrlStatusBar_SetParts($g_hStatus, $aParts)
_StatusBar_SetText(_WinAPI_GetClassName($hInput1), $idInput1, $sMsg1)


Global $ahIcons[2], $hWnd, $sFocus
$ahIcons[0] = _WinAPI_LoadShell32Icon(23) ; Extracts an icon from the shell32.dll file
$ahIcons[1] = _WinAPI_LoadShell32Icon(12)
_GUICtrlStatusBar_SetIcon($g_hStatus, 0, $ahIcons[0])
_GUICtrlStatusBar_SetIcon($g_hStatus, 1, $ahIcons[1])


While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_MOUSEMOVE
;~ 			ConsoleWrite('$GUI_EVENT_MOUSEMOVE' & @CRLF)
			_Position()
			$hWnd = _WinAPI_WindowFromPoint($g_tStruct)
			Switch $hWnd
				Case $hInput1
					_StatusBar_SetText(_WinAPI_GetClassName($hInput1), $idInput1, GUICtrlRead($idInput1))
				Case $hInput2
					_StatusBar_SetText(_WinAPI_GetClassName($hInput2), $idInput2, GUICtrlRead($idInput2))
				Case $hGUI
					$sFocus = ControlGetFocus($hGUI)
					Switch _WinAPI_GetDlgCtrlID(ControlGetHandle($hGUI, '', $sFocus))
						Case $idInput1
							_StatusBar_SetText(_WinAPI_GetClassName($hInput1), $idInput1, GUICtrlRead($idInput1))
						Case $idInput2
							_StatusBar_SetText(_WinAPI_GetClassName($hInput2), $idInput2, GUICtrlRead($idInput2))
						Case Else
							_StatusBar_SetText()
					EndSwitch
				Case Else
					_StatusBar_SetText()
			EndSwitch
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd


Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Local $iIDFrom = _WinAPI_LoWord ($wParam)
    Local $iCode   = _WinAPI_HiWord ($wParam)


	Switch $iIDFrom
		Case $idInput1, $idInput2
			Switch $iCode
				Case $EN_CHANGE, $EN_SETFOCUS
					_StatusBar_SetText(_WinAPI_GetClassName(ControlGetHandle($hGUI, '', $iIDFrom)), $iIDFrom, GUICtrlRead($iIDFrom))
				Case $EN_KILLFOCUS
					ConsoleWrite('$EN_KILLFOCUS: ' & ControlGetFocus($hGUI) & @CRLF)
			EndSwitch
		Case Else
			_StatusBar_SetText()
	EndSwitch


;~ 	ConsoleWrite('$iIDFrom   = ' & $iIDFrom & @CRLF)
;~ 	ConsoleWrite('$iCode     = ' & $iCode & @CRLF)
;~ 	ConsoleWrite('$idInput   = ' & $idInput & @CRLF)
;~ 	ConsoleWrite('$EN_CHANGE = ' & $EN_CHANGE & @CRLF)
	Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_COMMAND


Func _StatusBar_SetText($sPart1 = '', $sPart2 = '', $sPart3 = '')
	_GUICtrlStatusBar_SetText($g_hStatus, 'ClassName: ' & $sPart1)
	_GUICtrlStatusBar_SetText($g_hStatus, 'ID: ' & $sPart2, 1)
	_GUICtrlStatusBar_SetText($g_hStatus, $sPart3, 2)
EndFunc


Func _Position()
	Local $aMousePos = MouseGetPos()
    DllStructSetData($g_tStruct, "x", $aMousePos[0])
    DllStructSetData($g_tStruct, "y", $aMousePos[1])
EndFunc   ;==>Position

Alles anzeigen

**BugFix**

@Bitnugger: Da hast du es dir aber ziemlich kompliziert gemacht
Einen Großteil deines Codes kannst du eindampfen, wenn du GuiGetCursorInfo verwendest, um die ID zu ermitteln, über der sich die Maus bewegt.

Zitat von AutoIt-Hilfe

GUIGetCursorInfo

Gets the mouse cursor position relative to GUI window.

Success: a five-element array that containing the mouse cursor information:
$aArray[0] = X coord (horizontal)
$aArray[1] = Y coord (vertical)
$aArray[2] = Primary down (1 if pressed, 0 if not pressed)
$aArray[3] = Secondary down (1 if pressed, 0 if not pressed)
$aArray[4] = ID of the control that the mouse cursor is hovering over (or 0 if none)

**Bitnugger**

Zitat von BugFix

Bitnugger: Da hast du es dir aber ziemlich kompliziert gemacht
Einen Großteil deines Codes kannst du eindampfen, wenn du GuiGetCursorInfo verwendest, um die ID zu ermitteln, über der sich die Maus bewegt.

Oh ja. Dieses Beispiel hatte ich noch aus alten Zeiten als Code-Schnipsel hier rum liegen. GUIGetCursorInfo... wieso ich diese Funktion immer wieder aus den Augen verliere, ist mir ein Rätsel.

Hier die stark gekürzte Version...

StatusBar

AutoIt

;-- TIME_STAMP   2017-06-21 10:52:41   v 0.1


#Region    ;************ Includes ************
#Include <Array.au3>
#include <GUIConstantsEx.au3>
#include <GuiStatusBar.au3>
#include <WinAPIShellEx.au3>
#EndRegion ;************ Includes ************


Global $g_hStatus, $g_aParts[5] = [150, 220, 1150, 1230, -1]
Global $g_aIcons[4][3] = [['imageres.dll', 76, -1], ['imageres.dll', 77, -1], ['imageres.dll', 118, -1], ['setupapi.dll', 1, -1]], $g_aCursor, $g_idFocus


Global $g_aText = [ 'Das ist ein ganz ganz langer Text, der garantiert nicht in das kleine Feld passt.', _
					'Dieser Text ist noch viel länger, aber auch das ist nicht wirklich tragisch, solange er denn in die Statusbar passt... und falls dass auch nicht reicht, kann man den Text ja scrollen! ;-)', _
					'Dieser Text wird nicht in der Statusbar angezeigt! /-(']


Global $g_hGUI      = GUICreate('Test', 1280, 100)
Global $g_idInput1  = GUICtrlCreateInput($g_aText[0],  10, 10, 220, 20)
Global $g_idInput2  = GUICtrlCreateInput($g_aText[1], 240, 10, 260, 20)
Global $g_idInput3  = GUICtrlCreateInput($g_aText[2], 510, 10, 320, 20)
Global $g_idLabel   = GUICtrlCreateLabel('Bewege die Maus über die Input-Controls oder aktiviere eines und ändere den Text...', 10, 50, 1180, 22)
GUICtrlSetFont(-1, 12)
GUISetState()


$g_aCursor = GUIGetCursorInfo($g_hGUI)


$g_hStatus = _GUICtrlStatusBar_Create($g_hGUI)
_GUICtrlStatusBar_SetParts($g_hStatus, $g_aParts)
_StatusBar_SetText(_WinAPI_GetClassName(GUICtrlGetHandle($g_idInput1)), $g_idInput1, $g_aText[0])
For $i = 0 To UBound($g_aIcons) -1 Step 1
	$g_aIcons[$i][2] = _WinAPI_ShellExtractIcon($g_aIcons[$i][0], $g_aIcons[$i][1], 16, 16)
	_GUICtrlStatusBar_SetIcon($g_hStatus, $i, $g_aIcons[$i][2])
Next


While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $GUI_EVENT_MOUSEMOVE
			$g_aCursor = GUIGetCursorInfo($g_hGUI)
			$g_idFocus = $g_aCursor[4]
			Switch $g_idFocus
				Case $g_idInput1, $g_idInput2
					_StatusBar_SetText(_WinAPI_GetClassName(GUICtrlGetHandle($g_idFocus)), $g_idFocus, GUICtrlRead($g_idFocus))
				Case Else
					_StatusBar_SetText()
			EndSwitch
	EndSwitch
WEnd


Func _StatusBar_SetText($sPart1 = '', $sPart2 = '', $sPart3 = '')
	_GUICtrlStatusBar_SetText($g_hStatus, 'ClassName: ' & $sPart1)
	_GUICtrlStatusBar_SetText($g_hStatus, 'ID: ' & $sPart2, 1)
	_GUICtrlStatusBar_SetText($g_hStatus, $sPart3, 2)
	_GUICtrlStatusBar_SetText($g_hStatus, 'X: ' & StringRight('     ' & $g_aCursor[0], 6), 3)
	_GUICtrlStatusBar_SetText($g_hStatus, 'Y: ' & StringRight('     ' & $g_aCursor[1], 6), 4)
EndFunc

Alles anzeigen