Listview - Hintergrundfarbe einer Zeile setzen ohne den weißen Zwischenraum davor?

BLinz

Ich will ein Listview einsetzen um Statusmeldungen anzuzeigen. Je nach Schweregrade werden die Zeilen unterschiedlich eingefärbt.

Soweit kein Problem.

Mir ist aufgefallen das aber nicht die gesamte Zeile eingefärbt wird sondern das davor immer ein Bereich von 5 Pixeln weiß bleibt.

Kann man das verhindern / Kaschieren?

Hier ein Beispiel:

AutoIt: ListViewFarben.au3

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate("listview items", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
    GUISetBkColor(0x00E0FFFF) ; will change background color

    Local $idListview = GUICtrlCreateListView("col1  |col2|col3  ", 10, 10, 200, 150) ;,$LVS_SORTDESCENDING)
    Local $idButton = GUICtrlCreateButton("Value?", 75, 170, 70, 20)
    Local $idItem1 = GUICtrlCreateListViewItem("item2|col22|col23", $idListview)
    GUICtrlSetBkColor($idItem1, 0xE97659)
    Local $idItem2 = GUICtrlCreateListViewItem("item1|col12|col13", $idListview)
    GUICtrlSetBkColor($idItem2, 0x7499FF)
    Local $idItem3 = GUICtrlCreateListViewItem("item3|col32|col33", $idListview)
    GUICtrlCreateInput("", 20, 200, 150)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED) ; to allow drag and dropping
    GUISetState(@SW_SHOW)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $idButton
                MsgBox($MB_SYSTEMMODAL, "listview item", GUICtrlRead(GUICtrlRead($idListview)), 2)

            Case $idListview
                MsgBox($MB_SYSTEMMODAL, "listview", "clicked=" & GUICtrlGetState($idListview), 2)

        EndSwitch
    WEnd
EndFunc   ;==>Example

Alles anzeigen

Die erste Zeile ist rötlich - doch davor bleiben 5 Pixel weiß.

Gruß,

BLinz

**Musashi**

Hallo BLinz !

Ich habe, wie Du sicher auch, etwas mit den Styles und ExStyles von GUICtrlCreateListView herum experimentiert.

Um es gleich vorweg zu sagen, ohne sichtbaren Erfolg.

Dann habe ich mal die Standard-UDF GuiListView.au3 eingebunden. Damit kann man sich z.B. mittels :

ConsoleWrite("Item 1 X=" & _GUICtrlListView_GetItemPositionX($idListview, 0) & " Y=" & _GUICtrlListView_GetItemPositionY($idListview, 0) & @CRLF)

ConsoleWrite("Item 2 X=" & _GUICtrlListView_GetItemPositionX($idListview, 1) & " Y=" & _GUICtrlListView_GetItemPositionY($idListview, 1) & @CRLF)

ConsoleWrite("Item 3 X=" & _GUICtrlListView_GetItemPositionX($idListview, 2) & " Y=" & _GUICtrlListView_GetItemPositionY($idListview, 2) & @CRLF)

die X-Positionen der ListViewItems ansehen - diese beträgt bei allen Zeilen 4, was ggf. zu der Lücke führt ?!?

Mit z.B. _GUICtrlListView_SetItemPosition ließ sich die Lücke aber auch nicht schließen.

Ich könnte mir denken, dass es da einen geschützten Bereich für einen optionalen Rahmen gibt.

Das alles ist natürlich ein einziger Konjunktiv und keine Antwort. Ich hatte überlegt, ob ich überhaupt einen Beitrag poste .

Vielleicht findest Du darin aber ein Körnchen Info, das Dich weiterbringt.

Gruß Musashi

wollekuh

Ich weiss zwar nicht warum er diese Art Border zieht, aber die einfachste Lösung wäre wohl das:

Local $idListview = GUICtrlCreateListView("col1 |col2|col3 ", -6, 10, 200, 150) ;,$LVS_SORTDESCENDING)

-6 fand ich am passendsten

**Musashi**

Hallo wollekuh !

Das 'löst' das Problem zwar optisch, da man das Listview-Element einfach links aus der GUI herausschiebt.

Ich bin mir aber sicher, dass BLinz das Element innerhalb der GUI positionieren möchte.

Gruß Musashi

**alpines**

Wenn man eine Extraspalte hinzufügt und die Breite besagter Spalte 0 setzt, dann kommt man auf einen Pixel runter, das ist eigentlich ein Standardmargin für Windowselemente.

[Blockierte Grafik: https://i.imgur.com/suSVMCG.png]

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
Example()

Func Example()
    GUICreate("listview items", 220, 250, 100, 200, -1, $WS_EX_ACCEPTFILES)
    GUISetBkColor(0x00E0FFFF) ; will change background color

    Local $idListview = GUICtrlCreateListView("|col1  |col2|col3  ", 10, 10, 200, 150) ;,$LVS_SORTDESCENDING)
    _GUICtrlListView_SetColumnWidth($idListview, 0, 0)
    Local $idButton = GUICtrlCreateButton("Value?", 75, 170, 70, 20)
    Local $idItem1 = GUICtrlCreateListViewItem("|item2|col22|col23", $idListview)
    GUICtrlSetBkColor($idItem1, 0xE97659)
    Local $idItem2 = GUICtrlCreateListViewItem("|item1|col12|col13", $idListview)
    GUICtrlSetBkColor($idItem2, 0x7499FF)
    Local $idItem3 = GUICtrlCreateListViewItem("|item3|col32|col33", $idListview)
    GUICtrlCreateInput("", 20, 200, 150)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED) ; to allow drag and dropping
    GUISetState(@SW_SHOW)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $idButton
                MsgBox($MB_SYSTEMMODAL, "listview item", GUICtrlRead(GUICtrlRead($idListview)), 2)

            Case $idListview
                MsgBox($MB_SYSTEMMODAL, "listview", "clicked=" & GUICtrlGetState($idListview), 2)

        EndSwitch
    WEnd
EndFunc   ;==>Example

Alles anzeigen

**Musashi**

Zitat von alpines

Wenn man eine Extraspalte hinzufügt und die Breite besagter Spalte 0 setzt, dann kommt man auf einen Pixel runter, das ist eigentlich ein Standardmargin für Windowselemente.

Sieht doch gut aus, also ich wäre damit völlig zufrieden!

Gruß Musashi

**alpines**

Das einzige was vielleicht nerven könnte ist das Resizen der Header. Man kann den 1. nämlich von 0 auf x Pixel ziehen und so eine Lücke herstellen.

Wenn man das Resizen generell verhindert ist das sicherlich kein Problem, wenn man das Resizen der anderen allerdings erlauben möchte, dann muss man

das Event dafür hooken und schauen an welchem Header man gerade resized und je nachdem es sperren oder gewähren lassen.

BLinz

alpines Lösung mit der extra Spalte die man auf 0 setzt ist perfekt! Da ich die Header eh ausblende kann da auch keiner Unsinn treiben.

Musashi Lösung behalte ich aber im Hinterkopf. Könnte ich bei mir ebenfalls einsetzen (da ohne Header)

Danke!