Array mit Arrays

Bernhard65

Hallo an Alle,

ich habe leider wieder ein kleines (Verständnis) Problem.

Ich würde gerne ein Array mit Arrays als Inhalt erstellen.

Funktioniert ja soweit eigentlich, aber wenn ich auf das innere Array schreiben will geht das nur über einen Funktionsaufruf mit Variable ByRef.

Ist das die einzige Lösung?

Ich habe früher viel in C programmiert und da geht das mit Pointer etwas einfacher...

Schaut euch bitte mal mein Beispiel an.

(Es ist nur ein Beispiel, ohne tieferen Sinn)

Das Array-Tut von BugFix hab ich gelesen, aber leider greift er bei seinem Beispiel nur lesend auf das innere Array zu.

Vermutlich geht das doch einfacher oder vielleicht gibts dafür eine UDF.

Sorry, aber wie gesagt ich komme von C und muss mich noch etwas einarbeiten.

Bitte um Aufklärung,

Danke.

AutoIt: Array mit Arrays Beispiel

#include <Array.au3>

Global $aWochentage[][] = _
[ _
[ 1, "Montag","Monday"], _
[ 2, "Dienstag","Tuesday"], _
[ 3, "Mittwoch","Wednesday"], _
[ 4, "Donnerstag","Thursday"], _
[ 5, "Freitag","Friday"], _
[ 6, "Samstag","Saturday"], _
[ 7, "Sonntag","Sunday" ] _
]

Global $aMonate[][] = _
[ _
[1, "Januar","January"], _
[2, "Februar","February"], _
[3, "März","March"], _
[4, "April","April"], _
[5, "Mai","May"], _
[6, "Juni","June"], _
[7, "Juli","July"], _
[8, "August","August"], _
[9, "September","September"], _
[10,"Oktober","October"], _
[11,"November","November"], _
[12,"Dezember","December"] _
]

Global $aDatum[] = [$aWochentage,$aMonate]

; Array mit zwei Arrays
_ArrayDisplay($aDatum,"Array mit zwei Arrays")

; Erstes innere Array
_ArrayDisplay($aDatum[0],"Wochentage (Original)")

; Zweites innere Array
_ArrayDisplay($aDatum[1],"Monate (Original)")

; wäre schön, geht aber nicht
;($aDatum[0])[0][1] = "Neuer Montag"


; Temp-Array vom ersten inneren Array erzeugen
Global $aTemp = $aDatum[0]
; dies ist jetzt aber nur eine Kopie vom Array $aWochentage
$aTemp[0][1] = "Neuer Montag"

; Array $aTemp hat sich geändert
_ArrayDisplay($aTemp,"$aTemp")

; Array $aWochentage hat sich (natürlich) nicht geändert
_ArrayDisplay($aDatum[0],"Wochentage (nicht geändert)")


; Wie schreib ich den nun in Array $aWochentage???
; Geht das nur über einen Funktionsaufruf ?

Schreib_in_inneres_Array($aDatum[0])

; Array $aWochentage hat sich (natürlich) nicht geändert
_ArrayDisplay($aDatum[0],"Wochentage (geändert)")



Func Schreib_in_inneres_Array(ByRef $aArray)
$aArray[0][1] = "Neuer Montag"
EndFunc

Alles anzeigen

**alpines**

Zitat von Bernhard65

Funktioniert ja soweit eigentlich, aber wenn ich auf das innere Array schreiben will geht das nur über einen Funktionsaufruf mit Variable ByRef.
Ist das die einzige Lösung?
Ich habe früher viel in C programmiert und da geht das mit Pointer etwas einfacher...

ByRef ist hier praktisch die Pointervariante.

Du kannst das Array auch als ByValue übergeben und das modifizierte Array einfach returnen und in das ursprüngliche Array schreiben.

**BugFix**

Ein schreibender Zugriff über gekapselte Indizes ist nicht möglich. Wenn du ein Array im Array speicherst, musst du es zum Modifizieren separat behandeln. Ob du das mit einem temporären Array löst oder eine ByRef Lösung bevorzugst, bleibt dir überlassen.

Ich finde es meist übersichtlicher, das Array in eine temporäre Variable auszulagern und nach Änderung zurück zu schreiben.

Bernhard65

Super,

Danke euch beiden für die schnelle Antwort.

D.h.:

in meinem Beispiel ich würde das dann so schreiben:

AutoIt

