Button frei wählbare Funktion

JST

Hi zusammen,

bin neu hier und will Programmieren lernen.

Erst Frage:

Ist es möglich eine Taste so zu erstellen das diese erst beim anklicken eine funktion bekommt.

Bsp: Taste anklicken --> auswahl der Funktion --> " Datei / Textdokumet / Programm "

und diese sollte auch wieder neu belegt werden können.

Gruß

Stefan

**Moombas**

Mit "Taste" meinst du denke ich einen Button.

Das könnte z.B. so funktionieren: (ungetestet und noch unvollständig):

Code

;Nur auf den Button bezogen!
Local $idButton = GUICtrlCreateButton("Bla", 210, 170, 85, 25) ;Button erstellen

While 1
    Switch GUIGetMsg()
        Case $idButton
             if $Programm = "" then
                 $Programm = 'notepad.exe' ;hier könntest du stattdessen den entsprechenden Dialog einbauen
             else
                 Run($Programm, "", @SW_SHOWMAXIMIZED)
             Endif
    EndSwitch
WEnd

Alles anzeigen

Über eine andere Taste müsstest du dann diese "Einstellung" revidieren, also $Programm = "" setzen (in meinem Beispiel) um diese neu belegen zu können.

Alternativ kann man das auch ggf. über eine Ini-Datei machen, dann wären die Einstellungen nach dem Programmende noch erhalten (sofern gewollt).

JST

Hi hab es gerade getestet aber es funktioniert nicht.

dachte an sowas.

Bild:

Der Inhalt kann nicht angezeigt werden, da du keine Berechtigung hast, diesen Inhalt zu sehen.

C

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Button frei wählbare Funktion", 366, 214, 192, 124)
$Button1 = GUICtrlCreateButton("1 ?", 24, 88, 75, 25, 0)
GUICtrlSetFont(-1, 12, 400, 0, "Arial")
$Button2 = GUICtrlCreateButton("2 ?", 24, 120, 75, 25, 0)
GUICtrlSetFont(-1, 12, 400, 0, "Arial")
$Button3 = GUICtrlCreateButton("3 ?", 24, 152, 75, 25, 0)
GUICtrlSetFont(-1, 12, 400, 0, "Arial")
$Button = GUICtrlCreateLabel("Button", 20, 20, 48, 22)
GUICtrlSetFont(-1, 12, 400, 0, "Arial")
$anzahl = GUICtrlCreateCombo("anzahl", 76, 16, 77, 25)
GUICtrlSetFont(-1, 12, 400, 0, "Arial")
GUICtrlSetState(-1, $GUI_DISABLE)
$Butto = GUICtrlCreateRadio("Button Resten", 168, 20, 113, 17)
GUICtrlSetFont(-1, 12, 400, 0, "Arial")
$Radio1 = GUICtrlCreateRadio("Button neue Funktion", 168, 44, 161, 17)
GUICtrlSetFont(-1, 12, 400, 0, "Arial")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit


EndSwitch
WEnd

Alles anzeigen

**autoiter**

Hallo JST

Zitat von JST

Bsp: Taste anklicken --> auswahl der Funktion --> " Datei / Textdokumet / Programm "

Willst du einfach irgendeinen Bsp-Code oder ist das eine Programmieranfrage?
Wenn es letzteres ist, müsstest du beschreiben, wie du es dir vorstellst.

**BugFix**

Ich denke, das hier ist, was du willst:

AutoIt

Global $INI = @ScriptDir & '\test_button.ini'

Global $hGui = GUICreate('Test')

Global $cbReSet = GUICtrlCreateCheckbox('(Re)Set Button', 20, 15, 160)

Global $bt_1 = GUICtrlCreateButton('', 10, 60, 100, 20)
Global $sTitle_Btn1 = IniRead($INI, 'btn1', 'title', 'Frei')
GUICtrlSetData($bt_1, $sTitle_Btn1)

Global $bt_2 = GUICtrlCreateButton('', 10, 90, 100, 20)
Global $sTitle_Btn2 = IniRead($INI, 'btn2', 'title', 'Frei')
GUICtrlSetData($bt_2, $sTitle_Btn2)

GUISetState()

Global $nMsg
While True
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case -3
            Exit
        Case $bt_1
            _Check($bt_1, 'btn1')
        Case $bt_2
            _Check($bt_2, 'btn2')
    EndSwitch
WEnd


Func _Check($_ID, $_sSection)
    Local $sTitle = GUICtrlRead($_ID)
    Local $bSet = BitAND(GUICtrlRead($cbReSet), $GUI_CHECKED), $sExe
    If $bSet Then
        $sExe = _SelectFile($sTitle, $_sSection)
        If @error Then Return
        GUICtrlSetData($_ID, $sTitle)
    Else
        $sExe = IniRead($INI, $_sSection, 'program', '')
    EndIf
    If $sExe <> '' Then ShellExecute($sExe)
EndFunc

Func _SelectFile(ByRef $_sTitle, $_sSection)
    Local $sExe = FileOpenDialog('Programm wählen', @ProgramFilesDir, 'EXE (*.exe)')
    If @error Then Return SetError(@error,0,'')
    $_sTitle = StringTrimLeft(StringLeft($sExe, StringInStr($sExe, '.', 0, -1)-1), StringInStr($sExe, '\', 0, -1))
    IniWrite($INI, $_sSection, 'program', $sExe)
    IniWrite($INI, $_sSection, 'title', $_sTitle)
    Return $sExe
EndFunc

Alles anzeigen

**Moombas**

Ok, ich bin natürlich davon ausgegangen das du den Button drückst -> Wenn keine Funktion zugewiesen-> Funktion zuweisen (ggf. über gesonderten Dialog) sonst: Funktion ausführen.

Der Einfachheit halber habe ich eine Programmausführung genommen.

Ich hatte das mit der EXE ja nur als Beispiel genommen. Aber deinem Screenshot nach willst du ja programmierte Funktionen dynamisch zuweisen richtig?

Zitat von autoiter

Hallo JST
Willst du einfach irgendeinen Bsp-Code oder ist das eine Programmieranfrage?
Wenn es letzteres ist, müsstest du beschreiben, wie du es dir vorstellst.

Wenn er "programmieren lernen" möchte, wäre eine reine Programmieranfrage irgendwie kontraproduktiv

JST 28. November 2019 um 19:59