[gelöst] Textlänge in Pixel ermitteln

BigRox

Hallo,
ich versuche die Länge eines Texte in Pixel zu ermitteln.
Dabei kann ich aber nicht einfach die Zeichenzahl verwenden, da der Text als proportionale Schrift angezeigt werden soll.
Der Text soll z.B. als SplashText angezeigt werden, wobei sich die Länge der Box automatisch an die Textlänge anpasst.

Dabei bin ich u.a. auf die Funktion "_GUICtrlListView_GetStringWidth($hListView, "Text")" gestoßen.
Diese Funktion gibt mir zwar die Pixelzahl zurück, aber sie braucht auch ein Handle zu einer ListBox, die ich aber nicht habe.
Ich vermute diese Handle wird von der Funktion benötigt, um die Schriftart die Schriftgröße usw. zu ermitteln.

Ich brauche also eine Funktion, die aus einem Text, der als String vorliegt, die Pixelzahl zurückgibt, die dieser String benötigt und die am besten alle zum ermitteln erforderlichen Werte selber aus z.B. der Registry (ich vermute mal, da steht alles erforderliche drin) auslesen kann.
Achja, die Funktion soll mit Windows 10 funktionieren.

MfG:
BigRox

BLinz

_StringWidth, Breite eines Labels herausfinden (vor dem Erstellen)

So etwas?

Oder auf Deutsch: TextMeter

**BugFix**

Dafür hatte ich mal folgende Funktion erstellt:

AutoIt

; #FUNCTION# ====================================================================================================================
; Name...........: _GetTextMeasure
; Description ...: Ermittelt den Platz zur Darstellung eines Textes unter Angabe von Größe, Attributen und Font
; Syntax.........: _MeasureText($sText, $iSize, $iStyle, $sFont)
; Parameters ....: $sText    Der auszumessende Text
;                  $iSize    Die Größe des Fonts in pt
;                  $iStyle   Kombination der Textattribute
;                            0 - Normal weight or thickness of the typeface (Standard)
;                            1 - Bold typeface
;                            2 - Italic typeface
;                            4 - Underline
;                            8 - Strikethrough
;                  $sFont    Name des verwendeten Fonts (Standard='Arial')
; Return values .: Array[Höhe, Breite]
; Author ........: BugFix ( AutoIt@bug-fix.info )
; ===============================================================================================================================
#include-once
#include <GDIPlus.au3>
Func _GetTextMeasure($sText, $iSize=8.5, $iStyle=0, $sFont='Microsoft Sans Serif')
	_GDIPlus_Startup()
	Local $hGUI = GUICreate("", 800, 400)
	GUISetState(@SW_HIDE, $hGUI)
    Local $hFormat = _GDIPlus_StringFormatCreate(0)
    Local $hFamily = _GDIPlus_FontFamilyCreate($sFont)
    Local $hFont = _GDIPlus_FontCreate($hFamily, $iSize, $iStyle, 3)
    Local $tLayout = _GDIPlus_RectFCreate(0, 0, 0, 0)
	Local $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    Local $aInfo = _GDIPlus_GraphicsMeasureString($hGraphic, $sText, $hFont, $tLayout, $hFormat)
    Local $iWidth = Ceiling(DllStructGetData($aInfo[0], "Width"))
    Local $iHeight = Ceiling(DllStructGetData($aInfo[0], "Height"))
	_GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_ShutDown()
	GUIDelete($hGUI)
	Local $aOut[2] = [$iHeight,$iWidth]
	Return $aOut
EndFunc  ;==>_GetTextMeasure

Alles anzeigen

**Oscar**

In der Hilfe zu _WinAPI_GetTextExtentPoint32 findet sich eine Funktion GetStringDimensions, mit der man die Stringlänge gut berechnen kann.
Und das ohne eine Hilfs-Gui erstellen zu müssen oder GDI+ zu bemühen.
Ich habe das Beispiel mal auf ein Label erweitert:

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>


Example()


