Checkbox schalten über das Internet - vergleichbar mit Schach online

Banana_2_Day

Hallo,

auf einer AutoIt-Oberfläche gibt es 2 Checkboxen (später viel mehr).

(x) Brot

(x) Butter

Wird eine Checkbox angeklickt, ändert sich der Status checked <-> unchecked.

Solange die Anwendung auf einem Computer läuft, ist das kein Problem.

Ich suche eine Lösung, wie das ganze bei zwei Computern über eine Internetverbindung funktionieren kann.

Die IP des entfernten Computers ist bekannt.

A ändert den Status einer Checkbox und auf beiden Computern A und B ist der neue Status zu sehen.

B ändert den Status einer Checkbox und auf beiden Computern A und B ist der neue Status zu sehen.

Wie synchronisiere ich auf diese Weise die Anzeige von der Oberfläche zwei Programme über das Internet?

Welche Beispiele kennt Ihr, die ich mir hierzu ansehen kann?

Im Prinzip müsste das genauso funktionieren, wie zum Beispiel ein Schachprogramm über das Internet.

Wobei wahrscheinlich in einem Schachprogramm viel zu viele Scriptzeilen stecken, um das zu verstehen.

**BugFix**

Schau mal in der Hilfe die Bsp. zu TCPRec() oder auch UDPRec() an. Du brauchst in beiden Fällen Server und Client um Daten in beiden Richtungen senden und empfangen zu können.

Banana_2_Day

Zitat von BugFix

Schau mal in der Hilfe die Bsp. zu TCPRec() oder auch UDPRec() an. Du brauchst in beiden Fällen Server und Client um Daten in beiden Richtungen senden und empfangen zu können.

Vielen Dank. Ich habe ein wenig Grundlagen-Erfahrungen.

Ich kann mit AutoIt übers Internet Dateien senden und abrufen (Router, Portfreigabe ...).

Habe bisher kein einfaches AutoIt Online-Schach-Script oder "Schiffe versenken" gefunden.

Bei diesen Spielen werden wechselseitig Daten übertragen und die Oberfläche aktualisiert.

Dachte, ich könne dort etwas über die wechselseitige Aktualisierung der Daten übers Internet erfahren.

Das einfachste Script wäre eine geteilte Oberfläche für Rechner A und B und je einem lächelnden und einem weinenden :-).

Jeder kann auswählen, wie es ihm geht und wenn beide ein positives oder negatives ausgewählt haben, wird bei beiden eine entsprechende Musik abgespielt

**BugFix**

Wenn du schon Erfahrungen hast, geht es also darum, den richtigen Weg zu finden.

- auf beiden PC brauchst du Server und Client

- jeweils an unterschiedlichem Port

- definiere ein Protokoll

z. B. könntest du nach folgendem Muster senden: '1#1056#NACHRICHT#0'

# = Trennzeichen

1 = beginne zu senden

1056 = Anzahl Bytes der Sendung (gesamter String)

NACHRICHT = die Nachricht selbst

0 = fertig mit senden

Der Empfänger bestätigt dann mit der empfangenen Bytezahl (worauf der Sender wartet). Wird diese Nachricht mit falschem Wert oder außerhalb eines Zeitfensters empfangen, wird erneut gesendet.

Ich meine mich zu erinnern, dass hier im Forum ein Bsp. zur Interprozesskommunikation existiert, welches auf TCP Basis arbeitet. Such einfach mal.

**Musashi**

Zitat von BugFix

Ich meine mich zu erinnern, dass hier im Forum ein Bsp. zur Interprozesskommunikation existiert, welches auf TCP Basis arbeitet. Such einfach mal.

Banana_2_Day !

Kleiner Tipp (kennst Du wahrscheinlich bereits) :

Wenn Du bei Google autoit Interprozesskommunikation tcp site:autoit.de eingibst, dann müsste Treffer 1 oder 2 bereits das von BugFix angesprochene Beispiel sein.

Gruß Musashi

Banana_2_Day

Zitat von Musashi

das von BugFix angesprochene Beispiel

Danke. Ich glaube, folgendes ist es - ich lese mich gerade ein.Eine neue Erfahrung.

Interprozesskommunikation

**Oscar**

Oh, ich weiß nicht, ob das Script noch funktioniert!

Damals ging es, aber an den TCP-Befehlen wurde etwas geändert (AFAIR).