; Temp-Array vom ersten inneren Array erzeugen
Global $aTemp = $aDatum[0]
; dies ist jetzt aber nur eine Kopie vom Array $aWochentage
$aTemp[0][1] = "Neuer Montag"
$aDatum[0] = $aTemp		; geändertes Temp-Array zurückschreiben

bzw. über Return

**BugFix**

Die beste Übersicht wirst du behalten, wenn du für den Zugriff auf innere Arrays eine Funktion erstellst. Hier mal ein Bsp. für 1D-Array:

AutoIt

Local $aIntern1[] = [1,2,3]
Local $aIntern2[] = [4,5,6]
Local $aExtern[] = [$aIntern1,$aIntern2]

; abfragen Index1 in Array Intern2 (5)
ConsoleWrite(_SubArrayValue($aExtern, 1, 1) & @CRLF)

; Wert ändern Index1 in Array Intern2
_SubArrayValue($aExtern, 1, 1, 555)
ConsoleWrite(_SubArrayValue($aExtern, 1, 1) & @CRLF)

Func _SubArrayValue(ByRef $_aParent, $_IndexArray, $_IndexValue, $_Value=Null)
    Local $aSub = $_aParent[$_IndexArray]
    If $_Value = Null Then
        Return $aSub[$_IndexValue]
    Else
        $aSub[$_IndexValue] = $_Value
        $_aParent[$_IndexArray] = $aSub
    EndIf
EndFunc

Alles anzeigen

Bernhard65

Danke BugBix,

dein Vorschlag gefällt mir.

Werde ich so übernehmen.

**BugFix**

Ich habe mal noch eine universale Lösung für das Speichern von 1D oder 2D Array in einem 1D-Array:

AutoIt

Local $aIntern1[] = [1,2,3]
Local $aIntern2[] = [4,5,6]
Local $aExtern1[] = [$aIntern1,$aIntern2]

Local $aIntern3[][] = [[1,2,3],[4,5,6]]
Local $aIntern4[][] = [[11,12,13],[14,15,16]]
Local $aExtern2[] = [$aIntern3,$aIntern4]

; abfragen Index1 in Array Intern2 (5)
ConsoleWrite(_SubArrayValue($aExtern1, 1, 1) & @CRLF)

; Wert ändern Index1 in Array Intern2
_SubArrayValue($aExtern1, 1, 1, 555)
ConsoleWrite(_SubArrayValue($aExtern1, 1, 1) & @CRLF)

; abfragen in Array Intern4 [1][2] (16)
ConsoleWrite(_SubArrayValue($aExtern2, 1, '1,2') & @CRLF)

; Wert ändern in Array Intern4 [1][2]
_SubArrayValue($aExtern2, 1, '1,2', 666)
ConsoleWrite(_SubArrayValue($aExtern2, 1, '1,2') & @CRLF)



; wenn interne Array 1D sind: IndexValue als Ziffer, bei 2D als String: 'IndexDim1,IndexDim2'
Func _SubArrayValue(ByRef $_aParent, $_IndexArray, $_IndexValue, $_Value=Null)
    Local $IndexD1 = $_IndexValue, $IndexD2 = Null, $aSub = $_aParent[$_IndexArray]
    If IsString($_IndexValue) Then ; internes Array ist 2D
        Local $aD = StringSplit($_IndexValue, ',', 2)
        If UBound($aD) <> 2 Then Return SetError(1,0,0)
        $IndexD1 = $aD[0]
        $IndexD2 = $aD[1]
    EndIf
    If $_Value = Null Then
        If $IndexD2 = Null Then
            Return $aSub[$IndexD1]
        Else
            Return $aSub[$IndexD1][$IndexD2]
        EndIf
    Else
        If $IndexD2 = Null Then
            $aSub[$IndexD1] = $_Value
        Else
            $aSub[$IndexD1][$IndexD2] = $_Value
        EndIf
        $_aParent[$_IndexArray] = $aSub
    EndIf
EndFunc

Alles anzeigen

EDIT:

AutoIt

; Für die 2D-Variante:
; wenn im Skript die Indexwerte variabel sind (sehr wahrscheinlich), kann man das über Stringformat schnell einbinden
Global $SF = StringFormat ; Funktion in Kurznamen covern
; in Funktionsaufruf einsetzen:
_SubArrayValue($aExtern2, 1, $SF('%d,%d', $idx1, $idx2), 666)

Array mit Arrays

Ähnliche Themen

MySQL Abfrage in Formular ausgeben

doppelte Worte aus Zeichenkette entfernen - von links beginnen

Array auslesen

Execute bei komplizierterem/mehrzeiligen Code

_ArrayAdd() und Initialisieren von Arrays