Func Example()
	Local $hGUI = GUICreate("String height & width.")
	Local $idLabel = GUICtrlCreateLabel("---", 10, 10, 30, 20)
	GUICtrlSetBkColor(-1, 0xAAAAFF)
	GUICtrlSetFont(-1, 18, 400, 0, 'Arial')
	GUISetState(@SW_SHOW, $hGUI)


	Local $sText = "This is some text." ; The text we want to find the height & width of.
	Local $aStringDimension = GetStringDimensions(GUICtrlGetHandle($idLabel), $sText) ; Retrieve a 1 dimensional array with $aArray[0] = width & $aArray[1] = height.
	MsgBox($MB_SYSTEMMODAL, "String Height and Width", 'The height and width of the string "' & $sText & '" is:' & @CRLF & _
			"Width: " & $aStringDimension[0] & @CRLF & _
			"Height: " & $aStringDimension[1] & @CRLF)
	GUICtrlSetPos($idLabel, 10, 10, $aStringDimension[0], $aStringDimension[1])
	GUICtrlSetData($idLabel, $sText)
	Do
	Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example


Func GetStringDimensions($hWnd, $sText)
	Local $hDC = _WinAPI_GetDC($hWnd) ; Get the device context handle of the current window.
	Local $hFont = _SendMessage($hWnd, $WM_GETFONT) ; Retrieve the font with which the control is currently drawing its text.
	Local $hSelectObject = _WinAPI_SelectObject($hDC, $hFont) ; Select the object of the context device.
	Local $tSIZE = _WinAPI_GetTextExtentPoint32($hDC, $sText) ; Retrieve the height & width of a string.


	_WinAPI_SelectObject($hDC, $hSelectObject)
	_WinAPI_ReleaseDC($hWnd, $hDC) ; Release the device context.
	Local $aReturn[2] = [DllStructGetData($tSIZE, 1), DllStructGetData($tSIZE, 2)] ; Set an array with the width & height of the string.
	Return $aReturn
EndFunc   ;==>GetStringDimensions

Alles anzeigen

**BugFix**

Ja, Oscar - ich glaube über die Funktion hatten wir schon mal gesprochen. Sie ermöglicht aber nicht, die Textlänge vor Erstellen des Ctrl zu ermitteln. Ist ja klar - irgendwo muß der Text ja mit seiner Formatierung abgemessen werden.
Wenn du verschiedene Texte in einem Ctrl anzeigen möchtest, brauchst du die max. Länge um folgende Ctrl genau positionieren zu können. Also eher eine Funktion, die während der Skriptentwicklung Anwendung findet, weniger im fertigen Skript.

BigRox

Hallo BugFix und Oscar,
DANKE für eure Antworten

Ich versuch es mal mit der Funktion von BugFix.
Die Funktion funktioniert ganz gut.

Nur eins ist mir dabei nicht so ganz klar.
Wenn GDI+ schon vorm Aufruf der Funktion mit _GDIPlus_Startup() gestartet wurde, beendet dies Funktion dann einfach GDI+, weil da ja am Ende _GDIPlus_ShutDown() aufgerufen wird, oder läuft GDI+ auch nach dieser Funktion dann noch weiter, da ja dann auch noch einige GDI+-Objekte existieren ?

MfG:
BigRox

**BugFix**

Zitat von BigRox

Wenn GDI+ schon vorm Aufruf der Funktion mit _GDIPlus_Startup() gestartet wurde, beendet dies Funktion dann einfach GDI+, weil da ja am Ende _GDIPlus_ShutDown() aufgerufen wird, oder läuft GDI+ auch nach dieser Funktion dann noch weiter, da ja dann auch noch einige GDI+-Objekte existieren ?

Der Mechanismus ist folgender:
Über einen UDF-internen Zähler wird festgestellt, wie oft StartUp bzw. ShutDown aufgerufen wird. Dabei wird der Zähler rauf/runter gesetzt. Nur wenn er bei 0 ist, wird beim ShutDown auch die Dll geschlossen.

BigRox

Hallo BugFix,
DANKE für die Erklärung dieser Sache.

MfG:
BigRox