Ich kann's jetzt gerade nicht testen. Eventuell komme ich nachher dazu. Melde mich dann nochmal...

**Oscar**

So, ich hatte jetzt mal etwas Zeit, um das Script zu testen. Es funktioniert also doch noch.

Um Dir aber mal ein Beispiel für ein Server-/Client-Programm zu zeigen, habe ich mal eine Checkbox eingebaut.

Wenn man die Checkbox beim Client (de-)aktiviert, wird sie auch beim Server (de-)aktiviert.

C

#include <GUIConstantsEx.au3>
#include <Misc.au3>
Global $sTitle = 'Interprozesskommunikation' ; Programmname (für _Singleton)
Global $sIPAddress = '127.0.0.1' ; Localhost-IP-Adresse
Global $iPort = 55555 ; beliebige Portnummer (sollte im Bereich zwischen 49152 und 65535 liegen)
Global $hGui, $idInput, $idCheckbox, $MainSocket, $ConnectedSocket = -1, $sData, $sRecv, $iPID

TCPStartup()
If _Singleton($sTitle, 1) = 0 Then ; wenn Server bereits gestartet, dann hier als Client weitermachen
    $ConnectedSocket = TCPConnect($sIPAddress, $iPort) ; Verbindung zum Server herstellen
    If @error Then ; wenn nicht erfolgreich, dann Client beenden mit Fehlermeldung
        MsgBox(16, 'FEHLER!', 'TCPConnect fehlgeschlagen! Fehlernr.: ' & @error)
    Else ; TCP-Verbindung war erfolgreich
        $hGui = GUICreate($sTitle & ' - Client', 360, 80)
        $idCheckbox = GUICtrlCreateCheckbox('Checkbox', 10, 10, 120, 20)
        $idInput = GUICtrlCreateInput('', 10, 40, 340, 20)
        GUISetState(@SW_SHOW, $hGui)
        While True
            $sRecv = TCPRecv($ConnectedSocket, 2048) ; Daten abholen
            If $sRecv <> '' Then
                $sRecv = BinaryToString($sRecv, 4) ; Daten umwandeln
                If StringLeft($sRecv, 2) = 'cb' Then ; wenn Kommando "cb" empfangen, dann die folgende Zahl (1 oder 0) auswerten
                    GUICtrlSetState($idCheckbox, StringMid($sRecv, 3, 1) = '1' ? $GUI_CHECKED : $GUI_UNCHECKED)
                EndIf
            EndIf
            Switch GUIGetMsg()
                Case $GUI_EVENT_CLOSE
                    ExitLoop
                Case $idCheckbox
                    $sData = BitAND(GUICtrlRead($idCheckbox), $GUI_CHECKED) ? 'cb1' : 'cb0'
                    TCPSend($ConnectedSocket, StringToBinary($sData, 4)) ; Daten an den Server senden
                Case $idInput
                    $sData = GUICtrlRead($idInput)
                    TCPSend($ConnectedSocket, StringToBinary($sData, 4)) ; Daten an den Server senden
            EndSwitch
        WEnd
        TCPCloseSocket($ConnectedSocket) ; Verbindung zum Server trennen
    EndIf
