Hallo liebes Forum,
Ich erläutere kurz und knapp mein Vorhaben:
Ich habe eine Datenbank mit hilfe von sqlite gebaut und zeige Sie grafisch als Listview an.
Jetzt möchte ich eine ganze Spalte (Name) auslesen und in ein Array speichern. Soll den Sinn haben, das ich die Userliste nicht extra als Datensatz anlegen muss.
Sie Screenshot
Es ist bestimmt kurz und einfach... Wäre cool wenn Ihr kurz helfen würdet.
Schöne Grüße
Das geht ganz einfach mit _SQLite_GetTable. In der AutoIt-Hilfe findest du auch ein Bsp. dazu.
Hier habe ich mal das Bsp. aus der Hilfe ein wenig geändert, so dass nur die Spalte Name in ein Array kopiert wird.
;-- TIME_STAMP 2019-10-19 17:51:43 v 0.1
#include <Array.au3>
#include <MsgBoxConstants.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>
Local $aResult, $iRows, $iColumns, $iRval
_SQLite_Startup()
If @error Then
MsgBox($MB_SYSTEMMODAL, "SQLite Error", "SQLite.dll Can't be Loaded!")
Exit -1
EndIf
ConsoleWrite("_SQLite_LibVersion=" & _SQLite_LibVersion() & @CRLF)
_SQLite_Open() ; Open a :memory: database
If @error Then
MsgBox($MB_SYSTEMMODAL, "SQLite Error", "Can't Load Database!")
Exit -1
EndIf
; Example Table
; Name | Age
; -----------------------
; Alice | 43
; Bob | 28
; Cindy | 21
If Not _SQLite_Exec(-1, "CREATE TEMP TABLE persons (Name, Age);") = $SQLITE_OK Then _
MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Alice','43');") = $SQLITE_OK Then _
MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Bob','28');") = $SQLITE_OK Then _
MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Cindy','21');") = $SQLITE_OK Then _
MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
; Query
;~ $iRval = _SQLite_GetTable(-1, "SELECT * FROM persons;", $aResult, $iRows, $iColumns) ; kopiert die komplette Tabelle in ein Array
$iRval = _SQLite_GetTable(-1, "SELECT Name FROM persons;", $aResult, $iRows, $iColumns) ; kopiert nur die Spalte Name in ein Array
If $iRval = $SQLITE_OK Then
; $aResult Looks Like this:
; [0] = 4
; [1] = Name
; [3] = Alice
; [5] = Bob
; [7] = Cindy
_ArrayDisplay($aResult, "Query Result")
Else
MsgBox($MB_SYSTEMMODAL, "SQLite Error: " & $iRval, _SQLite_ErrMsg())
EndIf
_SQLite_Close()
_SQLite_Shutdown()Danke 
Ich habe nichts anderes erwartet. Geht VIELEN DANK