Else ; Server läuft noch nicht, also Server starten
    $hGui = GUICreate($sTitle & ' - Server', 360, 480)
    $idCheckbox = GUICtrlCreateCheckbox('Checkbox', 10, 10, 340, 20)
    $idInput = GUICtrlCreateEdit('', 10, 40, 340, 430)
    GUISetState(@SW_SHOW, $hGui)
    $MainSocket = TCPListen($sIPAddress, $iPort)
    If $MainSocket = -1 Then Exit MsgBox(0, $sTitle, 'Server konnte nicht gestartet werden!')
    GUICtrlSetData($idInput, '> Server gestartet!' & @CRLF, 1)
    GUICtrlSetData($idInput, '> Starte Client...' & @CRLF, 1)
    Run(@AutoItExe & ' "' & @ScriptFullPath & '"') ; starte das Script nochmal (als Client)
    If @error Then Exit MsgBox(0, $sTitle, 'Client konnte nicht gestartet werden.')
    GUICtrlSetData($idInput, '> Client gestartet.' & @CRLF, 1)
    While True ; in dieser Schleife wartet der Server auf Daten und es wird GUIGetMsg abgefragt
        If $ConnectedSocket = -1 Then ; wenn noch keine Verbindung hergestellt wurde, dann..
            $ConnectedSocket = TCPAccept($MainSocket) ; abfragen, ob sich der Client verbunden hat
            If $ConnectedSocket <> -1 Then ; wenn Verbindung hergestellt, dann Meldung ausgeben
                GUICtrlSetData($idInput, '> Verbindung hergestellt.' & @CRLF, 1)
                GUICtrlSetData($idInput, '> Warte auf Daten...' & @CRLF, 1)
            EndIf
        Else ; Verbindung ist hergestellt
            $sRecv = TCPRecv($ConnectedSocket, 2048) ; Daten abholen
            If @error Then ; wenn dabei ein Fehler aufgetreten ist, dann ist die Verbindung unterbrochen (Client beendet)
                $ConnectedSocket = -1
                GUICtrlSetData($idInput, '> Verbindung unterbrochen.' & @CRLF, 1)
                GUICtrlSetData($idInput, '> Warte auf Verbindung...' & @CRLF, 1)
            Else ; Daten wurden korrekt empfangen
                $sRecv = BinaryToString($sRecv, 4) ; Daten umwandeln
                If $sRecv <> '' Then
                    GUICtrlSetData($idInput, $sRecv & @CRLF, 1) ; und im Editfeld ausgeben
                    If StringLeft($sRecv, 2) = 'cb' Then ; wenn Kommando "cb" empfangen, dann die folgende Zahl (1 oder 0) auswerten
                        GUICtrlSetState($idCheckbox, StringMid($sRecv, 3, 1) = '1' ? $GUI_CHECKED : $GUI_UNCHECKED)
                    EndIf
                EndIf
            EndIf
        EndIf
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idCheckbox
                $sData = BitAND(GUICtrlRead($idCheckbox), $GUI_CHECKED) ? 'cb1' : 'cb0'
                TCPSend($ConnectedSocket, StringToBinary($sData, 4)) ; Daten an den Server senden
        EndSwitch
    WEnd
    GUICtrlSetData($idInput, '> Verbindung getrennt.' & @CRLF, 1)
    GUICtrlSetData($idInput, '> Server wird beendet.' & @CRLF, 1)
    TCPCloseSocket($ConnectedSocket)
    Sleep(1000)
EndIf
TCPShutdown()
Exit

Alles anzeigen

Banana_2_Day

Vielen Dank Oscar, das sieht sehr interessant aus.

Banana_2_Day

Zitat von Oscar

Wenn man die Checkbox beim Client (de-)aktiviert, wird sie auch beim Server (de-)aktiviert.

Auf lokaler Ebene funktioniert das 1a.

Ich habe versucht, das ganze für einen Zugriff übers Internet umzuschreiben.

Ich habe mich hoffnungslos in Endlos-Schleifen verfangen.

Kannst Du Dein Skript ein wenig dahingehend umschreiben, dass es geteilt ist in Client und Server?

Ein Verbindungsaufbau soll erst dann gestartet werden, wenn auf beiden Rechnern das Programm gestartet wurde.

Port im Router habe ich freigeschaltet.

Global $sIPAddress = "test.ddns.net"

If @Computername = "A" Then

$PC = "Server"

Else

$PC = "Client"

EndIf

Ich versuche zwischenzeitlich weiterzukommen. Wenn ich erfolgreich bin, ergänze ich meinen Post.

**Oscar**

Zitat von Banana_2_Day

Kannst Du Dein Skript ein wenig dahingehend umschreiben, dass es geteilt ist in Client und Server?

Ok! Findest Du als Anhang.

Die "Server.au3" musst Du erst compilieren und dann starten. Anschließend kannst Du die "Client.au3" ausführen (geht auch als Script).

Im Clientprogramm gibt es einen Button zum connecten mit dem Server. Dort musst Du noch Deine DynDns-Adresse eintragen (IP-Adresse wird vom Programm ermittelt).

Die DynDns-Konfiguration und die Port-Weiterleitung im Router hast Du ja bereits vorgenommen.

Banana_2_Day

Zitat von Oscar

Button zum connecten mit dem Server

Nach kurzer Einarbeitung funktionierte das Skript sofort. Danke Oscar!

BugFix 1. August 2019 um 08:49